form1.frm

Visual Basic开发实用编程200例 数据库编程实例

VERSION 5.00
Object = "{65E121D4-0C60-11D2-A9FC-0000F8754DA1}#2.0#0"; "MSCHRT20.OCX"
Begin VB.Form Form1 
   Caption         =   "用图表显示数据"
   ClientHeight    =   5040
   ClientLeft      =   4005
   ClientTop       =   1530
   ClientWidth     =   7200
   LinkTopic       =   "Form1"
   PaletteMode     =   1  'UseZOrder
   ScaleHeight     =   5040
   ScaleWidth      =   7200
   Begin MSChart20Lib.MSChart MSChart1 
      Height          =   3975
      Left            =   240
      OleObjectBlob   =   "Form1.frx":0000
      TabIndex        =   0
      ToolTipText     =   "1960到2000年人口增长趋势"
      Top             =   720
      Width           =   6615
   End
   Begin VB.Label Label1 
      BackStyle       =   0  'Transparent
      Caption         =   "折 线 图"
      BeginProperty Font 
         Name            =   "隶书"
         Size            =   15.75
         Charset         =   134
         Weight          =   400
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      Height          =   375
      Left            =   2760
      TabIndex        =   1
      Top             =   120
      Width           =   1455
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private Values() As Single
Private NumPoints As Integer

Private Sub LoadData()
Dim db As Database
Dim qdef As QueryDef
Dim rs As Recordset
Dim dbname As String
Dim i As Integer

    ' 打开数据库
    dbname = App.Path
    If Right$(dbname, 1) <> "\" Then dbname = dbname & "\"
    dbname = dbname & "data.mdb"
    Set db = OpenDatabase(dbname)

    ' 获得数据库记录
    Set qdef = db.CreateQueryDef("", _
        "SELECT Year, Value FROM YearlyValues")
    Set rs = qdef.OpenRecordset(dbOpenSnapshot)
    
    ' 查看数据库中记录数
    rs.MoveLast
    NumPoints = rs.RecordCount
    ReDim Values(1 To NumPoints, 1 To 2)

    ' 加载数据
    rs.MoveFirst
    For i = 1 To NumPoints
        Values(i, 1) = Format$(rs!Year, "yyyy")
        Values(i, 2) = rs!Value
        rs.MoveNext
    Next i

    rs.Close
    db.Close
End Sub

Private Sub MakeData()
Const NUM_POINTS = 40
Dim db As Database
Dim dbname As String
Dim i As Integer
Dim the_year As Date
Dim the_value As Single
Dim sql As String

    ' 打开数据库
    dbname = App.Path
    If Right$(dbname, 1) <> "\" Then dbname = dbname & "\"
    dbname = dbname & "data.mdb"
    Set db = OpenDatabase(dbname)

    
    sql = "DELETE FROM YearlyValues"
    db.Execute sql
    
    ' 插入数据
    the_year = #1/1/1960#
    the_value = 1000
    For i = 1 To 38
        sql = "INSERT INTO YearlyValues VALUES (#" & _
            Format$(the_year) & "#, " & _
            Format$(the_value) & ")"
        db.Execute sql
        
        the_year = DateAdd("yyyy", 1, the_year)
        the_value = the_value + Rnd * 2
    Next i

    db.Close
End Sub

Private Sub Form_Load()
Const MAKING_DATA = False

    If MAKING_DATA Then
        MakeData
        Unload Me
    Else
        LoadData
    
        '发送数据到MSChart控件
        MSChart1.chartType = VtChChartType2dXY
        MSChart1.RowCount = NumPoints
        MSChart1.ColumnCount = 2
        MSChart1.ChartData = Values
    End If
End Sub