booklist-4.asp

来自「《动态网页设计基础教程》,胡杰,科学出版社」· ASP 代码 · 共 100 行

ASP
100 行
字号 
<% @LANGUAGE=VBScript %>
<%
Option Explicit
'确保在浏览器上看到的数据不是缓存在客户端的数据，而是服务器端更新的数据
Response.Expires=0
%>
<!--#include file=adovbs.inc -->
<%
Dim Conn
'建立与数据库的连接
Set Conn=Server.CreateObject("ADODB.Connection")
Conn.Provider="Microsoft.Jet.OLEDB.4.0"
Conn.Open Server.MapPath("BookSys.mdb")
Dim RecordPerPage,absPageNUm,TotalPages,absRecordNUm,rsTest,StrSQL
'absPageNum-当前页数,TotalPages-总页数,absRecordNum-当前页中某一条记录的序号
RecordPerPage=6 '每页显示的记录数
absPageNum=CInt(Request.Form("PressPageNum"))
'若返回的是"上一页",则页数减一，若是"下一页"，则页数加一
If Request.Form("Submit")="上一页" Then
	absPageNum=absPageNum-1
ElseIf Request.Form("Submit")="下一页" Then
	absPageNum=absPageNum+1
End If
'创建记录集对象
StrSQL="Select *From BookCatalog" 'BookCatalog是BookSys.mdb的数据表
'创建RecordSet对象
Set rsTest=Server.CreateObject("ADODB.RecordSet")
rsTest.CacheSize=RecordPerPage '设置这个属性选项会提高性能
'使用RecordSet对象的Open方法得到记录集
rsTest.Open StrSQL,Conn,adOpenStatic,adLockReadOnly,adCmdText

'设置RecordSet对象的每一页数据记录条数
rsTest.PageSize=RecordPerPage
If absPageNum=0 Then
	absPageNum=1
End If
If Not rsTest.EOF Then
		rsTest.AbsolutePage=absPageNum
End If
TotalPages=rsTest.PageCount
%>

<Html>
<Body>
<%'利用循环，一条一条记录地显示，知道最后一条记录 %>
<Table border=1 bordercolor="#000000" cellspacing="1" cellpadding="0" align="center" >
	<Tr align=center valign=middle>
		<Td><B>代码</B></Td>
		<Td><B>图 书 名 称</B></Td>
		<Td><B>出 版 社</B></Td>
		<Td><B>种&nbsp;&nbsp;类</B></Td>
		<Td><B>作&nbsp;&nbsp;者</B></Td>
		<Td><B>描&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;述</B></Td>
		<Td><B>单 价</B></Td>
		<Td><B>库存</B></Td>
	</Tr>
<%
Dim i
For absRecordNum=1 to rsTest.PageSize
	Response.Write "<Tr valign=middle>"
	'将每条记录的各个字段输出
	For i=0 to rsTest.fields.count-1
		Response.Write "<Td>"&rsTest.fields(i).value&"</Td>"
	Next
	Response.Write "</Tr>"
	'移到下一条记录，判断是否到表尾
	rsTest.MoveNext
	If rsTest.EOF Then
		Exit For '若到记录尾，退出－如当最后一页数据不满页时。
	End If
Next
Response.Write "</Table><Br>"
'关闭数据库和数据表
rsTest.Close
Conn.Close
Set rsTest=Nothing
Set Conn=Nothing
%>

<Form Action="<% =Request.ServerVariables("SCRIPT_NAME") %>" Method="Post">
	<Input Type="Hidden" Name="PressPageNum" Value="<% =absPageNum %>">
	<Center><% 
	If absPageNum>1 Then '若当前页不是第一页，则显示上一页链接
		Response.Write "<Input Type=Submit Name=Submit Value=上一页>"
	End If
	If absPageNum<>TotalPages Then '若当前页不是最后一页，则显示下一页链接
		Response.Write "<Input Type=Submit Name=Submit Value=下一页>"
	End If
	%>
	</Center>
</Form>
<P><Center>[第<Font Color="#CC0033"><% =absPageNum %></Font>页,共<Font Color="#CC0033"><% =TotalPages %></Font>页]</Center></P>

</Body>
</Html>

booklist-4.asp - 源码说明

本页面展示了「《动态网页设计基础教程》,胡杰,科学出版社」中的 booklist-4.asp 源码文件，采用 ASP 编程语言编写，共 100 行代码。您可以在线阅读完整代码内容，也可以返回资源详情页下载完整源码包进行本地学习和开发。

虫虫开发者社区收录了大量与动态网页相关的技术资源，包括源代码、技术文档、电路图等，是电子工程师和嵌入式开发者的专业学习平台。

⌨️ 快捷键说明

复制代码Ctrl + C
搜索代码Ctrl + F
全屏模式F11
增大字号Ctrl + =
减小字号Ctrl + -
显示快捷键?