page.asp

网店批发系统,很好很强大,很好很强大很好很强大

<%
'*********************************************************************************************
'                                  (分页函数使用方法) 
'					code by terry 2006.01.24	今天是老婆生日好开心^.^
'	该函数只适用于getrows取数组并循环的方法,在页头调用此函数
'	然后定义页面显示数量pagenum,数据总数ArrayNum
'	循环格式如：
'		for news_j = (Page-1)*pagenum to ArrayNum
'			此处为循环内容
'			if news_j = Page*pagenum-1 then exit for
'  		next
'	在页尾调用 call PageTable(ArrayNum+1,pagenum,"条新闻")
'	分页的样式在该代码的最下放修改
'*********************************************************************************************
	dim Page,MaxPage,PageUrl,PageQuery,PageTrueUrl,LeftPageUrl,RightPageUrl
	
	'初始化
	Page=sqlCheck(Request.QueryString("Page"))
	
	if Page <= 0 or Page = "" then
		Page = 1
	end if	
		
	sub PageTable(i,PageNum,DataName)
	
		'判断页面最大值
		if i mod PageNum = 0 then
			MaxPage=int(i/PageNum)
		else
			MaxPage=int(i/PageNum)+1
		end if
		'读取该执行文件
		PageUrl=Request.ServerVariables("URL") 
		PageUrl=split(PageUrl,"/")
		LeftPageUrl=PageUrl(Ubound(PageUrl))
		
		'读取字符串
		PageQuery=Request.ServerVariables("QUERY_STRING") 
		
		if instr(PageQuery,"&") then
		'多字符
			if instr(PageQuery,"&page=") then
			'非头一次读
				PageQuery=split(PageQuery,"&page=")
				RightPageUrl="?"&PageQuery(0)&"&"
			else
			'头次读
				RightPageUrl="?"&PageQuery&"&"
			end if
		else
		'单字符或者无字符
			if PageQuery<>"" then
			'单字符
				if instr(PageQuery,"page=") then
					RightPageUrl="?"
				else
					RightPageUrl="?"&PageQuery&"&"
				end if
			else
			'无字符
				RightPageUrl="?"
			end if
		end if
		
		'页面地址OK
		PageTrueUrl = LeftPageUrl&RightPageUrl
		
			response.Write("<table width='100%' border='0' cellpadding='0' cellspacing='0'  height='30'><tr><td align='center'>（共有"&i&""&DataName&"，分"&MaxPage&"页，当前为第"&Page&"页）<a href='"&PageTrueUrl&"page=1'>首页</a>")
		if Cint(Page) <> 1 then
			response.Write("<a href='"&PageTrueUrl&"page="&Page-1&"'> 上一页 </a>")
		else
			response.Write(" 上一页 ")
		end if
	
		if Cint(MaxPage)>Cint(Page) then
			response.Write("<a href='"&PageTrueUrl&"page="&Page+1&"'> 下一页 </a>")
		else
			response.Write(" 下一页 ")
		end if	
		
			response.Write("<a href='"&PageTrueUrl&"page="&MaxPage&"'> 尾页 </a>转到 第 <select onchange="&chr(34)&"window.open(options[selectedIndex].value,'_self')"&chr(34)&">")
		for PageNum = 1 to MaxPage
			response.Write("<option value='"&PageTrueUrl&"page="&PageNum&"'") 
			if Cint(PageNum) = Cint(Page) then
				response.Write("selected")
			end if
			response.Write(">"&PageNum&"</option>")
		next
			response.Write("</select> 页</td></tr></table>")
	end sub
%>