eh0218.ld

手持机读写GSM标准的CPU卡代码,包括手持机的液晶显示

/* Linker Description file for MC2002 series */

OUTPUT_ARCH(m68k)
OUTPUT_FORMAT("coff-m68k")
/* GROUP(-lgcc -lg -lm -lm2002 -lmcard -lconso -lEx218 mifare530.a trans.a) */
GROUP(-lgcc -lg -lm  libezpos.a MifareLib.a exeh0218.a libcard.a )

/* for MC2002 configuration:  */
/* 1M byte FLASH, 2M byte Program RAM, Program Running in FLASH */
/* User Stack is 32K bytes, fixed size, located in system RAM   */
MEMORY
{
  ram   : ORIGIN = 0x05040000, LENGTH = 1788k          /* user RAM(Global Var,Heap) = 2048K(total) - 256K(system) - 4K(monitor)    */
  rom   : ORIGIN = 0x0005000C, LENGTH = 704k           /* user Flash(Program,Database) = 1024K(total) - 320K(system) */
}

PROVIDE (__stack = 0);

SECTIONS
{
  .text :
  {
     *(.text)
     . = ALIGN(4);
     etext  =  .;
     __CTOR_LIST__ = .;
     LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
     *(.ctors)
     LONG(0)
     __CTOR_END__ = .;
     __DTOR_LIST__ = .;
     LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
     *(.dtors)
     LONG(0)
     __DTOR_END__ = .;
    _etext = ALIGN(4);
  } > rom

  .data :
  AT(_etext)
  {
    _data = .;
    *(.data)
    _edata = .;
  } > ram

  _e_romdata = _etext + SIZEOF(.data) ;
  FLASH_DB_START = _e_romdata % 65536 ?
                  (_e_romdata / 65536 + 1) * 65536 :
                  _e_romdata;

  .bss :
  {
	_start_bss = .;
	*(.bss)
        *(COMMON)
        _end = .;
  } > ram

  .nvram (NOLOAD):
  {
    *(.nvram)
  } > ram

  .heap ALIGN(2048) (NOLOAD) :
  {
        _heap_bottom = .;

  /* here: we give 512K space for user global variables,                       */
  /* if linker failed due to user global variables space not enough,           */
  /* please try give more by decreasing the following number                   */
  /* try until linker works successfully.                                      */

        . += 1276k;       /* Heap Size = 1792(total) - 512K(global variables)  */

       _heap_top    = .;
  } > ram

}