bf.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Public.asp"-->
<!--#include file="Inc/Info.asp"-->
<%
Server.ScriptTimeOut = 600
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Call PHead("系统数据库备份还原")
Dim lg
lg = RQuery("action")
If lg&""<>"" Then
	lg = UCase(lg)
	Select Case lg
	Case "N"
		Call CreateBackup()
	Case "R"
		Call RecoveryBackup()
	Case "D"
		Call DeleteBackup()
	End select 
Else
	Call mainFace()
End If 
Call PFoot()
If Err Then
	Call ShowErrs()
End If 

Sub mainFace()
	Print "<div class='lface'>"
	Print "<div class='thetitle'>数据库备份还原</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print BFList()
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>在此你可以管理系统数据库备份，你可以生成新备份或还原备份数据！！"
	Print "<li>此操作可能需要时间较长，请耐心等待...</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	%>
	<script language="JavaScript">
	<!--
	function createBackup()
	{
		if (confirm('你确认要进行系统数据库备份操作吗？此操作将生成一个新的数据库备份文件！！'))
		{
			w();
			location.href="?Action=N";
			document.all.btn.value="正在备份...";
			document.all.btn.disabled=true;
		}
	}
  	function recoveryBackup(fN,fD)
	{
		if (confirm('你确认要将系统恢复到 '+fD+' 备份时的状态吗？？'))
		{
			w();
			location.href="?Action=R&f="+fN+"";
			document.getElementById('r-'+fN+'').value="还原...";
			document.getElementById('r-'+fN+'').disabled=true;
		}
	}
  	function deleteBackup(fN,fD)
	{
		if (confirm('你确认要将 '+fD+' 备份的系统备份删除吗？？'))
		{
			w();
			location.href="?Action=D&f="+fN+"";
			document.getElementById('d-'+fN+'').value="删除...";
			document.getElementById('d-'+fN+'').disabled=true;
		}
	}
	//-->
	</script>
	<%
End Sub 

Sub CreateBackup()
	Dim strBKFile,fso,DBFile
	strBKFile = Year(Date)&Right("00"&Month(Date),2)&Right("00"&Day(Date),2)
	strBKFile = strBKFile & Right("00"&Hour(Time),2)&Right("00"&Minute(Time),2)
	strBKFile = strBKFile & Right("00"&Second(Time),2)
	DBFile = Server.MapPath(".\db_Backup\bk"&strBKFile&".b")

	Set Fso = Server.CreateObject("scripting.filesystemobject")
	Call CloseConn()
	Fso.CopyFile Server.MapPath(DBP),DBFile
	Set Fso = Nothing
	Call CompactDB(DBFile)
	Call JavaScript("h();location.href='?'")
End Sub
Sub RecoveryBackup()
	Dim strBKFile,fso,DBFile
	strBKFile = RQuery("f")
	DBFile = Server.MapPath(".\db_Backup\"&strBKFile&"")
	Set fso = Server.CreateObject("Scripting.FileSystemObject")
	If Fso.FileExists(DBFile) Then
		Call CloseConn()
		Fso.CopyFile DBFile,Server.MapPath(DBP)
	Else
		Call JavaScript("alert('参数错误，没有需要还原的数据库文件存在！！');location.href='?'")
	End If
	Set fso = Nothing
	Call JavaScript("h();location.href='?'")
End Sub
Sub DeleteBackup()
	Dim strBKFile,fso,DBFile
	strBKFile = RQuery("f")
	DBFile = Server.MapPath(".\db_Backup\"&strBKFile&"")
	Set fso = Server.CreateObject("Scripting.FileSystemObject")
	If Fso.FileExists(DBFile) Then
		Fso.DeleteFile DBFile
	Else
		Call JavaScript("alert('参数错误，指定的数据库文件不存在！！');location.href='?'")
	End If
	Set fso = nothing
	Call SaveLog(Session("XM"),"数据备份","删除备份数据成功")
	Call JavaScript("h();location.href='?'")
End Sub
Sub CompactDB(DBPath)
	Dim fso,Engine,strDBPath
	strDBPath = Left(DBPath,InStrRev(DBPath,"\"))
	Set Fso = CreateObject("Scripting.FileSystemObject")
	If Fso.FileExists(DBPath) Then
		Set Engine = CreateObject("JRO.JetEngine")
		Engine.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&dbpath&"","Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&strDBPath&"temp.mdb"
		fso.CopyFile strDBPath&"temp.mdb",dbpath
		fso.DeleteFile(strDBPath&"temp.mdb")
		Set Engine = nothing
	End If
	Set fso = nothing
End Sub 
'//已有备份数据库列表
Function BFList()
   Dim fso, f, f1, fc, s
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f = fso.GetFolder(Server.MapPath("./db_backup/"))
   Set fc = f.Files
   s = "<table width=""95%"" class=""table1"" align='center' cellpadding='2' cellspacing='1'>"&vbCrLf
   s = s & "<tr class=""thead""><td>文件名</td><td>大小</td><td>备份时间</td>"&vbCrLf
   s = s & "<td colspan=""2""><input id=""btn"" type=""button"" value=""生成新备份"" onclick=""javascript:createBackup()""></td></tr>"&vbCrLf
   For Each f1 in fc
	  s = s & "<tr class=""tbody"" onmouseout=""this.style.background='#ffffff'"" onmouseover=""this.style.background='#f5f5f5'"">"&vbCrLf
      s = s & "<td>" & f1.name &"</td>"&vbCrLf
      s = s & "<td>" & Round(f1.size/1024) &" KB</td>"&vbCrLf
      s = s & "<td>" & f1.DateCreated &"</td>"&vbCrLf
	  s = s & "<td align='center'><input id='r-"&f1.name&"' type=""button"" value=""还原"" onclick=""javascript:recoveryBackup('"&f1.name&"','"&f1.DateCreated&"')""></td>"&vbCrLf
	  s = s & "<td align='center'><input id='d-"&f1.name&"' type=""button"" value=""删除"" onclick=""javascript:deleteBackup('"&f1.name&"','"&f1.DateCreated&"')""></td>"&vbCrLf
	  s = s & "</tr>"&vbCrLf
   Next
   s = s & "</table>"
   BFList = s
End Function 
%>