search.asp

网店批发系统,很好很强大,很好很强大很好很强大

<%
Dim action,StartPrice,EndPrice,ClassID,Key,ProductID,OrderNumber,OrderPass
dim search_alt_info
Dim sql1,sql2,sql3,sql4,sql0,sql5
dim searchTitle
dim searchPro,searchquery,classpro,classquery,searchkeypro,searchkeyquery,keyPro
dim search_kkt,search_j

action = shop.sqlchg(Request("action"))
StartPrice = shop.sqlcheck(Request("StartPrice"))
EndPrice = shop.sqlcheck(Request("EndPrice"))
ClassID = shop.sqlchg(Request("ClassID"))
Key = shop.sqlchg(Request("Key"))
ProductID =shop.sqlcheck(Request("ProductID"))
OrderNumber = shop.sqlchg(Request("OrderNumber"))
OrderPass = shop.sqlchg(Request("OrderPass"))

'***************订单搜索*********************
if action = "Order" then
	order = shop.DBClass("Select orderUserName from [Order] where OrderNumber = '"&OrderNumber&"' and OrderPass = '"&OrderPass&"'")
	if ArrayNum <> -1 then
		Session("Username") = order(0,0)
		Session.Timeout = 5
		
		response.Write("页面跳转中，您可以直接查看及修改订单状态。。。")
		response.Write("<script language='javascript'>window.location.href='UserCenter.asp?action=ViewDingDan&ID="&OrderNumber&"';</script>")
		response.End()
	else
		response.Write("<script language='javascript'>alert('订单号或密码错误');window.location.href='index.asp';</script>")
		response.End()
	end if
end if

'如果是商品ID
if ProductID <> "" then
	sql0 = "p.ProductID = "&Cint(ProductID)&" and "
end if

'价格判断
if StartPrice <> "" then
	sql1 = "ProductPrice1 >= "&Cint(StartPrice)&" and "
end if

if EndPrice <> "" then
	sql4 = "ProductPrice1 <= "&Cint(EndPrice)&" and "
end if

'类别判断
if ClassID <> "" then
	sql2 = "(instr(ClassTree,"&ClassID&") or ClassID = "&Cint(ClassID)&") and "
end if

'名称判断
if key <> "" then
	sql3 = "ProductName like '%"&Key&"%' and "	
end if

if action = "" then
	sql5 = "1=2"
else
	sql5 = "1=1"
end if

searchquery = "Select p.ProductID,p.ProductName,p.ProductPic,p.ProductPrice,p.ProductPrice1,p.ProductShortContent from Product p inner join [Class] c on p.ProductClassID = c.ClassID where "&sql0&sql1&sql4&sql2&sql3&sql5&" order by ProductID desc"

classquery = "Select ClassID,ClassName,ClassLevel,ClassHeadID from Class order by ClassLevel,orderid,ClassID desc"

searchkeyquery = "Select top 20 SearchName,SearchCount from Search order by SearchCount desc"

'ClassTitle
searchTitle = shop.connectXml(XML,"/language/search")

classpro = shop.DBClass(classquery)
searchkeypro = shop.DBClass(searchkeyquery)
searchPro = shop.DBClass(searchquery)

set search_kkt = new kktTemplate 

'判断支付方式
'支付宝
if config(33,0) = 0 then
	search_kkt.set_var "zhifu0", "<img src='images/icon_alipay.gif' width='16' height='16' border='0' alt='{altinfo2}' />", false 
end if
'网银支付
if config(34,0) = 0 then
	search_kkt.set_var "zhifu1", "<img src='images/icon_chinabank.gif' width='16' height='16' border='0' alt='{altinfo3}' />", false 
end if

search_kkt.set_file "hndKktTemp", "kktTemplate/search.dwt"
search_kkt.set_var "url", config(1,0), false 

'读XML
search_alt_info = shop.connectXml(XML,"/language/alt")  	
for search_j = 0 to 3
	search_kkt.set_var "altinfo"&search_j, search_alt_info(search_j), false 
next

search_kkt.set_block "hndKktTemp", "searchProList", "a"
search_kkt.set_block "hndKktTemp", "ClassList", "b"
search_kkt.set_block "hndKktTemp", "searchkey", "c"

for search_j = 1 to UBound(searchTitle)
	search_kkt.set_var "searchTitle"&search_j, searchTitle(search_j), false 
next

'定义分页必须数据
PageNum = 8
call shop.setPage(PageNum,ArrayNum + 1)

search_kkt.set_var "PageTrueUrl", shop.pageNow(), false 

if ArrayNum <> -1 then
	for search_j = (Page-1)*PageNum to PageEnd
		search_kkt.set_var "ProductID", searchPro(0,search_j), false
		search_kkt.set_var "ProductName", searchPro(1,search_j), false	
		search_kkt.set_var "ProductPrice", searchPro(3,search_j), false	
		search_kkt.set_var "ProductPrice1", searchPro(4,search_j), false	
		search_kkt.set_var "ProductShortContent", searchPro(5,search_j), false	
		search_kkt.set_var "ProductPic", searchPro(2,search_j), false	
		search_kkt.parse "a", "searchProList", true
	next
end if

'写入数据库
if Key <> "" and ArrayNum <> -1 then
	keyPro = shop.DBClass("Select Count(*) from Search where SearchName = '"&Key&"'")
	search_j = keyPro(0,0)

	if search_j = 0 then
		shop.DBExecute("Insert into Search (SearchName,SearchCount) values ('"&Key&"','1')")
	'如果搜索过
	else
		shop.DBExecute("Update Search set SearchCount = SearchCount + 1 where SearchName = '"&Key&"'")
	end if
end if

'****************************重新排列顺序******************************
	Dim i,j,k,l,m
	Dim NewProClass
	i=0
	l=0
	
	i = UBound(classpro,2)
	NewProClass = classpro
	
	'重新排列顺序
	for k = 0 to i
		if classpro(2,k) = 0 then
		
			NewProClass(0,l)=classpro(0,k)
			NewProClass(1,l)=classpro(1,k)
			NewProClass(2,l)=classpro(2,k)
			l=l+1
			checkChild(classpro(0,k))
		end if
	next
	
	function checkChild(father)
		dim n
		for n = 0 to i
			if classpro(3,n) = father then
			
				NewProClass(0,l)=classpro(0,n)
				NewProClass(1,l)=classpro(1,n)
				NewProClass(2,l)=classpro(2,n)
				l=l+1
				checkChild(classpro(0,n))
			end if		
		next
	end function
	
	for k = 0 to i
		NewProClass(3,k)=""
		for m = 1 to NewProClass(2,k)
			if m = 1 then
				NewProClass(3,k)=NewProClass(3,k)&"&nbsp;├"
			else
				NewProClass(3,k)=NewProClass(3,k)&"-"
			end if
		next
	next
'****************************重新排列顺序******************************

for search_j = 0 to i
	search_kkt.set_var "ClassID", NewProClass(0,search_j), false	
	search_kkt.set_var "ClassName", NewProClass(3,search_j)&NewProClass(1,search_j), false	
	search_kkt.parse "b", "ClassList", true	
next

for search_j = 0 to ubound(searchkeypro,2)
	search_kkt.set_var "key", searchkeypro(0,search_j), false	
	search_kkt.parse "c", "searchkey", true	
next

search_kkt.parse "out", "hndKktTemp", false      				
search_kkt.p "out"                              			
set search_kkt = nothing              			
%>