a6crank.txt

Ansys专题教程

!********************************************************************
! 		1/4拐曲轴参数化生成，并复制成六拐模型的程序   	    *
!                           邵慰严1999.8-2000.2编制                 *
!								    *
!                             2000.3.17 完成复制                    *
!********************************************************************
!
!
/PREP7  
scal=.1                   ! Let nuit from mm->cm
!Define all paras 定义参数（全部长度单位毫米）
D=100*scal		  ! 缸径
S=125*scal                ! 冲程
B=130*scal
!B=136*scal               ! 曲柄宽度
h=25*scal                 ! 曲柄厚度
dj=85*scal                ! 主轴径直径
Lj=34*scal                ! 主轴径长度
dp=70*scal                ! 连杆轴径直径
Lp=42*scal                ! 连杆轴径长度
rj=5*scal                 ! 主轴径圆角半径
rp=5*scal                 ! 连杆轴径圆角半径
e1=6*scal                 ! 下圆比主轴径中心上移量
e2=10*scal                ! 上圆比连杆径中心下移量
e3=5*scal                 ! 连杆径中空偏心量
dpi=28*scal               ! 连杆径中空部分内径（如为零则实心）
dpm=20*scal               ! 连杆径中空部分较小孔内径
Bm=156*scal               ! 辅助线：为作四圆弧倒角而画的两线间距
Ru=b*.4
!Ru=52*scal               ! 辅助线：上圆半径
Rd=57*scal                ! 辅助线：下圆半径
PZ=90 			  ! 爆发压力（KG/CM2）
! define element type 定义元素类型（95）和材料特性
ET,1,SOLID95
!
!*  
UIMP,1,EX, , ,2000000,  
UIMP,1,PRXY, , ,0.27,   
UIMP,1,ALPX, , , ,  
UIMP,1,REFT, , , ,  
UIMP,1,MU, , , ,
UIMP,1,DAMP, , , ,  
UIMP,1,DENS, , ,7.8E-3, 
!*  
!-----------------------------------以下建曲柄臂----
!Begin to create crank web
!开始建立曲柄臂体
!
! Define KPoint 生成接点
K, ,0,0,0,           ! KP1 ，坐标原点，主轴径中心
K, ,0,s/2,0,         ! KP2 ，连杆轴径中心
K, ,0,e1,0,          ! KP3 ，画下圆的辅助圆心点
K, ,0,S/2-e2,0,      ! KP4 ，画上圆的辅助圆心点
!
!
! downcircle 画下圆
KWPAVE, KP(0,e1,0)            !移动工作平面到KP3
CYL4,0,0,Rd                   !画圆面
ADELE,       1                !删除圆
LPLOT                         !显示线
LSEL,U,LOC,Y,-dj/2,0          !选择不删除的线(lower)
LDELE,all, , ,1               !删除多余的线
!
!
! upcircle 画上圆
KWPAVE,KP(0,s/2-e2,0)         !移动工作平面到KP4
CYL4,0,0,Ru                   !画圆面
ADELE,       1                !其余同上
GPLOT                         !惟有显示全部（Multiplot)
LSEL,s,LOC,Y,s/2-e2-ru,s/2    !选择删除的线(lower)
LDELE,all, , ,1               !删除多余的线
allsel,all
Lplot
!
!
! Create web 建曲柄臂
!
KWPAVE,KP(-b*.4,s/2,0)       ! 移动WP
wpro,,,-90.000000            ! 旋转Y轴
LSEL,s,LOC,Y,-dj/2,0  
LSEL,R,LOC,X,-dj/2,0  
LPLOT   
LSBW,       all              ! 切割线段（下圆弧）                ! 切割线段（下圆弧）
!   
allsel,all
KWPAVE, KP(b*.4,s/2,0)       ! 移动WP
LSEL,s,LOC,Y,-dj/2,0  
LSEL,R,LOC,X,0,dj/2  
LSBW,      all               ! 切割线段（下圆弧）
!
!
! Delete 2 small no use lines 删除切割下来的两小线段
LSEL,S,LOC,X,-0.5*b,-0.4*b 
LDELE,all, , ,1
allsel,all
LSEL,S,LOC,X,0.4*b,0.5*b
LDELE,all, , ,1 
!
!
! link 2 lines to create web area 连接两线段,以构成曲柄臂平面
!   
LSTR,      KP(-b*.4,dp/2,0),  11  !KP11 do not solved yet
LSTR,      KP(b*.4,dp/2,0),   12  !KP12 do not solved yet
!   
! create web area 建面
allsel,all
! create web area 建面
AL,all 
!
!
! create area as a web  提拉成曲柄
!
VEXT,all, , ,0,0,h,,,, 
!
!
!Delete 2 scope corners
!删除曲柄两对角
! 
!The first one 第一角
!   
!Select line
!
LSEL,S,LOC,Y,s/2+ru-e2  
LSEL,r,LOC,X,0  
LSEL,r,LOC,Z,0,h
LPLOT   
!*  
!
LDIV,all, , ,4,0                    ! 将上线分为四段
KWPAVE,KP(0,s/2+ru-e2,3*h/4)        ! 移动WP到第三点处
wpro,,,-90.000000                   ! 转动Y轴90度
wpro,,-30.000000,                   ! 转动X轴30度
VSBW,       all                     ! 切割曲柄臂
!
! Delete volume 删除曲柄臂多余体   
VDELE,       2, , ,1
!
! 
BOPT,NUMB,OFF
!
!The seond one 第二角
!
!Select line
!
LSEL,S,LOC,Y,e1-rd
LSEL,r,LOC,X,0  
LSEL,r,LOC,Z,0,h
LPLOT  
!
LDIV,all, , ,4,0                    ! 将下线分为四段
KWPAVE,KP(0,e1-rd,h/4)              ! 移动WP到第三点处
!   
VSBW,       all                     ! 切割曲柄臂 
!
! Delete volume 删除曲柄臂多余体   
VDELE,       1, , ,1
!
!--------------------------------------以上曲柄臂-------
!
!
!--------------------------------------以下建主轴径-----
!create Journal
!建主轴径
!
!
KWPAVE,KP(0,0,0)          !移动WP
WPCSYS,-1,0               !旋转
CYL4,0,0,dj/2             !建回转体
FLST,2,1,5,ORDE,1   
FITEM,2,2   
VEXT,P51X, , ,0,0,-Lj/2,,,,  
!
!
!
!切割曲柄臂平面
!
!竖切一平面
KWPAVE, KP(0,0,0) 
wpro,,,-90.000000   
ASEL,S,LOC,Z,0  
APLOT   
ASBW,      all   
!   
!   
!横切两平面
wpro,,-90.000000,   
!   
ASBW,all   
!
allsel,all
!*  
!将两体黏结
!   
!   
VGLUE,all  
!
!
!----------------------------以上主轴径建摸---------------------------------------
!
!
!----------------------------以下连杆轴径建摸--------------------------------------
!
!
ALLSEL,ALL
VPLOT
!
!Draw crankpin
!画连杆轴径
!  
!
!
K, ,0,s/2,h,
KWPAVE,      KP(0,s/2,h)
wpro,,,-90.000000   
CYL4,0,0,dp/2, , , ,-lp/2   
!   
!   
!devide crankpin area      
!切割曲柄臂平面   
!     
wpro,,90.000000,
VSEL,R,LOC,Z,0,h                  !slelct volume
ALLSEL,BELOW,VOLU                 !Select underbelow
ASEL,R,LOC,Z,h                    !Select area to devide
ASBW,      all                    !cut（竖切）  
!
wpro,,,-90.000000   
ASBW,      all                    !cut（横切）   
!
!   
!  
!Glue web and crankpin  
!将曲柄臂和连杆径体GLUE在一起
!   
allsel,all
VSEL,S,LOC,Z,1.4*RJ,h+Lp/2 
ALLSEL,BELOW,VOLU   
VPLOT   
VGLUE,all
!     
ALLSEL,ALL  
VPLOT  
!
!转工作平面，准备切割曲轴
!
wpro,,,-90.000000   
!
!切割曲轴
!
VSBW,all   
!
!去一半并重新画图
!
VSEL,S,LOC,X,0,b/2  
VDELE,all,,,1
!
allsel,all
/REPLOT 
!
!
!
!Fillet 8 areas 建主轴径圆角，两处四面倒角
!*  
!1 左上角  
ASEL,S,LOC,Z,-Lj/2+Lj/8,0  
ASEL,R,LOC,Y,0,dj/2+rj
ASEL,R,LOC,x,-dj/2,0
APLOT  
!   
!将原点所在的线和面(不选）
!Component ALU=Area of Left and down
CM,ALU,AREA            !将所选的三面存为COMPONENT
ALLSEL,BELOW,AREA       !
KSEL,R, , ,KP(0,0,0)    !选点
LSLK,R                  !选在此点上的线
LPLOT                   !
CMSEL,S,ALU             !重选保存的COMPONENT
ASLL,U                  !不选由两线构成的面
APLOT                   !
!
!仅有两面，对其进行FILLET
*get,A1,Area,,Num,Max,,,
*get,A2,Area,,Num,Min,,,
ALLSEL,BELOW,AREA 
AFILLT,A2,A1,0.5,
!*  
!
!2 左下角 
allsel,all
ASEL,S,LOC,Z,-Lj/2+Lj/8,0  
ASEL,R,LOC,Y,e1-dj/2,0
ASEL,R,LOC,x,-dj/2,0
APLOT  
!   
!
!将原点所在的线和面(不选）
!Component ALD=Area of Left and down
CM,ALD,AREA            !将所选的三面存为COMPONENT
ALLSEL,BELOW,AREA       !
KSEL,R, , ,KP(0,0,0)    !选点
LSLK,R                  !选在此点上的线
LPLOT                   !
CMSEL,S,ALD             !重选保存的COMPONENT
ASLL,U                  !不选由两线构成的面
APLOT                   !
!
!仅有两面，对其进行FILLET
*get,A1,Area,,Num,Max,,,
*get,A2,Area,,Num,Min,,,
ALLSEL,BELOW,AREA 
AFILLT,A2,A1,0.5,
!
!Make volumes of circle fillet
!
!将所产生的圆弧面用关键点（由KP）建主轴径圆角体
!
allsel,all
V,      46,      17,      33,      47,      18,      37 
V,      47,      18,      37,      48,      24,      43 
!   
!横切主轴径
!
KWPAVE,      KP(dj/2,0,-rj) 
wpro,,,-90.000000   
VSEL,S,LOC,Z,-Lj/2,0  
VSEL,R,LOC,Y,-dj/2,dj/2 
VSBW,       all   
!   
!1 主轴径上半  
!ALLSEL,ALL  
VSEL,R,LOC,Y,0,dj/2+rj  !上下（Y方向）定界
VSEL,R,LOC,z,-Lj/2,0    !轴向定界
VPLOT                   !显示所选体
!将体（主轴径与圆角）相加
VADD,all                !相加
ALLSEL,BELOW,VOLU   
!
!add areas   
!将靠曲柄臂处（主轴径与圆角）面相加
ASEL,R,LOC,Z,0  
ALLSEL,BELOW,AREA   
APLOT   
AADD,all   
!
!2
!2 主轴径下半 
!
allsel,all
VSEL,R,LOC,Y,e1-dj/2,0
VSEL,R,LOC,z,-Lj/2,0
VPLOT  
!将体（主轴径与圆角）相加
VADD,all   
ALLSEL,BELOW,VOLU 
!
!add areas   
!将靠曲柄臂处（主轴径与圆角）面相加
ASEL,R,LOC,Z,0  
ALLSEL,BELOW,AREA   
APLOT   
AADD,all   
!
!Reselect volumes to add some more areas and lines
!重选主轴径及圆角体，以便将剩余的面和线相加
!
ALLSEL，ALL
!重选上半体
VSEL,R,LOC,Y,0,dj/2+rj  !上下（Y方向）定界
VSEL,R,LOC,z,-Lj/2,0    !轴向定界
VPLOT                   !显示所选体
!
!add areas   
!将面相加
ALLSEL,BELOW,VOLU   
ASEL,R,LOC,Y,0          !上下半分界面
AADD,all 
ALLSEL，ALL
!
!重选上半体
VSEL,R,LOC,Y,0,dj/2+rj  !上下（Y方向）定界
VSEL,R,LOC,z,-Lj/2,0    !轴向定界
VPLOT                   !显示所选体
!
!add areas   
!将面相加
ALLSEL,BELOW,VOLU   
ASEL,R,LOC,X,0          !子午面 
AADD,all 
ALLSEL，ALL