selectedlist.asp.bak

来自「《动态网页设计基础教程》,胡杰,科学出版社」· BAK 代码 · 共 128 行

BAK
128 行
字号 
<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%
Option Explicit
Response.Expires=0
%>
<!--#include file=adovbs.inc -->
<!--#include file=connection.asp -->
<%
Dim RecordPerPage,absPageNUm,TotalPages,absRecordNUm,rsTest,StrSQL
'absPageNum-当前页数,TotalPages-总页数,absRecordNum-当前页中某一条记录的序号
RecordPerPage=4 '每页显示的记录数
absPageNum=CInt(Request.Form("PressPageNum"))
'若返回的是"上一页",则页数减一，若是"下一页"，则页数加一
If Request.Form("Submit")="上一页" Then
	absPageNum=absPageNum-1
ElseIf Request.Form("Submit")="下一页" Then
	absPageNum=absPageNum+1
End If
Select Case Session("Userlevel")
	Case "Student"
		StrSQL="Select Course.Courseno,Course.Name,Course.Credit,Course.Maximumnum,Course.Currentnum,Teacher.Name+Teacher.Title From Course,Selection,Teacher Where Course.Courseno=Selection.Courseno And Selection.Studentno='"&Session("Userno")&"' And Course.Teacherno=Teacher.Teacherno" 
	Case "Teacher" 
		StrSQL="Select Course.Courseno,Course.Name,Course.Credit,Course.Maximumnum,Course.Currentnum,Teacher.Name+Teacher.Title From Course,Selection,Teacher Where Course.Courseno=Selection.Courseno And Course.Teacherno=Teacher.Teacherno And Course.Teacherno='"&Session("Userno")&"'" 
	Case "Admin"
		StrSQL="Select Course.Courseno,Course.Name,Course.Credit,Course.Maximumnum,Course.Currentnum,Teacher.Name+Teacher.Title From Course,Selection,Teacher Where Course.Courseno=Selection.Courseno And Course.Teacherno=Teacher.Teacherno"  
End Select
Set rsTest=Server.CreateObject("ADODB.RecordSet")
rsTest.CacheSize=RecordPerPage '设置这个属性选项会提高性能
rsTest.Open StrSQL,Conn,adOpenStatic,adLockReadOnly,adCmdText
'设置RecordSet对象的每一页数据记录条数
rsTest.PageSize=RecordPerPage
If rsTest.RecordCount=0 Then
	Response.Redirect "selectedlisterror.asp"	
End If
If absPageNum=0 Then
	absPageNum=1
End If
If Not rsTest.EOF Then
		rsTest.AbsolutePage=absPageNum
End If
TotalPages=rsTest.PageCount
%>
<Html>
<Head>
<Meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<Title>浏览课程信息</Title>
</Head>
<Body>
<P>&nbsp;</P>
<Table width="100%" border="0">
  <Tr> 
    <Td height="49"> 
      <Div align="center"><Font color="#009900" size="7" face="华文新魏"><% If Session("Userlevel")<>"Admin" Then Response.Write Session("UserName") End If %> 选 课 信 息 一 览 表</Font></Div></Td>
  </Tr>
  <Tr> 
    <Td height="100"> 
      <Table width="80%" height="90" align="center" border="1" bordercolor="#0000FF">
        <Tr> 
          <Td width="10%" height="15"> 
			 <Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">课程号</Font>
			</Div>
		 </Td>
          <Td width="40%">
			<Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">课程名称</Font>
			</Div>
		  </Td>
          <Td width="8%">
			<Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">学分</Font>
			</Div>
		  </Td>
          <Td width="12%">
			<Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">应选人数</Font>
			</Div>
		  </Td>
          <Td width="12%">
			<Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">实选人数</Font>
			</Div>
		  </Td>
          <Td width="18%">
			<Div align="center">
				<Font color="#CC6600" size="4" face="华文隶书">任课教师</Font>
			</Div>
		  </Td>
		</Tr>
<%
For absRecordNum=1 to rsTest.PageSize
	Response.Write "<Tr valign=middle>"
	'将每条记录的各个字段输出
	Response.Write "<Td>"&rsTest.Fields(0).Value&"</Td>"
	Response.Write "<Td>"&rsTest.Fields(1).Value&"</Td>"
	Response.Write "<Td>"&rsTest.Fields(2).Value&"</Td>"
	Response.Write "<Td>"&rsTest.Fields(3).Value&"</Td>"
	Response.Write "<Td>"&rsTest.Fields(4).Value&"</Td>"
	Response.Write "<Td>"&rsTest.Fields(5).Value&"</Td>"
	Response.Write "</Tr>"
	rsTest.MoveNext
	If rsTest.EOF Then
		Exit For '若到记录尾，退出－如当最后一页数据不满页时。
	End If
Next
Response.Write "</Table><Br>"
'关闭数据库和数据表
rsTest.Close
Conn.Close
Set rsTest=Nothing
Set Conn=Nothing
%>
<Form Action="<% =Request.ServerVariables("SCRIPT_NAME") %>" Method="Post">
	<Input Type="Hidden" Name="PressPageNum" Value="<% =absPageNum %>">
	<Center><% 
	If absPageNum>1 Then '若当前页不是第一页，则显示上一页链接
		Response.Write "<Input Type=Submit Name=Submit Value=上一页>"
	End If
	If absPageNum<>TotalPages Then '若当前页不是最后一页，则显示下一页链接
		Response.Write "<Input Type=Submit Name=Submit Value=下一页>"
	End If
	%>
	</Center>
</Form>
<P><Center>[第<Font Color="#CC0033"><% =absPageNum %></Font>页,共<Font Color="#CC0033"><% =TotalPages %></Font>页]</Center></P>
</Body>
</Html>

selectedlist.asp.bak - 源码说明

本页面展示了「《动态网页设计基础教程》,胡杰,科学出版社」中的 selectedlist.asp.bak 源码文件，采用 BAK 编程语言编写，共 128 行代码。您可以在线阅读完整代码内容，也可以返回资源详情页下载完整源码包进行本地学习和开发。

虫虫下载站收录了大量与动态相关的技术资源，包括源代码、技术文档、电路图等，是电子工程师和嵌入式开发者的专业学习平台。

⌨️ 快捷键说明

复制代码Ctrl + C
搜索代码Ctrl + F
全屏模式F11
增大字号Ctrl + =
减小字号Ctrl + -
显示快捷键?