timerun.dpr

作为服务

program TimeRun;

uses
  sharemem,
  Forms,
  windows,
  Messages,
  Types,
  Graphics,
  UnitMain in 'UnitMain.pas' {FrmRun},
  Common in 'Common.pas',
  DMCommon in 'DMCommon.pas' {DM: TDataModule};

{$R *.res}
var
  hMutex: THandle;
  FoundWnd: THandle;
  ModuleName: string;
const
  WM_NOTIFYICON = WM_User + 10;

//枚举窗口  
function EnumWndProc (hwnd: THandle; Param: Cardinal): Bool; stdcall;
var
  ClassName, WinModuleName: string;
  WinInstance: THandle;
begin
  Result := True;
  SetLength (ClassName, 100);
  GetClassName (hwnd, PChar (ClassName), Length (ClassName));
  ClassName := PChar (ClassName);
  if ClassName = TFrmRun.ClassName then
  begin
    // get the module name of the target window
    SetLength (WinModuleName, 200);
    WinInstance := GetWindowLong (hwnd, GWL_HINSTANCE);
    GetModuleFileName (WinInstance,
      PChar (WinModuleName), Length (WinModuleName));
    WinModuleName := PChar(WinModuleName); // adjust length

    // compare module names
    if WinModuleName = ModuleName then
    begin
      FoundWnd := Hwnd;
      Result := False; // stop enumeration
    end;
  end;
end;
//=============================================================================

var
  multi: Boolean = False;
begin
  HMutex := CreateMutex (nil, False, 'VDFill');
  if multi or (WaitForSingleObject (hMutex, 0) <> wait_TimeOut) then
  begin
    Application.Initialize;
    //------------------------------------------------------------------
    Application.Title := '系统软件监视程序';
    Application.ShowMainForm := False;
    Sleep(50);
    //------------------------------------------------------------------
    Application.CreateForm(TFrmRun, FrmRun);
  Application.Run;
  end
  else
  begin
    // get the current module name
    SetLength (ModuleName, 200);
    GetModuleFileName (HInstance, PChar (ModuleName), Length (ModuleName));
    ModuleName := PChar (ModuleName); // adjust length
    // find window of previous instance
    EnumWindows (@EnumWndProc, 0);
    if FoundWnd <> 0 then
    begin
      { show the window, eventually }
      if not IsWindowVisible (FoundWnd) then PostMessage(FoundWnd, WM_NOTIFYICON, 0, WM_LBUTTONDBLCLK);
      SetForegroundWindow(FoundWnd);
    end;
  end;
end.