cx_cj.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Info.asp"-->
<!--#include file="Inc/Page.asp"-->
<!--#include file="Inc/Public.asp"-->
<%
Response.Buffer = True
On Error Resume Next 
Dim sxm,sxh
sxh = RQuery("sk")
sxm = RQuery("sxm")
Call PHead("成绩查询")
Call Waiting()
Response.Flush()
If (sxh&""<>"" or sxm&""<>"") And Session("LG")=1 then
	Call viewface()
ElseIf (sxh&""<>"" And sxm&""<>"") then
	Call viewface()
Else
	Call listface()
End If
Call HWaiting()
Call PFoot()
Response.Flush()
If Err Then
	Call ShowErrs()
End If 

Sub viewface()
Dim strSQL,objRs,ZCJ,PCJ,KSID,KSName,i,XM,BJ,sID,XH
strSQL = "Select distinct cjTable.ksID,考试名称 From cjTable,ksName,sTable Where ksName.ksID=cjTable.ksID And sTable.sID=cjTable.sID"
If sxh&""<>"" Then strSQL = strSQL & " And sTable.学号='"&sxh&"'"
If sxm&""<>"" Then strSQL = strSQL & " And sTable.姓名='"&sxm&"'"
Set ksObj = oConn.Execute(strSQL)
If Not ksObj.Eof Then
%>
	<div align="center" width="100%" style="clear:both">
	<div class="thetitle">学号<span id="xh"></span> 姓名<span id="xm"></span> 的成绩查询结果</div>
	<hr size="1" color="#b8b8b8"/>
	</div>
<%
	Do While Not ksObj.Eof
		KSID = ksObj(0)
		KSName = ksObj(1)
		%>
		<div style="float:left;margin:5px;">
		<div class="thead" style="font-size:14px;text-align:left;"><%=KSName%></div>
		<hr size="1" color="#b8b8b8" width="145"/>
		<table width="145" cellpadding="4" cellspacing="1" align="center" class="table1">
		<tr class="thead">
			<!--<td width="5%">ID</td>
			<td>学号</td>
			<td>姓名</td>-->
			<td>科目</td>
			<td>成绩</td>
			<td>班名</td>
			<td>级名</td>
		</tr>
		<%
		strSQL = "Select 学号,姓名,科目名称,分数,cjTable.备注,班级,sTable.sID,cjTable.kmID from sTable,kmName,cjTable where sTable.sID=cjTable.sID And kmName.kmID=cjTable.kmID And cjTable.ksID="&KSID&""
		If sxh&""<>"" Then strSQL = strSQL & " And sTable.学号='"&sxh&"'"
		If sxm&""<>"" Then strSQL = strSQL & " And sTable.姓名='"&sxm&"'"
		strSQL = strSQL & " order by cjTable.kmID desc"
		Set objRs = oConn.Execute(strSQL)
		If Not objRs.Eof Then
				tmpCount = 0
				i = 1
				Do While Not objRs.Eof 
					sID = objRs(6)
					%>
					<tr class="tbody" onmouseout="this.style.background='#ffffff'" onmouseover="this.style.background='#f5f5f5'" title="<%=objRs(4)%>">
						<!--<td><%=i%></td>
						<td><%=objRs(0)%></td>
						<td><%=objRs(1)%></td>-->
						<td><%=objRs(2)%></td>
						<td align="right"><%=objRs(3)%></td>
						<td align="right"><%=KMPM(sID,KSID,objRs(7),1,objRs(5),objRs(3))%></td>
						<td align="right"><%=KMPM(sID,KSID,objRs(7),2,objRs(5),objRs(3))%></td>
					</tr>
					<%	
					XH = objRs(0)
					XM = objRs(1)
					BJ = objRs(5)
					objRs.MoveNext
					If objRs.Eof Then Exit Do
					i = i + 1
				Loop 
				ZCJ = oConn.Execute("Select 总成绩 from sumCJ where sID="&sid&" and ksID="&ksID&"")(0)
				'PCJ = oConn.Execute("Select 平均成绩 from sumCJ where sID="&sid&" and ksID="&ksID&"")(0)
				%>
				<tr class="tbody">
					<td>总分</td>
					<td align="right"><%=ZCJ%></td>
					<td title="总成绩班级排名" align="right"><%=ZCJPM(ksID,1,BJ,ZCJ)%></td>
					<td title="总成绩年级排名" align="right"><%=ZCJPM(ksID,2,BJ,ZCJ)%></td>
				</tr>
		<%	
		End If
		Set objRs = Nothing 
		%>
		</table>
		</div>
		<%
		ksObj.MoveNext
		If ksObj.Eof Then Exit Do
	Loop
	Call Javascript("document.all.xh.innerHTML='"&XH&"';document.all.xm.innerHTML='"&XM&"';")
	%>
	<hr size="1" color="#b8b8b8"/>
	<div align="center" width="100%" style="clear:both" class="np">
	<input type='button' value='返回继续查询' onclick="history.back(-1)">
	<input type='button' value='打印查询结果' onclick="window.print();">
	</div>
