up_cj.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Public.asp"-->
<!--#include file="Inc/Info.asp"-->
<%
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Call PHead("更新成绩统计数据")
Dim lg
lg = RQuery("action")
If lg&""<>"" Then
	lg = UCase(lg)
	If lg = "UPCJ" Then
		Call UpCJ()
	End If 
Else 
	Call mainFace()
End If 
Call HWaiting()
Call PFoot()
If Err Then
	Call ShowErrs()
End If 

Sub mainFace()
	Print "<div class='lface'>"
	Print "<div class='thetitle'>更新成绩统计数据</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print sKS()&"<br /><br />"
	Print "<input id='btn' type='button' value=' 开 始 更 新 ' onclick=""toDC();"">"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>运行此项操作，将删除以前所有或选择考试的统计数据；"
	Print "<li>此操作在所有或选择考试的考生成绩数据录入后进行；"
	Print "<li>此操作将更新所有或选择考试的学生的总成绩和平均成绩数据；</li>"
	Print "<li>更新时间较长，请耐心等待系统完成..."
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	%>
	<script language="JavaScript">
	<!--
	function toDC()
	{
	<%if IsDC = 0 then %>
		alert("此功能暂停使用；");
	<%elseif IsDC = 1 then %>
		var k = document.all.ksID.options[document.all.ksID.selectedIndex].value;
		w();
		location.href="?Action=upcj&ksid="+k+"";
		document.all.btn.value="正在更新成绩统计数据，请等待...";
	<%end if%>
		document.all.btn.disabled=true;
		document.all.ksID.disabled=true;
	}
	//-->
	</script>
	<%
	If isDC = 0 Then Call JavaScript("toDC()")
End Sub 

Sub UpCJ()
	Dim objRs,strSQL,kID,ksID
	kID = RQuery("ksID")
	If kID&""<>"" Then
		strSQL = "Select sID,sum(分数),avg(分数) from cjtable Where ksID="&kID&" group by sID"
		Set objRs = oConn.Execute(strSQL)
		If Not objRs.Eof Then
			oConn.Execute("delete from sumCJ where ksID="&kID&"")
			Do While Not objRs.Eof
				oConn.Execute("insert into sumCJ (sID,ksID,总成绩,平均成绩) values ("&objRs(0)&","&kID&","&objRs(1)&","&Round(objRs(2),2)&")")
				objRs.MoveNext
				If objRs.Eof Then Exit do
			Loop
		End If
	Else
		strSQL = "Select sID,ksID,sum(分数),avg(分数) from cjtable group by ksID,sID"
		Set objRs = oConn.Execute(strSQL)
		If Not objRs.Eof Then
			oConn.Execute("delete from sumCJ")
			Do While Not objRs.Eof
				oConn.Execute("insert into sumCJ (sID,ksID,总成绩,平均成绩) values ("&objRs(0)&","&objRs(1)&","&objRs(2)&","&Round(objRs(3),2)&")")
				objRs.MoveNext
				If objRs.Eof Then Exit do
			Loop
		End If
	End If 
	Set objRs = Nothing
	Print "<div class='lface'>"
	Print "<div class='thetitle'>更新成绩统计数据</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>"
	Print "<li>更新成绩统计数据完成；"
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	Call SaveLog(Session("XM"),"成绩管理","更新成绩统计数据成功")	
End Sub
%>