rz.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Info.asp"-->
<!--#include file="Inc/Page.asp"-->
<!--#include file="Inc/Public.asp"-->
<%
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Dim action,id,pg
action = RQuery("action")
id = RQuery("id")
pg = RQuery("page")
If pg&""="" Then pg=1
If action&""<>"" Then action = LCase(action)
Call PHead("系统日志管理")
Call Waiting()
Select Case action
Case "delsave"
	Call DelSave()
Case "delall"
	Call DelAll()
Case Else
	Call ListFace()
End Select 
Call HWaiting()
Call PFoot()
If Err Then
	Call ShowErrs()
End If 

Sub listface()
Dim objRs,strSQL,MyPage,i,sk,xm,mk,tmpJS,tmpJS1
sk = RQuery("sk")
xm = RQuery("xm")
mk = RQuery("mk")
%>
<table align="center" width="100%">
<form method="get" name="Search">
<tr><td class="thetitle">系统日志</td>
<td align="right">
<%
Call XMList()
Call MKList()
%>
<input type="text" size="10" name="sk" id="sk">
<input type="submit" value="查询结果">
<%If sk&""<>"" Or xm&""<>"" Or mk&""<>"" Then Print "<input type='button' value='显示所有' onclick=""location.href='?'"">"%>
<input type="button" value="全部删除" onClick="toDel()">
<input id="btn" style="display:none" type="button" value="删除选定" onClick="document.forms[1].submit();">
</td>
</tr>
</form>
</table>
<hr size="1" color="#b8b8b8"/>
<table width="98%" cellpadding="5" cellspacing="1" align="center" class="table1">
<form method="post" action="?Action=DelSave">
<tr class="thead">
	<td width="7%">姓名</td>
	<td width="10%">模块名称</td>
	<td width="10%">日期</td>
	<td width="7%">时间</td>
	<td width="20%">操作结果</td>
	<td width="10%">来源IP</td>
	<td>命令</td>
	<td width="3%" onclick="cll()" style="cursor:hand" title="全选">删</td>
</tr>
<%
	strSQL = "Select lgID,姓名,模块,日期,时间,结果,来源,命令 From lgTable where 1=1"
	If sk&""<>"" Then strSQL = strSQL & " And 结果 like '%"&sk&"%'"
	If xm&""<>"" Then strSQL = strSQL & " And 姓名 = '"&xm&"'"
	If mk&""<>"" Then strSQL = strSQL & " And 模块 = '"&mk&"'"
	strSQL = strSqL & " Order by lgID Desc"
	'Response.Write strSQL
	Set MyPage = New xdownpage
	MyPage.GetConn = oConn
	MyPage.GetSQL = strSQL
	MyPage.PageSize = 14
	Set objRs = MyPage.GetRs()
	If Not objRs.Eof Then
		tmpJS = ""
		For i = 1 To MyPage.PageSize
	%>
	<tr id="tr<%=objRs(0)%>" class="tbody" onmouseout="mU(this)" onmouseover="mV(this)" onclick="mC('tr<%=objRs(0)%>',<%=objRs(0)%>)">
		<td><%=objRs(1)%></td>
		<td><%=objRs(2)%></td>
		<td><%=objRs(3)%></td>
		<td><%=objRs(4)%></td>
		<td><%=objRs(5)%></td>
		<td><%=objRs(6)%></td>
		<td><%=objRs(7)%></td>
		<td align="center"><input style="width:14px;height:14px;margin:0px;padding:0px;" type="checkbox" name="lgID" id="<%=objRs(0)%>" value="<%=objRs(0)%>"></td>
	</tr>
	<%		tmpJS = tmpJS & "!cl("&objRs(0)&")&&"
			tmpJS1 = tmpJS1 & "mC('tr"&objRs(0)&"',"&objRs(0)&");mU(document.getElementById('tr"&objRs(0)&"'));"&vbCrLf
			objRs.MoveNext
			If objRs.Eof Then Exit For
		Next
		tmpJS = Left(tmpJS,Len(tmpJS)-2)
	Else
	%>
	<tr><td colspan="9" class="tbody" height="60" align="center">没有记录存在</td></tr>
	<%
	End If
	Set objRs = Nothing
	%>
	</form>
	<tr><td colspan="9" class="tbody"><%=MyPage.ShowPage()%></td></tr>
	</table>
