registermessagegetu.pas

Delphi Win32核心API参考光盘

unit RegisterMessageGetU;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls;

var
  UserMessage: UINT;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Timer1: TTimer;
    Label3: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private declarations }
    procedure DefaultHandler(var Msg); override;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.DefaultHandler(var Msg);
begin
  {allow default message handling to occur}
  inherited DefaultHandler(Msg);

  {if the user defined message was recieved...}
  if (TMessage(Msg).Msg=UserMessage) then
  begin
    {...send a reply. this causes the message to return
     immediately if sent by one of the SendMessage functions}
    ReplyMessage(5);

    {enable the timer and turn on a user interface object}
    Timer1.Enabled := TRUE;
    Label2.Visible := TRUE;

    {indicate if the message was sent via one of the SendMessage functions}
    if InSendMessage then Label3.Visible := TRUE;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  {register the system wide user defined message}
  UserMessage := RegisterWindowMessage('System Wide User Defined Message');
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  {turn off the user interface elements after one second}
  Timer1.Enabled := FALSE;
  Label2.Visible := FALSE;
  Label3.Visible := FALSE;
end;


end.