upfile_cj.asp

轩圆学生信息管理系统 081029修正了成绩数据浏览时查看单个学生成绩时总分排名显示表格问题。 //===============================================

<!--#include file="Inc/Check.asp"-->
<!--#include file="Inc/oConn.asp"-->
<!--#include file="Inc/Public.asp"-->
<!--#include file="Inc/Info.asp"-->
<!--#include file="Inc/u.inc.asp"-->
<%
On Error Resume Next 
Call CheckAdmin(",1,",","&Session("JB")&",")
Dim ExConn
Dim lg
lg = RQuery("action")
If lg&""<>"" Then
	lg = UCase(lg)
	If lg = "DC" Then
		Call DC2()
	End If 
Else
	Call mainFace()
End If 
If Err Then
	Call ShowErrs()
End If 

Sub mainFace()
	Call PHead("上传成绩数据")
	Print "<div class='lface'>"
	Print "<div class='thetitle'>上传成绩数据</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<form method='post' action='UpFile_CJ.asp?Action=dc' enctype='multipart/form-data' name='upfile'>"
	Print "<input type='file' size='35' name='upf'>"
	Print "<input type='submit' name='send' style='display:none'>"
	Print "</form>"
	Print "<input id='btn' type='button' value=' 开 始 上 传 Excel 文 件' onclick=""toDC();"">"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>导入成绩前请先上传Excel格式成绩数据文档！！"
	Print "<li>所上传Excel文档必须符合下列要求："
	Print "<li>第一行须包括下列名称：编码"&Replace(getKM,",","、")&"；"
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	%>
	<script language="JavaScript">
	<!--
	function toDC()
	{
		var s = document.all.upf.value;
		if (s!="")
		{
		<%if IsDC = 0 then %>
			alert("此功能暂停使用；");
		<%elseif IsDC = 1 then %>
			w();
			document.upfile.submit();
			document.all.btn.value="正在上传数据，请不要进行其他操作...";
		<%end if%>
			document.all.btn.disabled=true;
			document.all.upf.disabled=true;
		}
		else
		{
			<%if IsDC = 0 then%>
				alert("此功能暂停使用；");
				document.all.btn.disabled=true;
				document.all.upf.disabled=true;
			<%elseif IsDC = 1 then%>
				alert("请选择要上传的Excel文档！");
				document.all.upf.focus();
			<%end if%>
		}
	}
	//-->
	</script>
	<%
	If isDC = 0 Then Call JavaScript("toDC()")
	Call PFoot()
End Sub 

Sub DC2()
	Call PHead("上传成绩数据")
	Dim UploadObj,FileExt,SavePath,File
	SavePath = "Export/toData_CJ.xls"
	Set UploadObj = New UpFile_Class
	UploadObj.InceptFileType = "xls"
	UploadObj.MaxSize = "20000"
	UploadObj.GetDate()
	If UploadObj.Err>0 Then
		Select Case UploadObj.Err 
		Case 1
			Call JavaScript("alert('请先选择要上传的文件！')")
		Case 2
			Call JavaScript("alert('选择的文件超过上传限制，最大为"&UploadObj.MaxSize/1024&"KB！')")
		Case 3
			Call JavaScript("alert('你选择的文件类型不允许，只能上传"&UploadObj.InceptFileType&"文件！')")
		Case Else
			Call JavaScript("alert('"&UploadObj.Err&"')")
		End Select
		Set file = nothing
		Set upload = Nothing 
		Call JavaScript("h();history.back(0);")
		Response.End
	Else
		Set File = UploadObj.File("upf")
		FileExt = File.FileExt
		If FileExt = "xls" Then
			File.SaveToFile Server.MapPath(SavePath)
		End If 
		Set File = nothing
	End If 
	Set UploadObj = Nothing 

	Print "<div class='lface'>"
	Print "<div class='thetitle'>上传成绩数据成功</div>"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<input type='button' value='点此前往导入成绩操作' onclick=""location.href='DR_CJ.asp';"">"
	Print "<hr size='1' color='#b8b8b8'/>"
	Print "<ol>提示："
	Print "<li>上传成绩Excel文档成功。"
	Print "<li>文件已被保存到服务器的Export/目录下，并命名为ToData_CJ.xls；"
	Print "</ol>"
	Print "<div align='left' class='footcopy'>&copy;2007 XMSky</div>"
	Print "</div>"
	Call SaveLog(Session("XM"),"上传数据","上传成绩数据文件成功")
	Call HWaiting()
	Call PFoot()
End Sub
%>