cs.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Public.asp"-->
<!--#include file="Inc/Info.asp"-->
<%
Server.ScriptTimeOut = 600
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Dim lg
lg = RQuery("action")
If lg&""<>"" Then
	lg = UCase(lg)
	If lg = "DC" Then
		Call DC()
	End If 
Else
	Call mainFace()
End If 
If Err Then
	Call ShowErrs()
End If 

Sub mainFace()
	Call PHead("系统数据库初始化")
	Print "<div class='lface'>"
	Print "<div class='thetitle'>系统数据库初始化</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<br />"
	Print "<input id='btn' type='button' value='系统数据库初始化' onclick=""toDC();"">"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>系统数据库初始化后将删除除系统用户数据外的全部数据！！"
	Print "<li>此操作可能需要时间较长，请耐心等待...</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	%>
	<script language="JavaScript">
	<!--
	function toDC()
	{
		if (confirm('你真的要进行系统初始化吗？此操作将系统初始化到最初状态！！'))
		{
			w();
			location.href="?Action=dc";
			document.all.btn.value="正在进行数据库初始化，请不要进行其他操作...";
			document.all.btn.disabled=true;
		}
		else
		{
			document.all.btn.value="你已取消系统初始化操作";
			document.all.btn.disabled=true;		
		}
	}
	//-->
	</script>
	<%
	Call PFoot()
End Sub 

Sub DC()
	Dim strSQL
	strSQL = "delete from cjTable"
	oConn.Execute(strSQL)
	strSQL = "delete from kmName"
	oConn.Execute(strSQL)
	strSQL = "delete from ksName"
	oConn.Execute(strSQL)
	strSQL = "delete from lgTable"
	oConn.Execute(strSQL)
	strSQL = "delete from sTable"
	oConn.Execute(strSQL)
	strSQL = "delete from sumCJ"
	oConn.Execute(strSQL)
	strSQL = "delete from tmpCJ"
	oConn.Execute(strSQL)

	Call CompactDB(Server.MapPath(DBP))

	Call PHead("系统数据库初始化")
	Print "<div class='lface'>"
	Print "<div class='thetitle'>系统数据库初始化成功</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>系统信息："
	Print "<li>除系统用户数据外的全部数据初始化完毕..."
	Print "<li>数据库压缩完毕..."
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	Call SaveLog(Session("XM"),"系统初始化","系统数据库初始化成功")
	Call HWaiting()
	Call PFoot()
End Sub

Sub CompactDB(DBPath)
	Call CloseConn()
	Dim fso,Engine,strDBPath
	strDBPath = Left(DBPath,InStrRev(DBPath,"\"))
	Set Fso = CreateObject("Scripting.FileSystemObject")
	If Fso.FileExists(DBPath) Then
		Set Engine = CreateObject("JRO.JetEngine")
		Engine.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&dbpath&"","Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&strDBPath&"temp.mdb"
		fso.CopyFile strDBPath&"temp.mdb",dbpath
		fso.DeleteFile(strDBPath&"temp.mdb")
		Set Engine = nothing
	End If
	Set fso = nothing
	If Not IsObject(oConn) Then Call DBConnBegin()
End Sub 
%>