linux_adam2.xn

ADAM2 sources (modified by Oleg)

/************************************************************************
 *
 *  link.xn
 *
 *  Linker script for sample application
 *
 ***********************************************************************/

OUTPUT_ARCH(mips)

/**** Start point ****/
ENTRY(_start)			/* Entry point of application		*/

MEMORY
  {
  FLASH   (RX) : ORIGIN = 0x90000000, LENGTH = 0x40000
  FLASHFS (R)  : ORIGIN = 0x90040000, LENGTH = 0x2000000-0x40000
  SDRAM   (WX) : ORIGIN = 0x94000700, LENGTH = 0x8000000-0x700
  }

SECTIONS
{
  /**** Code and read-only data ****/

  .text_rom :  
    {
    _stext_rom = ABSOLUTE(.) ;	/* Start of code and read-only data	*/
    avreset.o (.text)		/* Entry point				*/
    *[a-z,0-9].o(.text)
    *(.rodata)  
    . = ALIGN(8);
    _etext_rom = ABSOLUTE(.);	/* End of code and read-only data	*/
    } >FLASH = 0xff 

  /**** Initialised data ****/

  .data : AT ( ADDR (.text_rom) + SIZEOF (.text_rom) )
  {
    _sdata = ABSOLUTE(.);	/* Start of initialised data		*/
    *(.text)
    *(.data) 
   
    . = ALIGN(8);

    _gp = ABSOLUTE(. + 0x7ff0); /* Base of small data			*/

     *(.sdata) 

    . = ALIGN(8);

    _edata  = ABSOLUTE(.);	/* End of initialised data		*/
  } >SDRAM  = 0xff

  /**** Uninitialised data ****/

  .bss :
    {
    _sbss = .;
    . = ALIGN(8);
    *(.sbss) 
    *(.scommon) 
    *(.bss) 
    *(COMMON) 
    _ebss = .;

    _freemem = .;
    /* Allocate room for stack */
    .   =  ALIGN(8) ;
    .   += 0x5000 ;
    _stack_end_pt =  . - 16;
    .   =  ALIGN(8) ;
    .   += 0x3000 ;
    _tmp_stack_end_pt = . - 16;
    _heap_start_pt = .;
    .  += 0x8000;
    _heap_end_pt   = .;
 
    }>SDRAM

  .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
  .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }


  PROVIDE(temp_stack_end = _stack_end_pt);
  PROVIDE(etext = _etext_rom);
  PROVIDE(sdata = _sdata);
  PROVIDE(edata = _edata);
  PROVIDE(sbss = _sbss);
  PROVIDE(ebss = _ebss);
  PROVIDE (edata = .);
  PROVIDE (end = .);

  /DISCARD/ :
    {
    *(.reginfo)                 /* this section should have no data */
    }

  /* modifications for EST tools to support symbols */
  .debug_info    0:{*(.debug_info)}
  .debug_abbrev  0:{*(.debug_abbrev)} 
  .debug_line    0:{*(.debug_line)}
  .debug_frame   0:{*(.debug_frame)}
  .debug_str     0:{*(.debug_str)}
  .debug_loc     0:{*(.debug_loc)}
  .debug_macinfo 0:{*(.debug_macinfo)}

}