📄 remark

📁 WAP手机网页XXXXX WAP手机网页XXXXX
💻
字号:
Private blnError
Private strError
Private strHandle
Private objPage
Private rs, strSQL

Private Sub Class_Initialize()
    strHandle = Request.QueryString("Handle")
    blnError = True
    strError = "无错误"
End Sub

Public Sub main()
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Select Case LCase(strHandle)
    Case "list"
        Call doGetList
    Case "option"
        Call doGetOption
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doPost()
    Select Case LCase(strHandle)
    Case "remove"
        Call doPostRemove
    Case Else
        MyIO.Echo "未知操作"
    End Select
End Sub

Private Sub doGetMain()
    MyIO.Echo "<html>"
    MyIO.Echo "<head>"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""no-cache"" />"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""max-age=0"" />"
    MyIO.Echo "<meta http-equiv=""content-type"" content=""text/html; charset=gb2312"" />"
    MyIO.Echo "<title>" & MyKernel.Env("WM_VNAME") & " - 评论管理</title>"
    MyIO.Echo "<link rel=""stylesheet"" href=""images/xw.css"" />"
    MyIO.Echo "<script language=""javascript"" src=""jspp/jspp.js""></script>"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "jspp.Caption = """ & MyKernel.Env("WM_NAME") & """;"
    MyIO.Echo "</script>"
    MyIO.Echo "<script language=""javascript"" src=""images/wm_remark.js""></script>"
    MyIO.Echo "</head>"
    MyIO.Echo "<body style=""padding:5;margin:0;overflow:auto;border:0"">"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"" style=""border:1px solid #000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td align=""right"" bgcolor=""#A2ADC4"" style=""border-bottom:1px solid #000000;padding-right:1px;padding-top:1px"" height=""24""><img src=""images/xw_cls0.gif"" border=""0"" align=""absMiddle"" onMouseOver=""this.src='images/xw_cls1.gif'"" onMouseOut=""this.src='images/xw_cls0.gif'"" onMouseDown=""this.src='images/xw_cls2.gif'"" onMouseUp=""this.src='images/xw_cls1.gif'"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td height=""24"" style=""background-image:url(images/xw_back4.gif)"">&nbsp;</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""98%"" border=""0"" cellpadding=""0"" cellspacing=""0"" align=""center"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td id=""_OPTION"" class=""f12""></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "<iframe id=""console"" name=""console"" frameborder=""0"" scrolling=""no"" width=""0"" height=""0"" style=""display:none""></iframe>"
    MyIO.Echo "</body>"
    MyIO.Echo "</html>"
End Sub

Private Sub doGetOption()
    Select Case Request.QueryString("Option")
    Case "0"
        MyIO.Echo "<form id=""frmMain"" onsubmit=""return(false)"">"
        MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td colspan=""2"" class=""winT0"">"
        MyIO.Echo " <b>所有评论</b>"
        MyIO.Echo " <a href=""javascript:void(0)"" class=""a1"" onclick=""jspp.Remark.doPage(jspp.Remark.page)"">刷新评论列表</a>"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td colspan=""2"" id=""_list_""></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
        MyIO.Echo "</form>"
    Case Else
        MyIO.Echo "未知选项"
    End Select
End Sub

Private Sub doGetList()
    Response.Charset = "utf-8"
    MyIO.CodePage = 65001
    Dim i
    Dim strKey
    Dim strWhere
    strKey = Trim(MyIO.QueryString("Keyword"))
    Set objPage = MyKernel.Page()
    objPage.PageNum = MyIO.QueryString("Page")
    objPage.PageSize = 20
    objPage.dataType = WM_DataType
    objPage.Increment = "Intime"
    objPage.Column = "*"
    objPage.Table = T_REMARK
    strWhere = "1=1"
    If strKey <> "" Then
        strWhere = strWhere & Replace(" AND (Title LIKE '%$(Keyword)%' Or UserName LIKE '%$(Keyword)%' Or Content LIKE '%$(Keyword)%')", "$(Keyword)", SafeString(strKey))
    End If
    objPage.Where = strWhere
    objPage.Sort = "Intime DESC"
    objPage.SortType = True
    Set rs = objPage.Execute()
    MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse;word-break:break-all;word-wrap:break-word;"" bordercolor=""#000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>选择</b></td>"
    MyIO.Echo "<td width=""30%"" class=""winT0""><b>所属内容<b/></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>姓名<b/></td>"
    MyIO.Echo "<td width=""30%"" class=""winT0""><b>评论<b/></td>"
    MyIO.Echo "<td width=""14%"" class=""winT0""><b>时间<b/></td>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>管理</b></td>"
    MyIO.Echo "</tr>"
    If objPage.TotalRow > 0 Then
        i = 0
        Dim objRemark
        Set objRemark = MyKernel.Table(T_REMARK)
        Do While Not rs.EOF And i < objPage.PageSize
            objRemark.Source = rs
            MyIO.Echo "<tr class=""winT1"">"
            MyIO.Echo "<td align=""center""><input type=""checkbox"" id=""SeqId"" name=""SeqId"" value=""" & objRemark("SeqId") & """ /></td>"
            MyIO.Echo "<td>" & Server.HTMLEncode(objRemark("Title")) & "</td>"
            MyIO.Echo "<td>" & objRemark("UserName") & "</td>"
            MyIO.Echo "<td>" & Server.HTMLEncode(objRemark("Content")) & "</td>"
            MyIO.Echo "<td align=""right"">" & FormatTime(getDate(objRemark("Intime")), "YY-MM-DD HH24:MI") & "</td>"
            MyIO.Echo "<td align=""center"">"
            MyIO.Echo "<select class=""sel"" onchange=""jspp.Remark.control(this, " & objRemark("SeqId") & ")"">"
            MyIO.Echo "<option value=""0"">管理</option>"
            MyIO.Echo "<option value=""1"">删除</option>"
            MyIO.Echo "</select>"
            MyIO.Echo "</td>"
            MyIO.Echo "</tr>"
            rs.MoveNext
            i = i + 1
        Loop
        Set objRemark = Nothing
        Call ShowControl
        Call ShowPage
    Else
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td colspan=""6"">尚无任何评论</td>"
        MyIO.Echo "</tr>"
        Call ShowControl
    End If
    MyIO.Echo "</table>"
    If Not rs Is Nothing Then rs.Close
    Set rs = Nothing
    Set objPage = Nothing
End Sub

Private Sub ShowControl()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td align=""center""><input type=""checkbox"" onclick=""chkAll(this)"" /></td>"
    MyIO.Echo "<td colspan=""5"">"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""删除"" onclick=""jspp.Remark.removeAll(this.form)"" />"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""搜索"" onclick=""jspp.Remark.query(this.form)"" />"
    MyIO.Echo " <input name=""Keyword"" type=""text"" class=""txt"" value=""" & Server.HTMLEncode(MyIO.QueryString("Keyword")) & """ />"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub ShowPage()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td colspan=""7"" align=""right"">"
    MyIO.Echo "共 " & objPage.TotalRow & " 条信息 "
    MyIO.Echo objPage.PageSize & " 条/页 "
    MyIO.Echo objPage.PageNum & "/" & objPage.TotalPage & " 页"
    If objPage.PageNum > 1 Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Remark.doPage(1)"" class=""a1"" />首  页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Remark.doPage(" & (objPage.PageNum - 1) & ")"" class=""a1"" />上一页</a>"
    Else
        MyIO.Echo " <a class=""a1"">首  页</a>"
        MyIO.Echo " <a class=""a1"">上一页</a>"
    End If
    If objPage.PageNum < objPage.TotalPage Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Remark.doPage(" & (objPage.PageNum + 1) & ")"" class=""a1"" />下一页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Remark.doPage(" & objPage.TotalPage & ")"" class=""a1"" />尾  页</a>"
    Else
        MyIO.Echo " <a class=""a1"">下一页</a>"
        MyIO.Echo " <a class=""a1"">尾  页</a>"
    End If
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub doPostRemove()
    Response.Charset = "utf-8"
    If MyPower("DeleteRemark") = 0 Then
        MyIO.Echo "您没有删除评论的权限"
    Else
        Dim strId
        Dim arr, i
        strId = Trim(Request.Form("SeqId"))
        If Not IsNumbers(strId) Then
            MyIO.Echo "请先选择您要删除的评论"
        Else
            strSQL = "SELECT CONTENTID FROM $(Table) WHERE SEQID IN ($(SeqId))"
            strSQL = Replace(strSQL, "$(Table)", T_REMARK)
            strSQL = REplace(strSQL, "$(SeqId)", strId)
            arr = MyKernel.DB.getRecords(strSQL)
            If Not IsArray(arr) Then
                MyIO.Echo "找不到您要删除的评论"
            Else
                strSQL = "UPDATE $(Table) SET REMARKTOTAL=REMARKTOTAL-1 WHERE SEQID=$(SeqId)"
                strSQL = Replace(strSQL, "$(Table)", T_CONTENT)
                For i = 0 To UBound(arr, 2)
                    MyKernel.DB.Exec Replace(strSQL, "$(SeqId)", arr(0, i))
                Next
                strSQL = "DELETE FROM $(Table) WHERE SEQID IN ($(SeqId))"
                strSQL = Replace(strSQL, "$(Table)", T_REMARK)
                strSQL = REplace(strSQL, "$(SeqId)", strId)
                MyKernel.DB.Exec strSQL
                MyIO.Echo "OK"
            End If
        End If
    End If
End Sub
💿 文件大小 2070 K
👤 上传用户 dongchenxi2
📂 所属分类手机WAP编程
🏷️ 相关标签

#XXXXX #WAP #手机 #页
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -