remove

WAP手机网页XXXXX WAP手机网页XXXXX

Public Sub main()
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Response.Charset = "utf-8"
    Dim strTarget
    Dim strName
    Dim lngSeqId
    strTarget = LCase(Request.QueryString("Target"))
    strName = LCase(Request.QueryString("Name"))
    lngSeqId = atol(Request.QueryString("SeqId"))
    Select Case strTarget
    Case "site"
        If strName = "logo" Then
            ClearImage "logo"
            MyKernel.Config("SiteLogo") = ""
            MyIO.Echo "OK"
        ElseIf strName = "backimage" Then
            ClearImage "backimage"
            MyKernel.Config("BackImage") = ""
            MyIO.Echo "OK"
        ElseIf strName = "backsound" Then
            ClearFile "backsound", "AllowRing"
            MyKernel.Config("BackSound") = ""
            MyIO.Echo "OK"
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case "staple"
        If lngSeqId = 0 Then
            MyIO.Echo "请选择您要删除的文件"
        ElseIf strName = "icon" Then
            ClearImage "icon" & lngSeqId
            MyKernel.DB.Exec "UPDATE " & T_STAPLE & " SET Icon='' WHERE SeqId=" & lngSeqId
            MyIO.Echo "OK"
        ElseIf strName = "logo" Then
            ClearImage "logo" & lngSeqId
            MyKernel.DB.Exec "UPDATE " & T_STAPLE & " SET Logo='' WHERE SeqId=" & lngSeqId
            MyIO.Echo "OK"
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case "matter"
        If lngSeqId = 0 Then
            MyIO.Echo "请选择您要删除的素材"
        ElseIf strName = "jad" Or strName = "preview" Then
            DeleteOther strName, lngSeqId
        ElseIf strName = "all" Then
            DeleteMatter lngSeqId
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case Else:
        MyIO.Echo "未知操作[" & strTarget & "]"
    End Select
End Sub

Private Sub doPost()
End Sub

Private Sub DeleteOther(ByVal strHandle, ByVal lngId)
    Dim objMatter
    Dim strName
    Dim strPath
    Dim fso
    Set fso = vbsre.mocom.util.com.forName("Scripting.FileSystemObject")
    Set objMatter = MyKernel.Table(T_MATTER)
    If objMatter.Execute("*", "SeqId=" & atol(lngId)) Then
        strName = getMatterName(objMatter("Category")) & "/" & FormatTime(getDate(objMatter("Intime")), "YYYYMMDD") & "/" & Hex(objMatter("Mark"))
        If strHandle = "jad" Then
            strPath = getMapPath("images/" & strName & ".jad")
            If fso.FileExists(strPath) Then
                fso.DeleteFile strPath
            End If
        Else
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
            MyKernel.DB.Exec "UPDATE " & T_MATTER & " SET Preview='' WHERE SeqId=" & objMatter("SeqId")
        End If
        MyIO.Echo "OK"
    Else
        MyIO.Echo "未找不到您要删除的" & IIf(strHandle = "jad", "JAD 文件", "预览图片")
    End If
    Set objMatter = Nothing
    Set fso = Nothing
End Sub

Private Sub DeleteMatter(ByVal lngId)
    Dim objMatter
    Dim strName, intCate
    Dim strPath
    Set objMatter = MyKernel.Table(T_MATTER)
    If objMatter.Execute("*", "SEQID=" & atol(lngId)) Then
        intCate = objMatter("Category")
        strName = getMatterName(intCate) & "/" & FormatTime(getDate(objMatter("Intime")), "YYYYMMDD") & "/" & Hex(objMatter("Mark"))
        If intCate = wmTypeImage Then
            ClearImage strName & "D"
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
        ElseIf intCate = wmTypeVideo Or intCate = wmTypeSoft Then
            ClearFile strName, IIf(intCate = wmTypeVideo, "AllowVideo", "AllowSoft")
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
        Else
            ClearFile strName, "AllowRing"
        End If
        MyKernel.DB.Exec "DELETE FROM " & T_MATTER & " WHERE SEQID=" & objMatter("SeqId")
        MyKernel.DB.Exec "UPDATE " & T_CONTENT & " SET MATTER=0 WHERE MATTER=" & objMatter("Mark")
        MyIO.Echo "OK"
    Else
        MyIO.Echo "未找不到您要删除的素材"
    End If
    Set objMatter = Nothing
End Sub