<%
	Dim CXR
	If Session("XM") = Empty Then 
		CXR = "匿名"
	Else
		CXR = Session("XM")
	End If 
	Call SaveLog(CXR,"成绩查询","查看"&XM&"的成绩")
Else
	Print "<div class='lface'>"
	Print "<div class='thetitle'>成绩查询失败</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>失败原因："
	Print "<li>输入的学号可能和姓名不对应，没有找到相应的成绩数据。"
	Print "<li>数据库中没有此学生的考试成绩记录或没有此学生资料存在。"
	Print "</ol>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<div align='center'><input type='button' value='返回重新查询' onclick=""location.href='?'""></div>"
	Print "<br /><br /><div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
End If
Set ksObj = Nothing
End Sub

Sub listface()
	Print "<div class='lface' style='text-align:center'>"
	Print "<div class='thetitle' style='text-align:left'>成绩查询系统</div>"
	Print "<hr size='1' color='#b8b8b8'/><br />"
	Print "<form method='get' name='Search' onsubmit=""return checkF()"">"
	Print "学号：<input type='text' name='sk' size='17'><br /><br />"
	Print "姓名：<input type='text' name='sxm' size='17'><br /><br />"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<input type='submit' id='btn' value='提交查询'>"
	Print "<input type='reset' value='重新填写'>"
	If Session("LG")<>1 Then Print "<input type='button' value='登录系统' onclick=""location.href='LG.asp'"">"
	Print "</form>"
	Print "<div style='text-align:left'>"
	Print "<ol>欢迎使用考试成绩查询系统..."
	Print "<li>匿名用户需要输入对应的学号和姓名才可以查询。"
	Print "<li>登录系统后可输入任意一项即可查询。"
	Print "<li>查询结果可显示单科成绩、总成绩及相应的班级排名和年级排名。"
	Print "</ol>"
	Print "</div>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
%>
<script language="JavaScript">
<!--
FocusKey();
function checkF()
{
	var k = document.forms[0].sk.value;
	var m = document.forms[0].sxm.value;
	<%if Session("LG")<>1 then%>
	if (k!=""&&m!="")
	{
		w();
		document.forms[0].btn.value="正在查询，请耐心等待...";
		document.forms[0].btn.disabled=true;
	}
	else
	{
		window.alert('你必须输入对应的学号和姓名方可查询！');
		if (k=="")
		{
			document.forms[0].sk.focus();	
		}else{
			document.forms[0].sxm.focus();	
		}
		return false;
	}
	<%else%>
	if (k!=""||m!="")
	{
		w();
		document.forms[0].btn.value="正在查询，请耐心等待...";
		document.forms[0].btn.disabled=true;
	}
	else
	{
		window.alert('你必须输入学号和姓名中的任意一项方可查询！');
		document.forms[0].sk.focus();	
		return false;
	}
	<%end if%>
}
//-->
</script>
<%
End Sub
%>