cls_upload.asp

后台管理系统

	' ============================================
	' 执行保存上传文件
	' ============================================
	Public Sub SaveUpFile()
		'On Error Resume Next
		Select Case CInt(Upload_Type)
			Case 0
				ObjName = "拓网无组件上传类 Version 1.0" 
				Set UploadObj = New Cls_UploadClass
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_0
				End If
			Case 1
				ObjName = "Aspupload3.0组件"
				Set UploadObj = Server.CreateObject(ServerObject_011) 
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_1
				End If
			Case 2
				ObjName = "SA-FileUp 4.0组件"
				Set UploadObj = Server.CreateObject(ServerObject_013)
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_2
				End If
			Case 3
				ObjName = "DvFile.Upload V1.0组件"
				Set UploadObj = Server.CreateObject(ServerObject_014)
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_3
				End If
			Case 4
				ObjName = "IronSoft.Upload组件"
				Set UploadObj = Server.CreateObject(ServerObject_020)
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_4
				End If
			Case 5
				ObjName = "LyfUpload.UploadFile"
				Set UploadObj = Server.CreateObject(ServerObject_021)
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_5
				End If
			Case 6
				ObjName = "w3.Upload"
				Set UploadObj = Server.CreateObject(ServerObject_022)
				If Err.Number<>0 Then
					ErrCodes = 1
				Else
					SaveFile_6
				End If
			Case Else
				ErrCodes = 2
		End Select
	End Sub

	' ========================================================================================
	' 上传处理过程 
	' ========================================================================================
	' ============================================
	' 拓网无组件上传类 Version 1.0
	' ============================================
	Private Sub SaveFile_0()
		On Error Resume Next
		Dim i
		Dim FormName,Item, File
		Dim FileExt, FileName, FileType, FileToBinary, FileSize
		' 设置属性
		UploadObj.MaxSize 	= FileMaxSize	' 单文件大小
		UploadObj.FileType  = Replace(InceptFile, ",", "/")	' 文件类型
		UploadObj.SavePath 	= FilePath	' 保存路径
		UploadObj.UpLoadPID = p_UpLoadPID ' 上传进度数据文件名称
		UploadObj.AutoSave 	= 2 ' 设置为手动保存
		UploadObj.Open() ' 打开对象
		FileToBinary = Null
		' 检查错误
		If Not IsEmpty(SessionName) Then
			If Session(SessionName) <> UploadObj.Form(SessionName) Or Session(SessionName) = Empty Then
				ErrCodes = 7
				Exit Sub
			End If
		End If
		If UploadObj.Error > 0 then
			Select Case UploadObj.Error
				Case 1 : ErrCodes = 4
				Case 2 : ErrCodes = 5
				Case 3 : ErrCodes = 8
				Case 4 : ErrCodes = 9
			End Select
			Exit Sub
		Else
			' 执行保存
			For i = 1 To UBound(UploadObj.FileItem) 		''列出所有上传了的文件
				FormName = UploadObj.FileItem(i)
				If Count > MaxFile Then
					ErrCodes = 6
					Exit Sub
				End If
				OldFileName = UploadObj.Form(FormName & "_Name") ' 原文件名
				FileExt = LCase(UploadObj.Form(FormName & "_Ext")) ' 检测文件扩展名
				FileName = FormatName(FileExt) ' 检测文件名
				FileType = CheckFiletype(FileExt) ' 检测文件类型
				If IsBinary Then
					FileToBinary = UploadObj.GetData(FormName)
				End If
				FileSize = ChkNumeric(UploadObj.Form(FormName & "_Size"))
				If FileSize > 0 Then
					UploadObj.Save FormName, FileName
					AddData FormName , _ 
							FileName , _
							FilePath , _
							FileSize , _
							UploadObj.Form(FormName & "_Type") , _
							FileType , _
							FileToBinary , _
							FileExt , _
							UploadObj.Form(FormName & "_Width") , _
							UploadObj.Form(FormName & "_Height"),_
							ClsPub.CreateId(0,RanNums)
					Count = Count + 1
					CountSize = CountSize + UploadObj.Form(FormName & "_Size")
				End If
			Next
			For i = 0 To UBound(UploadObj.FormItem)
				If UploadForms.Exists(UploadObj.FormItem(i)) Then
					UploadForms(i) = UploadObj.FormItem(i) & ", " & UploadObj.FormItem(i)
				Else
					UploadForms.Add i, UploadObj.FormItem(i)
				End If
			Next
			If Not IsEmpty(SessionName) Then Session(SessionName) = Empty
		End If
	End Sub
	' ============================================
	' Aspupload3.0组件上传
	' ============================================
	Private Sub SaveFile_1()
		On Error Resume Next
		Dim FileCount
		Dim FormName,Item,File
		Dim FileExt,FileName,FileType,FileToBinary
		UploadObj.OverwriteFiles = False
		UploadObj.IgnoreNoPost = True
		UploadObj.SetMaxSize FileMaxSize, True
		FileCount = UploadObj.Save
		FileToBinary = Null
		If Not IsEmpty(SessionName) Then
			If Session(SessionName) <> UploadObj.Form(SessionName) or Session(SessionName) = Empty Then
				ErrCodes = 7
				Exit Sub
			End If
		End If
		If Err.Number = 8 Then
				ErrCodes = 4
				Exit Sub
		Else 
				If Err <> 0 Then
					ErrCodes = -1
					Response.Write "错误信息: " & Err.Description
					Exit Sub
				End If
				If FileCount < 1 Then 
					ErrCodes = 3
					Exit Sub
				End If
				For Each File In UploadObj.Files
					If File.Size>FileMaxSize Then
						ErrCode=4
						Exit Sub
					End If
					If Count>MaxFile Then
						ErrCodes = 6
						Exit Sub
					End If
					FileExt = FixName(Replace(File.Ext,".",""))
					If CheckFileExt(FileExt) = False then
						ErrCodes = 5
						Exit Sub
					End If
					OldFileName = File.FileName
					FileName = FormatName(FileExt)
					FileType = CheckFiletype(FileExt)
					If IsBinary Then
						FileToBinary = File.Binary
					End If
					If File.Size>0 Then
						File.SaveAs Server.Mappath(FilePath & FileName)
						AddData File.Name , _ 
							FileName , _
							FilePath , _
							File.Size , _
							File.ContentType , _
							FileType , _
							FileToBinary , _
							FileExt , _
							File.ImageWidth , _
							File.ImageHeight,_
							ClsPub.CreateId(0,RanNums)
						Count = Count + 1
						CountSize = CountSize + File.Size
					End If
				Next
				For Each Item in UploadObj.Form
					If UploadForms.Exists (Item) Then _
						UploadForms(Item) = UploadForms(Item) & ", " & Item.Value _
					Else _
						UploadForms.Add Item.Name , Item.Value
				Next
				If Not IsEmpty(SessionName) Then Session(SessionName) = Empty
		End If
	End Sub

	' ============================================
	' SA-FileUp 4.0组件上传FileUpSE V4.09
	' ============================================
	Private Sub SaveFile_2()
		On Error Resume Next
		Dim FormName,Item,File,FormNames
		Dim FileExt,FileName,FileType,FileToBinary
		Dim Filesize,ImageHeight,ImageWidth
		FileToBinary = Null
		If Not IsEmpty(SessionName) Then
			If Session(SessionName) <> UploadObj.Form(SessionName) or Session(SessionName) = Empty Then
				ErrCodes = 7
				Exit Sub
			End If
		End If
		For Each FormName In UploadObj.Form
			FormNames = ""
			If IsObject(UploadObj.Form(FormName)) Then
				If Not UploadObj.Form(FormName).IsEmpty Then
					UploadObj.Form(FormName).Maxbytes = FileMaxSize	'限制大小
					UploadObj.OverWriteFiles = False
					Filesize = UploadObj.Form(FormName).TotalBytes
					If Err.Number<>0 Then
						ErrCodes = -1
						Response.Write "错误信息: " & Err.Description
						Exit Sub
					End If
					If Filesize>FileMaxSize then
						ErrCodes = 4
						Exit Sub
					End If
					FileName	= UploadObj.Form(FormName).ShortFileName	 '原文件名
					OldFileName = FileName
					FileExt		= Mid(Filename, InStrRev(Filename, ".")+1)
					FileExt		= FixName(FileExt)
					If CheckFileExt(FileExt) = False then
						ErrCodes = 5
						Exit Sub
					End If
					FileName = FormatName(FileExt)
					FileType = CheckFiletype(FileExt)
					If IsBinary Then
						FileToBinary = UploadContents (2)
					End If
					If Filesize>0 Then
						UploadObj.Form(FormName).SaveAs Server.MapPath(FilePath & FileName)
						If FileType="1" Then
							Set ClsImage = New NetBuilderImage
							ClsImage.LoadFromFile(Server.MapPath(FilePath&FileName))
							ImageWidth=ClsImage.Width
							ImageHeight=ClsImage.Height
						Else
							ImageWidth=0
							ImageHeight=0
						End If
						AddData FormName , _ 
								FileName , _
								FilePath , _
								FileSize , _
								UploadObj.Form(FormName).ContentType , _
								FileType , _
								FileToBinary , _
								FileExt , _
								ImageHeight , _
								ImageWidth,_
								ClsPub.CreateId(0,RanNums)
						Count = Count + 1
						CountSize = CountSize + Filesize
					End If
				Else
					ErrCodes = 3
					Exit Sub
				End If
			Else
				If UploadObj.FormEx(FormName).Count > 1 Then
					For Each FormNames In UploadObj.FormEx(FormName)
						FormNames = FormNames & ", " & FormNames
					Next
					UploadForms.Add FormName , FormNames
				Else
					UploadForms.Add FormName , UploadObj.Form(FormName)
				End If
			End If
		Next
		If Not IsEmpty(SessionName) Then Session(SessionName) = Empty
	End Sub

	' ============================================
	' DvFile.Upload V1.0组件上传
	' ============================================
	Private Sub SaveFile_3()
		On Error Resume Next
		Dim FormName, Item, File,i
		Dim FileExt, FileName, FileType, FileToBinary
		UploadObj.InceptFileType = InceptFile
		UploadObj.MaxSize = FileMaxSize
		UploadObj.Install
		FileToBinary = Null
		If Not IsEmpty(SessionName) Then
			If Session(SessionName) <> UploadObj.Form(SessionName) Or Session(SessionName) = Empty Then
				ErrCodes = 7
				Exit Sub
			End If
		End If
		If UploadObj.Err > 0 then
			Select Case UploadObj.Err
				Case 1 : ErrCodes = 3
				Case 2 : ErrCodes = 4
				Case 3 : ErrCodes = 5
				Case 4 : ErrCodes = 5
				Case 5 : ErrCodes = -1
			End Select
			Exit Sub
		Else
			For Each FormName In UploadObj.File	
				If Count>MaxFile Then
					ErrCodes = 6
					Exit Sub
				End If
				Set File = UploadObj.File(FormName)
				FileExt = FixName(File.FileExt)
				If CheckFileExt(FileExt) = False then
					ErrCodes = 5
					Exit Sub
				End If
				FileName = FormatName(FileExt)
				OldFileName = File.FileName 
				FileType = CheckFiletype(FileExt)
				If IsBinary Then
					FileToBinary = File.FileData
				End If
				If File.FileSize>0 Then
					UploadObj.SaveToFile Server.mappath(FilePath & FileName), FormName
					AddData FormName , _ 
							FileName , _
							FilePath , _
							File.FileSize , _
							File.FileType , _
							FileType , _
							FileToBinary , _
							FileExt , _
							File.FileWidth , _
							File.FileHeight,_
							ClsPub.CreateId(0,RanNums)
					Count = Count + 1
					CountSize = CountSize + File.FileSize
					UploadForms.Add FormName, FileField&FormName
				End If
				Set File=Nothing
			Next
			If Not IsEmpty(SessionName) Then Session(SessionName) = Empty
		End If
	End Sub

	' ============================================
	' IronSoft.Upload组件
	' ============================================
	Private Sub SaveFile_4()
		On Error Resume Next
		Dim FirstFile,File,i
		Dim FileExt, FileName, FileType, FileToBinary
		UploadObj.MaxUploadSize = FileMaxSize
		If Not IsEmpty(SessionName) Then
			If Session(SessionName) <> UploadObj.Form(SessionName) Or Session(SessionName) = Empty Then
				ErrCodes = 7
				Exit Sub
			End If
		End If
		If UploadObj.ErrorCode > 0 then
			Select Case UploadObj.ErrorCode 
				Case 3
					ErrCodes = 4
					Exit Sub
				Case 5
					ErrCodes = 3
					Exit Sub
				Case Else
					ErrCodes = 10
					Exit Sub
			End Select	
		Else
			For i=0 To UpLoadObj.FileFormLength-1		
				If Count>MaxFile Then
					ErrCodes = 6
					Exit Sub
				End If
				Set File = UpLoadObj.FileByIndex(i)
				If Not File.IsEmpty Then
					FileExt = FixName(File.ExeName)
					If CheckFileExt(FileExt) = False then
						ErrCodes = 5
						Exit Sub
					End If
					FileName = FormatName(FileExt)
					OldFileName = File.FileName
					FileType = CheckFiletype(FileExt)
					If IsBinary Then
						FileToBinary = File.FileContent
					End If
					File.SaveAsFile Server.MapPath(FilePath & FileName)
					AddData FileField&i , _ 
							FileName , _
							FilePath , _
							File.FileSize , _
							File.FileType , _
							FileType , _
							FileToBinary , _
							FileExt , _
							File.ImageHeight , _
							File.ImageWidth,_
							ClsPub.CreateId(0,RanNums)
					Count=Count+1
					CountSize = CountSize + File.FileSize