p_detail.asp

网店批发系统,很好很强大,很好很强大很好很强大

<%
dim ProductID,ReturnUrl,p_class,p_classquery
dim detailTitle,detail_pic
dim detailPro,detailquery
dim detail_kkt,detail_j,detail_k,detail_c,ProTitle,detailPro_t
dim d_user

ProductID = shop.sqlCheck(Request.QueryString("ProID"))
ReturnUrl = "ProductDetail.asp?ProID="&ProductID

if Request.Form("pingflag") = "save" then
	'保存评论
	dim emoticon,pingname,pingcontent,pingcode,pingdate,pingquery
	emoticon = shop.sqlcheck(Request.Form("emoticon"))
	if User <> "" then
		pingname = User
	else
		pingname = "过客"
	end if
	pingcontent = "<img src=images/00"&emoticon&".gif>"&shop.sqlchg(request.Form("pingcontent"))
	pingcode = request.Form("pingcode")
	pingdate = now()
	'判断验证码
	if Cstr(pingcode) <> Cstr(Session("verifyCode")) then
		Response.Write("<script language='javascript'>alert('验证码错误！');history.go(-1);</script>")
		Response.End()		
	end if
	pingquery = "Insert into Message (MsgFrom,MsgContent,MsgDate,ProductID,MsgType) values ('"&pingname&"','"&pingcontent&"','"&pingdate&"','"&ProductID&"','1')"
	call shop.DBExecute(pingquery)
	
	Response.Write("<script language='javascript'>alert('发布成功！');window.location.href='"&ReturnUrl&"';</script>")
	Response.End()
end if

'ClassTitle
detailTitle = shop.connectXml(XML,"/language/detail")

set detail_kkt = new kktTemplate 

detail_pic = shop.connectXml(XML,"/language/pic")  

detail_kkt.set_file "hndKktTemp", "kktTemplate/p_detail.dwt"
detail_kkt.set_block "hndKktTemp", "detailProList", "d"
detail_kkt.set_block "hndKktTemp", "ReProPinglun", "r"
detail_kkt.set_block "hndKktTemp", "ProPinglun", "p"
detail_kkt.set_var "url", config(1,0), false 
detail_kkt.set_var "u_name", UserLevelName, false 
detail_kkt.set_var "u_num", UserLevelNum, false 

'判断支付方式
'支付宝
if config(33,0) = 0 then
	detail_kkt.set_var "zhifu0", "<img src='images/payment_alipay.gif' border='0' />", false 
end if
'网银支付
if config(34,0) = 0 then
	detail_kkt.set_var "zhifu1", "<img src='images/payment_chinabank.gif' border='0' />", false 
end if

for detail_j = 0 to UBound(detailTitle)
	detail_kkt.set_var "detailTitle"&detail_j, detailTitle(detail_j), false 
next

for detail_j = 5 to 7
	detail_kkt.set_var "detail_pic"&detail_j, detail_pic(detail_j), false 
next

'ProClass
detailquery = "Select p.ProductID,p.ProductName,p.ProductPic,p.ProductPrice,p.ProductPrice1,p.ProductContent,p.ProductClassID,c.ClassTree,c.ClassName,c.Classlevel,p.ProductJifen,p.ProductNum,p.ProductPic1,p.ProductDate,p.ProductShortContent,p.ProductKey,p.ProductMaxLength from Product p inner join [Class] c on c.ClassID = p.ProductClassID where p.ProductID="&ProductID&""
detailPro = shop.DBClass(detailquery)

if ArrayNum <> -1 then
	for detail_j = 0 to ArrayNum
		detail_kkt.set_var "ProductID", detailPro(0,detail_j), false
		detail_kkt.set_var "ProductName", detailPro(1,detail_j), false	
		detail_kkt.set_var "ProductPic", detailPro(12,detail_j), false	
		detail_kkt.set_var "ProductPrice", detailPro(3,detail_j), false
		detail_kkt.set_var "ProductPrice1", Cint(detailPro(4,detail_j)*UserLevelNum/100), false	
		detail_kkt.set_var "ProductContent", detailPro(5,detail_j), false	
		detail_kkt.set_var "ProductJifen", detailPro(10,detail_j), false
		detail_kkt.set_var "ProductNum", detailPro(11,detail_j), false	
		detail_kkt.parse "d", "detailProList", true
	next
else
	Response.Write("该商品不存在")
	Response.End()
end if

'读商品所属类别
if isnull(detailPro(7,0)) then
'是否为顶级分类
	ProTitle="<a href='ProductClass.asp?ID="&detailPro(6,0)&"'>"&detailPro(8,0)&"</a>"
else
	ProTitle = "<a href='index.asp'>首页 >> </a>"
	detailquery = "Select ClassID,ClassName from [Class] where ClassID="&detailPro(6,0)&" or instr('"&detailPro(7,0)&"',ClassID)"
	detailPro_t = shop.DBClass(detailquery)	
	
	for detail_j = 0 to UBound(detailPro_t,2)
		if detailPro_t(0,detail_j) = detailPro(6,0) then
			ProTitle=ProTitle&"<a href='ProductClass.asp?ID="&detailPro_t(0,detail_j)&"'>"&detailPro_t(1,detail_j)&"</a> "
		else
			ProTitle=ProTitle&"<a href='ProductClass.asp?ID="&detailPro_t(0,detail_j)&"'>"&detailPro_t(1,detail_j)&"</a> >> "
		end if
	next
end if

detail_kkt.set_var "ProTitle", ProTitle, false

'用户名
if User <> "" then
	d_user = User
else
	d_user = "过客"
end if
detail_kkt.set_var "Username", d_user, false

dim p_query,p_array
'商品评论
p_query = "Select MsgFrom,MsgContent,MsgDate,MsgID,MsgTo,ReUserName from Message where ProductID = "&ProductID&" and msgType = 1 order by MsgID DESC"
p_array = shop.DBClass(p_query)

detail_c = 1

if ArrayNum <> -1 then
	for detail_j = 0 to ArrayNum
		if p_array(0,detail_j) <> "管理员" then
			detail_kkt.set_var "MsgCount", detail_c, false
			detail_kkt.set_var "MsgFrom", p_array(0,detail_j), false
			detail_kkt.set_var "MsgContent", p_array(1,detail_j), false	
			detail_kkt.set_var "MsgDate", p_array(2,detail_j), false
			detail_kkt.unset_var "r"	
			for detail_k = 0 to ArrayNum
				if p_array(4,detail_k) <> "" then
					if Cint(p_array(4,detail_k)) = Cint(p_array(3,detail_j)) then				
						detail_kkt.set_var "ReMsgContent", p_array(1,detail_k), false
						detail_kkt.parse "r", "ReProPinglun", true
					end if
				end if
			next
			detail_kkt.parse "p", "ProPinglun", true
			detail_c = detail_c + 1
		end if
		if detail_j = ArrayNum then
			detail_kkt.unset_var "r"
		end if
	next
end if

dim s_query,s_array
'读配送方式
s_query = "Select NewsContent from News where NewsID = 14 or NewsID = 16 order by NewsID"
s_array = shop.DBClass(s_query)

detail_kkt.set_var "peisong0", s_array(0,0), false
detail_kkt.set_var "peisong1", s_array(0,1), false

detail_kkt.parse "out", "hndKktTemp", false      				
detail_kkt.p "out"                              			
set detail_kkt = nothing           			
%>