productclass.asp

网店批发系统,很好很强大,很好很强大很好很强大

<%
Response.Buffer = True 
Response.ExpiresAbsolute = Now() - 1 
Response.Expires = 0 
Response.CacheControl = "no-cache" 
Response.AddHeader "Pragma", "No-Cache" 

dim l_ClassID,l_ClassType,l_css,l_pageNum,l_order,Orderquery
dim PLTitle,PL_altinfo
dim ProductList,PLquery
dim PCquery,PCList
dim PL_kkt,PL_j
dim detailquery,detailPro_t,ProTitle
dim pic1,pic2,pic3,pic4,pic5,p

l_ClassID=shop.sqlcheck(Request.QueryString("ID"))
l_ClassType=shop.sqlchg(Request.QueryString("ClassType"))
l_css=shop.sqlchg(Request.QueryString("css"))
l_pageNum=shop.sqlchg(Request.Form("pageNum"))
l_order=shop.sqlchg(Request.Form("order"))

'css样式cookie
if request.Cookies("dalu")("css") = "" then
	response.Cookies("dalu")("css") = 1
elseif l_css <> "" then
	response.Cookies("dalu")("css") = l_css
end if

'商品数量cookie
if request.Cookies("dalu")("page") = "" then
	response.Cookies("dalu")("page") = 12
elseif l_pageNum <> "" then
	response.Cookies("dalu")("page") = l_pageNum
end if
'排序方式cookie
if request.Cookies("dalu")("order") = "" then
	response.Cookies("dalu")("order") = 0
elseif l_order <> "" then
	response.Cookies("dalu")("order") = l_order
end if

'排序
if request.Cookies("dalu")("order") = 1 then
	Orderquery = "ProductPrice1,"
end if

'判断显示图片
if request.Cookies("dalu")("css") = 1 then
	pic1 = "_act"
end if
if request.Cookies("dalu")("css") = 2 then
	pic2 = "_act"
end if
if request.Cookies("dalu")("css") = 3 then
	pic3 = "_act"
end if
if request.Cookies("dalu")("order") = 1 then
	pic4 = "_act"
else
	pic5 = "_act"
end if

'ClassTitle
PLTitle = shop.connectXml(XML,"/language/ProductList")

set PL_kkt = new kktTemplate

PL_kkt.set_file "hndKktTemp", "kktTemplate/ProductClass.dwt"
PL_kkt.set_var "url", config(1,0), false 

PL_kkt.set_var "pic1", pic1, false 
PL_kkt.set_var "pic2", pic2, false 
PL_kkt.set_var "pic3", pic3, false 
PL_kkt.set_var "pic4", pic4, false 
PL_kkt.set_var "pic5", pic5, false 

'判断支付方式
'支付宝
if config(33,0) = 0 then
	PL_kkt.set_var "zhifu0", "<img src='images/icon_alipay.gif' width='16' height='16' border='0' alt='{altinfo2}' />", false 
end if
'网银支付
if config(34,0) = 0 then
	PL_kkt.set_var "zhifu1", "<img src='images/icon_chinabank.gif' width='16' height='16' border='0' alt='{altinfo3}' />", false 
end if

PL_altinfo = shop.connectXml(XML,"/language/alt")  	
for PL_j = 0 to 3
	PL_kkt.set_var "altinfo"&PL_j, PL_altinfo(PL_j), false 
next

PL_kkt.set_block "hndKktTemp", "ProductClass", "a"

for PL_j = 0 to UBound(PLTitle) 
	PL_kkt.set_var "PLTitle"&PL_j, PLTitle(PL_j), false 
next

'ProClass
if l_ClassID <> "" then
	PLquery = "Select p.ProductID,p.ProductName,p.ProductPic,p.ProductPrice,p.ProductPrice1,p.ProductShortContent,c.ClassTree,c.ClassLevel from Product p Inner Join [Class] c on c.ClassID = p.ProductClassID where instr(c.ClassTree,"&l_ClassID&") or ProductClassID = "&l_ClassID&" order by "&Orderquery&"p.orderID desc,ProductID desc"
elseif l_ClassType <> "" then

	if l_ClassType <> "Tuijian" and l_ClassType <> "Tejia" and l_ClassType <> "Xinpin" then
		Response.Write("<script>window.location.href='error.asp?errorMsg=无效的商品类别信息';</script>")
		Response.End()
	end if
	
	if l_ClassType = "Tuijian" then
		ProTitle = PLTitle(10)
	elseif l_ClassType = "Tejia" then
		ProTitle = PLTitle(9)
	elseif l_ClassType = "Xinpin" then
		ProTitle = PLTitle(8)
	end if	
	
	PLquery = "select ProductID,ProductName,ProductPic,ProductPrice,ProductPrice1,ProductShortContent from Product order by "&Orderquery&"Product"&l_ClassType&" desc,orderID,ProductID desc"
else
	ProTitle = PLTitle(11)
	PLquery = "select ProductID,ProductName,ProductPic,ProductPrice,ProductPrice1,ProductShortContent from Product order by "&Orderquery&"orderID desc,ProductID desc"
end if

ProductList = shop.DBClass(PLquery)

'定义分页必须数据
PageNum = request.Cookies("dalu")("page")
call shop.setPage(PageNum,ArrayNum + 1)

PL_kkt.set_var "PageTrueUrl", shop.pageNow(), false 

if ArrayNum <> -1 then
	for PL_j = (Page-1)*PageNum to PageEnd
		PL_kkt.set_var "ProductID", ProductList(0,PL_j), false
		PL_kkt.set_var "ProductName", left(ProductList(1,PL_j),12), false	
		PL_kkt.set_var "ProductPic", ProductList(2,PL_j), false
		PL_kkt.set_var "ProductPrice", ProductList(3,PL_j), false
		PL_kkt.set_var "ProductPrice1", ProductList(4,PL_j), false
		PL_kkt.set_var "ProductShortContent", ProductList(5,PL_j), false
		PL_kkt.parse "a", "ProductClass", true
	next
end if

if l_ClassType = "" and l_ClassID <> "" then
	PCquery = "Select ClassLevel,ClassTree from [Class] where ClassID="&l_ClassID&""
	PCList = shop.DBClass(PCquery)
	
	if ArrayNum <> -1 then
		if l_ClassID <> "" then
		'读所属类别
			if PCList(0,0) = 0 then
				detailquery = "Select ClassID,ClassName from [Class] where ClassID="&l_ClassID&""	
			else
				detailquery = "Select ClassID,ClassName from [Class] where ClassID="&l_ClassID&" or instr('"&PCList(1,0)&"',ClassID)"
			end if
			detailPro_t = shop.DBClass(detailquery)	
			'response.Write detailquery
			for PL_j = 0 to UBound(detailPro_t,2)
				if Cint(detailPro_t(0,PL_j)) = Cint(l_ClassID) then
					ProTitle=ProTitle&"<a href='ProductClass.asp?ID="&detailPro_t(0,PL_j)&"'>"&detailPro_t(1,PL_j)&"</a>"
				else
					ProTitle=ProTitle&"<a href='ProductClass.asp?ID="&detailPro_t(0,PL_j)&"'>"&detailPro_t(1,PL_j)&"</a> >> "
				end if
			next
		end if
	end if
end if
	
PL_kkt.set_var "PLTitle", ProTitle, false 

PL_kkt.parse "out", "hndKktTemp", false      				
PL_kkt.p "out"                              			
set PL_kkt = nothing              			
%>