<hr size='1' color='#b8b8b8'/>
<div>提示：通过顶部查询功能可进行日志查询，查询内容为操作结果内容。</div>
<script language="JavaScript">
<!--
FocusKey();
function toDel()
{
	var isT = confirm('\n警告：\n\n你真的要执行删除所有日志功能吗？此操作将删除所有日志记录！！');
	if (isT)
	{
		location.href='?Action=DelAll';
	}
}
//选定表格时变色
  function mC(objid,lid)
  {
	var obj = document.getElementById(objid)
	var oc = obj.style.background;
	if (oc=="#f4f9fe")
	{
		obj.style.background='#f5f5f5';
		document.getElementById(lid).checked=false;
		if (<%=tmpJS%>)
		{
			document.getElementById('btn').style.display='none';
		}
	}
	else
	{
		obj.style.background='#f4f9fe';
		document.getElementById(lid).checked=true;
		document.getElementById('btn').style.display='';
	}
  }
 function cl(lid)
 {
	var isc = document.getElementById(lid).checked;
	return isc;
 }
 function cll()
 {
	<%=tmpJS1%>
 }
//-->
</script>
<%
End Sub

Sub XMList()
	Dim strSqL,tmpHtml,objRs
	tmpHtml = "<select name='xm' style='width:90px;'>"
	tmpHtml = tmpHtml & "<option value=''>-姓名-</option>"
	strSQL = "Select 姓名,Count(*) from lgTable Group by 姓名"
	Set objRs = oConn.Execute(strSQL)
	If Not objRs.Eof Then
		Do While Not objRs.Eof
			tmpHtml = tmpHtml & "<option value='"&objRs(0)&"'>"&objRs(0)&"（"&objRs(1)&"）</option>"
			objRs.MoveNext
			If objRs.Eof Then Exit Do
		Loop
	End If
	Set objRs = Nothing
	tmpHtml = tmpHtml & "</select>"

	Print tmpHtml
End Sub 

Sub MKList()
	Dim strSqL,tmpHtml,objRs
	tmpHtml = "<select name='mk' style='width:100px;'>"
	tmpHtml = tmpHtml & "<option value=''>--模块--</option>"
	strSQL = "Select 模块,Count(*) from lgTable Group by 模块"
	Set objRs = oConn.Execute(strSQL)
	If Not objRs.Eof Then
		Do While Not objRs.Eof
			tmpHtml = tmpHtml & "<option value='"&objRs(0)&"'>"&objRs(0)&"（"&objRs(1)&"）</option>"
			objRs.MoveNext
			If objRs.Eof Then Exit Do
		Loop
	End If
	Set objRs = Nothing
	tmpHtml = tmpHtml & "</select>"

	Print tmpHtml
End Sub 

Sub DelSave()
	Dim delID,delCount,strSQL
	delCount = Request.Form("lgID").Count
	delID = ""
	For i = 1 to DelCount
		DelID = DelID & Request.Form("lgID")(i) &","
	Next
	If delID&""<>"" Then 
		On Error Resume Next 
		DelID = Left(DelID,Len(DelID)-1)
		strSQL = "delete from lgTable where lgID in ("&DelID&")"
		oConn.Execute(strSQL)
		If Err Then
			Call ShowErrs()
		Else 
			Call SaveLog(Session("XM"),"系统日志","删除选定日志成功")
			Call JavaScript("alert('删除选定日志资料成功！');location.href='?';")
		End If 
	Else
		Call JavaScript("alert('请选取要删除的日志记录！');location.href='?';")
	End If 
End Sub

Sub DelAll()
	On Error Resume Next 
	oConn.Execute("delete from lgTable")
	If Err Then
		Call ShowErrs()
	Else 
		Call SaveLog(Session("XM"),"系统日志","删除所有日志成功")
		Call JavaScript("alert('删除所有日志资料成功！');location.href='?';")
	End If 
End Sub
%>