frmmain.frm

Winsock Auto Find Server

VERSION 5.00
Object = "{248DD890-BB45-11CF-9ABC-0080C7E7B78D}#1.0#0"; "MSWINSCK.OCX"
Begin VB.Form frmMain 
   Caption         =   "Client"
   ClientHeight    =   5205
   ClientLeft      =   60
   ClientTop       =   450
   ClientWidth     =   8400
   LinkTopic       =   "Form1"
   ScaleHeight     =   5205
   ScaleWidth      =   8400
   StartUpPosition =   3  'Windows Default
   Begin VB.Timer Timer1 
      Interval        =   333
      Left            =   1350
      Top             =   180
   End
   Begin VB.CommandButton cmdSend 
      Caption         =   "&Send"
      Height          =   285
      Left            =   7245
      TabIndex        =   2
      Top             =   4725
      Width           =   1005
   End
   Begin VB.TextBox txtSendMessage 
      Height          =   285
      Left            =   90
      TabIndex        =   1
      Top             =   4725
      Width           =   7035
   End
   Begin MSWinsockLib.Winsock SckTCP 
      Left            =   765
      Top             =   180
      _ExtentX        =   741
      _ExtentY        =   741
      _Version        =   393216
   End
   Begin MSWinsockLib.Winsock SckUDP 
      Left            =   180
      Top             =   180
      _ExtentX        =   741
      _ExtentY        =   741
      _Version        =   393216
   End
   Begin VB.ListBox lstMessages 
      Height          =   4545
      Left            =   90
      TabIndex        =   0
      Top             =   90
      Width           =   8160
   End
End
Attribute VB_Name = "frmMain"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

' Made By Michael Ciurescu (CVMichael)


Private Const DiscoveryPort As Long = 4112 ' ports are reversed from the server
Private Const ResponsePort As Long = 4111

Private ServerIP As String
Private ServerPort As Long

Private Sub Form_Load()
    SckUDP.Close
    SckUDP.Protocol = sckUDPProtocol
    SckUDP.RemoteHost = "255.255.255.255"
    SckUDP.LocalPort = DiscoveryPort
    SckUDP.RemotePort = ResponsePort
    SckUDP.Bind DiscoveryPort
    
    ' Broadcast, and ask where the server is
    SckUDP.SendData "CLIENT|What's your IP ?"
End Sub

Private Sub SckUDP_DataArrival(ByVal bytesTotal As Long)
    Dim MSG As String
    
    ' Received message from server
    SckUDP.GetData MSG, vbString
    
    If MSG Like "SERVER|*" Then ' Received message from server
        ServerIP = Split(Split(MSG, "|")(1), ",")(0)
        ServerPort = Val(Split(Split(MSG, "|")(1), ",")(1))
        
        If Len(ServerIP) > 0 And ServerPort > 0 Then
            ConnectToServer
        End If
    End If
End Sub

Private Sub ConnectToServer()
    With SckTCP
        .Close
        .RemoteHost = ServerIP
        .RemotePort = ServerPort
        
        .Connect
    End With
End Sub

Private Sub txtSendMessage_KeyPress(KeyAscii As Integer)
    If KeyAscii = 13 Then
        cmdSend_Click
        KeyAscii = 0
    End If
End Sub

Private Sub cmdSend_Click()
    If Len(Me.txtSendMessage.Text) > 0 Then
        SckTCP.SendData Me.txtSendMessage.Text
        
        On Error Resume Next
        lstMessages.AddItem "Client: " & Me.txtSendMessage.Text
        lstMessages.TopIndex = lstMessages.ListCount
        
        Me.txtSendMessage.Text = ""
    End If
End Sub

Private Sub SckTCP_DataArrival(ByVal bytesTotal As Long)
    Dim MSG As String
    
    SckTCP.GetData MSG, vbString
    
    lstMessages.AddItem "Server: " & MSG
    On Error Resume Next
    lstMessages.TopIndex = lstMessages.ListCount
End Sub

Private Sub Timer1_Timer()
    Dim TmpStr As String
    
    TmpStr = "Client - " & Choose(SckTCP.State + 1, "Closed", "Open", "Listening", "Connection pending", "Resolving host", "Host resolved", "Connecting", "Connected", "Server is disconnecting", "Error")
    
    If Me.Caption <> TmpStr Then Me.Caption = TmpStr
End Sub