2407x.cmd

DSP的汇编程序

-stack 40
/*--------------------------------------------------------------------------*/
/*  LINKER COMMAND FILE - MEMORY SPECIFICATION for F2407 DSK  	    	   */
/*  Last update 8 JULY 2001				         		   */
/*--------------------------------------------------------------------------*/
MEMORY
{
PAGE 0 :	VECS	: origin =0000h , length = 0040h     /* PROGRAM */
			PVECS	: origin = 0044h , length = 0100h
 				/* Peripheral Interrupt Vectors */
	       		PROG	: origin = 0150h , length = 7EAFh
	/* FLASH on Chip*/
PAGE 1 :	MMRS	: origin = 0000h ,length = 005Fh /* MMRS*/
	       		B2	: origin = 0060h ,length = 0020h/* DARAM B2 BLOCK*/
	       		B01	: origin = 0200h ,length = 0080h/* DARAM B0 BLOCK*/
	       		B02	: origin = 0280h ,length = 0080h
	       		B11	: origin = 0300h ,length = 0080h/* DARAM B1 BLOCK*/
	       		B12	: origin = 0380h ,length = 0080h
	       		SARAM1	: origin = 0800h ,length = 0080h/* SARAM BLOCK*/
	       		SARAM3	: origin = 0900h ,length = 0100h/* SARAM BLOCK*/
	       		SARAM5	: origin = 0A00h ,length = 0200h/* SARAM BLOCK*/
	       		SARAM7	: origin = 0C00h ,length = 0080h/* SARAM BLOCK*/
	       		SARAM9	: origin = 0D00h ,length = 0300h/* SARAM BLOCK*/
}
/*-------------------------------------------------------------------------*/
/* SECTIONS ALLOCATION                                                     */
/*-------------------------------------------------------------------------*/
SECTIONS
{
    .reset	: { } > VECS   PAGE 0	/* Interrupt Vector Table*/
    .vectors	: { } > VECS   PAGE 0	/* INTERRUPT VECTOR TABLE*/
    .pvecs	: { } > PVECS  PAGE 0/* Peripheral INTERRUPT VECTOR TABLE*/
    .const	: LOAD = PROG  PAGE 0, RUN= B01     PAGE 1
    .text	: { } > PROG   PAGE 0	/* CODE	*/
    init	: { } > PROG   PAGE 0	/* FFT */
    twiddles	: { } > PROG   PAGE 0	/* FFT */
    fftprog	: { } > PROG   PAGE 0	/* FFT	*/
    .cinit	: { } > PROG   PAGE 0
    .b2		: { } > B2     PAGE 1	/* 保存ST0,ST1 */
    .context	: { } > B01    PAGE 1	/* 保存contex的内容 	*/
    .stack	: { } > B01    PAGE 1	/* 保存堆栈stack的内容*/
    .data0	: { } > B02    PAGE 1	/* 存放液晶显示定义的寄存器及一些常用寄存器*/  
    .data1	: { } > B11    PAGE 1	/* FFT Working Space--c2cx0032.ASM	*/
     twid	: { } > B11    PAGE 1	/* FFT--c2cx0032.ASM		*/
    .fftvar  	: { } > B11    PAGE 1	/* FFT--INIT-FFT.ASM(17 words)*/ 
    .xtdata	: { } > SARAM1 PAGE 1	/* 存放第1种工作情况的系统参数	*/
    .yxdata	: { } > SARAM3 PAGE 1	/* 存放第1种工作情况的运行参数	*/
    .uidata	: { } > SARAM5 PAGE 1	/* 存放第1种工作情况的电压、电流、功率、电能参数*/
    .gzdata	: { } > SARAM7 PAGE 1	/* 记录第1种工作情况的故障参数 	*/
    .ad		: { } > SARAM9 PAGE 1	/* 存放A/D采集的16通道的参数	*/
}
/*剩余空间，380-3ff，f00-fff*/