s2l7.bas

TI公司54XX系列DSP程序.很好实用的哦！

Option Explicit
'**********************************************************************
'* S2L7.bas - (Section 2, Lesson 7) RECEIVING DATA FROM THE ALL CHANNEL
'*            This is the RTDX Host Client for Section 2, Lesson 7
'*
'* This example receives integer values 1-3 from the target via the
'* ALL channel
'**********************************************************************

Const Success = &H0                     ' Method call is valid
Const Failure = &H80004005              ' Method call failed
Const ENoDataAvailable = &H8003001E     ' No data was available.
                                        ' However, more data may be
                                        ' available in the future.
Const EEndOfLogFile = &H80030002        ' No data was available
                                        ' The end of the log file has
                                        ' been reached.


Sub main()

    Dim rtdx As Object
    Dim data As Integer
    Dim status As Long
    Dim i As Long

    On Error GoTo Error_Handler

    ' Create an instance of the RTDX COM object
    Set rtdx = CreateObject("RTDX")

    '******************************************************************
    ' Insert code from Step #3 here - to open the "ALL" channel for
    '                                 reading
    '******************************************************************
    status = rtdx.Open("ALL", "R")

    If status <> Success Then
        Debug.Print "Opening of channel ALL failed"
        GoTo Error_Handler
    End If

    Do
        ' Read a 16-bit integer from the target
        status = rtdx.ReadI2(data)
        
        Select Case (status)
            Case Success
                If status = Success Then
                    Debug.Print "Value " & _
                                data & _
                                " was received from the target"
                End If
            Case ENoDataAvailable
                Debug.Print "No data is currently available"
            Case EEndOfLogFile
                Debug.Print "End of log file has been detected"
            Case Failure
                Debug.Print "ReadI2 returned failure"
                Exit Do
            Case Else
                Debug.Print "Unknown return code"
                Exit Do
        End Select
    Loop Until status = EEndOfLogFile

    ' Close the channel
    status = rtdx.Close()

    ' Release the reference to the RTDX COM object
    Set rtdx = Nothing

    Exit Sub

Error_Handler:
Debug.Print "Error in COM method call"
Set rtdx = Nothing

End Sub