cache.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomUtilCache
Public Expires

Private Function getCacheName(ByVal strName)
    getCacheName = Replace(Replace("VBS.Cache.$(Name)", "$(Name)", strName), ".", "_")
End Function

Public Default Property Get Item(ByVal strName)
    Dim strCache
    strCache = getCacheName(strName)
    If Not IsEmpty(Application(strCache)) Then
        Expires = Application(strCache & "_Expires")
        If DateDiff("s", Expires, Now()) < 0 Then'未超时
            If IsObject(Application(strCache)) Then
                Set Item = Application(strCache)
            Else
                Item = Application(strCache)
            End If
        End If
    End If
End Property

Public Property Let Item(ByVal strName, vtIn)
    Dim strCache
    strCache = getCacheName(strName)
    Application.Lock
    If IsObject(vtIn) Then
        Set Application(strCache) = vtIn
    Else
        Application(strCache) = vtIn
    End If
    Application(strCache & "_Expires") = Expires
    Application.Unlock
End Property

Public Sub Remove(ByVal strName)
    Dim strCache
    strCache = getCacheName(strName)
    Application.Lock
    If IsObject(Application(strCache)) Then
        Set Application(strCache) = Nothing
    End If
    Application(strCache) = Empty
    Application(strCache & "_Expires") = Empty
    Application.Unlock
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomUtilCache
End Function
End Class
%>