dr_cj.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Info.asp"-->
<!--#include file="Inc/Public.asp"-->
<%
Server.ScriptTimeOut = 600
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Dim ExConn
Dim lg
lg = RQuery("action")
If lg&""<>"" Then
	lg = UCase(lg)
	If lg = "DC" Then
		Call DC2()
	End If 
Else
	Call mainFace()
End If 
If Err Then
	Call ShowErrs()
End If 

Sub mainFace()
	Call PHead("导入考试成绩")
	Print "<div class='lface'>"
	Print "<div class='thetitle'>导入成绩数据</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print sKS()&" "&ExSheetList()&"<br /><br />"
	Print "<input id='btn' type='button' value=' 开 始 导 入 Excel 文 件' onclick=""toDR();"">"
	Print "<input id='btn1' type='button' value='重新上传' onclick=""location.href='DelFile.asp?Action=dc&f=toData_CJ.xls'"">"
	Print "<br /><br /><input type='checkbox' name='delAll'> <span style='color:red;font-weight:700'>清空原数据库中的所有成绩和成绩排名数据！！</span>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>第一行须包括下列名称：编码"&Replace(getKM,",","、")&"；"
	Print "<li>第二行的成绩字段必须全部有值，如果没有话，请输入“0”，导入成功后再删除该生的“0”成绩；"
	Print "<li>导入完成后，请进行“成绩统计”操作，以便自动更新成绩统计数据；"
	Print "<li>此操作可能需要时间较长，请耐心等待..."
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	%>
	<script language="JavaScript">
	<!--
	function toDR()
	{
		var k = document.all.ksID.options[document.all.ksID.selectedIndex].value;
		var s = document.all.exs.options[document.all.exs.selectedIndex].value;
		var d = document.all.delAll.checked;
		if (k!=""&&s!="")
		{
		<%if IsDC = 0 then %>
			alert("此功能暂停使用；");
		<%elseif IsDC = 1 then %>
			w();
			location.href="?Action=dc&ksID="+k+"&exs="+s+"&del="+d+"";
			document.all.btn.value="请等待，系统正在导入数据...";
			document.all.btn1.disabled=true;
		<%end if%>
			document.all.btn.disabled=true;
			document.all.btn1.disabled=true;
			document.all.ksID.disabled=true;
			document.all.exs.disabled=true;
		} 
		else
		{
		<%if IsDC = 0 then %>
			alert("此功能暂停使用；");
			document.all.btn.disabled=true;
			document.all.btn1.disabled=true;
			document.all.ksID.disabled=true;
			document.all.exs.disabled=true;
		<%elseif IsDC = 1 then %>
			if (k=="")
			{
				alert("请先选择要导入到的考试项目！！");
				document.all.ksID.focus();
			}
			else
			{
				alert("请选择要导入的数据表名！！");
				document.all.exs.focus();
			}
		<%end if%>
		}
	}
	//-->
	</script>
	<%
	If isDC = 0 Then Call JavaScript("toDR()")
	Call PFoot()
End Sub 

function ExSheetList()
	Call ExConnBegin()
	Dim tmpHtml,e,rsObj,tmpName
	tmpHtml = "<select name='exs'>"
	tmpHtml = tmpHtml & "<option value=''>数据表名</option>"
	Set rsObj = ExConn.openSchema(20)
	If Not rsObj.Eof Then
		Do While Not rsObj.Eof
			tmpName = rsObj("TABLE_NAME")
			If InStr(tmpName,"'")=0 Then 
				tmpName = Replace(tmpName,"'","")
				tmpHtml = tmpHtml & "<option value="""&tmpName&""">"&Replace(tmpName,"$","")&"</option>"
			End If 
			rsObj.MoveNext
			If rsObj.Eof Then Exit Do
		Loop 
	Else
		Set rsObj = Nothing
		Call ExCloseConn()
		Call JavaScript("alert('请先上传要导入的Excel文档。');location.href='UpFile_CJ.asp';")
	End If 
	Set rsObj = Nothing
	tmpHtml = tmpHtml & "</select>"
	Call ExCloseConn()

	ExSheetList = tmpHtml
End function

Sub DC2()
	Dim ksID,kmID,sID,i,objRs,isDel,tmpFS,strSheet,tmpRs,tmpCount,tmpBM,tmpKM,tmpKMCount
	ksID = RQuery("ksID")
	strSheet = RQuery("exs")
	isDel = RQuery("del")
	tmpKM = getKM()
	tmpKMCount = UBound(Split(tmpKM,","))
	Call ExConnBegin()
	Dim Rs,sql
	Sql="Select 编码"&tmpKM&" From ["&strSheet&"]"
	'//删除原来成绩数据和成绩统计数据
	If isDel Then oConn.Execute("Delete from cjTable"):oConn.Execute("Delete from sumCJ"):oConn.Execute("Delete from tmpCJ")
	response.write sql
	Set Rs = ExConn.Execute(Sql)
	IF Not Rs.Eof Then
		Do While Not Rs.EOF
			tmpBM = Trim(Rs(0))
			Set objRs = oConn.Execute("Select sID From sTable Where 编码='"&tmpBM&"'")
			If Not objRs.Eof Then
				sID = objRs(0)
				For i = 1 To tmpKMCount
					tmpFS = Trim(Rs(i))
					sql = ""
					If IsNumeric(tmpFS) Then
						sql = "Select Count(*) from cjTable Where ksID="&ksID&" And kmID="&i&" And sID="&sID&""
						tmpCount = oConn.Execute(sql)(0)
						If tmpCount = 0 Then
							sql = "insert into cjTable (ksID,kmID,sID,分数,考试时间,备注) values ("&ksID&","&i&","&sID&","&tmpFS&",'"&Date()&"','导入数据')"
							oConn.Execute(sql)
						Else
							Response.Write "<li>"&sql&"记录已经存在。"					
						End If
					End If 
				Next 
			End If  
			Rs.MoveNext
			If Rs.Eof Then Exit do
		Loop
	End If
	Set objRs = Nothing
	Call ExCloseConn()
	Call PHead("导入成绩数据")
	Print "<div class='lface'>"
	Print "<div class='thetitle'>导入考试成绩数据成功</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>导入成功完成。"
	Print "<li>请进行“成绩统计”操作，以便自动更新成绩统计数据；</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	Call SaveLog(Session("XM"),"导入数据","导入成绩数据成功")
	Call HWaiting()
	Call PFoot()
End Sub

Sub ExConnBegin()
	On Error Resume Next 
	If IsObject(ExConn) Then Exit Sub
	Dim  dbFilePath,dbFileName,strConn
	dbFileName = "Export/ToData_CJ.xls"
	dbFilePath = Server.MapPath(dbFileName)

	Set ExConn = Server.CreateObject("ADODB.Connection")
	strConn = "Driver={Microsoft Excel Driver (*.xls)};DBQ="&dbFilePath&""
	ExConn.Open strConn
	If Err Then
		Err.clear
		Response.write "<ol>系统错误:"
		Response.write "<li>不能打开"&dbFileName&"文件。"
		Response.write "<li>请将要导入成绩的Excel文件复制到"&dbFileName&"，并确定有读取权限。"
		Response.Write "</ol>"
		Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
		Response.End
	End If 
End Sub

Sub ExCloseConn()
	If IsObject(ExConn) Then
		ExConn.Close()
		Set ExConn = Nothing
	End If
End Sub
%>