m5329_sdram.lcf

coldfire的mcf5329的程序

#/*
# * File:		sdram.lcf
# * Purpose:	Linker file for the M5208EVB
# *
# * Notes:		running in SDRAM
# *
# */

MEMORY
{
    text    (RX) : ORIGIN = 0x40000480,  LENGTH = 0
    data    (RW) : ORIGIN = AFTER(text), LENGTH = 0
    bss     (RW) : ORIGIN = AFTER(data), LENGTH = 0
    ram     (RW) : ORIGIN = 0x80000000,  LENGTH = 0x00004000
    
}

SECTIONS
{

    ___SDRAM			= 0x40000000;
    ___SDRAM_SIZE		= (32 * 1024 * 1024);

    ___CORE_SRAM		= 0x80000000;
    ___CORE_SRAM_SIZE	= (32 * 1024);

    ___EXT_SRAM			= 0xC0000000;
    ___EXT_SRAM_SIZE	= (512 * 1024);

    ___FLASH			= 0x00000000;
    ___FLASH_SIZE		= (2 * 1024 * 1024);

    ___PARAMS			= 0x00004000;
    ___PARAMS_SIZE		= 0x50;

    ___VECTOR_RAM		= 0x40000000;
    
    .sram :
    {
    	.				= ALIGN(0x10);
    	mcf532x_lo.s (.text)
    	sysinit.c (.text)
    	clock.c (.text)
    } > ram

	.text :
	{
		. 				= ALIGN(0x10);
		vectors.s (.text)
		*(.text)
		. 				= ALIGN(0x10);
	} > text

	.data :
	{
		. 				= ALIGN(0x10);
		___DATA_ROM 	= .;
		___DATA_RAM 	= .;
		*(.rodata)	
		*(.sdata)
		*(.data)
		*(.relocate_code)
		*(.relocate_const)
		*(.relocate_data)
		. 				= ALIGN(0x10);
		___DATA_END 	= .;
	} > data
	
	.bss :
	{
		. 					= ALIGN(0x10);
		___BSS_START 		= .;
		*(.sbss)
		*(SCOMMON)
		*(.bss)
		*(COMMON)
		___BSS_END 			= .;
		. 					= ALIGN(0x10);
		___HEAP_START		= .;
		.					= . + (92 * 1024);
		___HEAP_END			= .;
		___PARAMS_START		= .;
		.					= . + ___PARAMS_SIZE;
		___PARAMS_END		= .;
		___SP_END			= .;
		.					= . + (4 * 1024);
		___SP_INIT			= .;
	} > bss
}