inventory.l

来自「A very small LISP implementation with se」· L 代码 · 共 53 行

# 25jun07abu
# (c) Software Lab. Alexander Burger

(must "Inventory" Report)

(menu
   (<h3> NIL ,"Inventory")
   (form NIL
      (<grid> "-.-"
         ,"Number" NIL
         (prog
            (gui '(+Var +NumField) '*InvFrom 10)
            (prin " - ")
            (gui '(+Var +NumField) '*InvTill 10) )
         ,"Description" NIL (gui '(+Var +TextField) '*InvNm 30)
         ,"Supplier" (gui '(+ChoButton) '(choCuSu (field 1)))
         (gui '(+Var +Obj +TextField) '*InvSup '(nm +CuSu) 30) )
      (----)
      (gui '(+ShowButton)
         '(csv ,"Inventory"
            (<table> 'chart NIL
               (quote
                  (align)
                  (NIL ,"Description")
                  (align ,"Inventory")
                  (NIL ,"Supplier")
                  NIL
                  (NIL ,"Zip")
                  (NIL ,"City")
                  (align ,"Price") )
               (pilog
                  (quote
                     @Rng (cons *InvFrom (or *InvTill T))
                     @Nm *InvNm
                     @Sup *InvSup
                     (select (@Item)
                        ((nr +Item @Rng) (nm +Item @Nm) (sup +Item @Sup))
                        (range @Rng @Item nr)
                        (tolr @Nm @Item nm)
                        (same @Sup @Item sup) ) )
                  (with @Item
                     (<row> (alternating)
                        (<+> (: nr) This)
                        (<+> (: nm) This)
                        (<+> (cnt> This))
                        (<+> (: sup nm) (: sup))
                        (<+> (: sup nm2))
                        (<+> (: sup plz))
                        (<+> (: sup ort))
                        (<-> (money (: pr))) ) ) ) ) ) ) ) )

# vi:et:ts=3:sw=3