register.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomWAPmoWAPRegister
Private blnError
Private strError
Private strReferer

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
    blnError = True
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    strReferer = Request.QueryString("Referer")
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("SiteName") & "会员注册"
    MyXML.Align = "left"
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    If strReferer <> "" Then
        MyXML.Println CreateA(strReferer, "快速返回", getImagePrefix("back.gif"))
    End If
    Call BackHomeX(0)
    Call setLog("register", 0)
    MyXML.Transform Response
End Sub

Private Sub doGet()
    MyXML.Println "标记为*的表单必填"
    MyXML.SetF getURL("register.asp", "Referer", strReferer), "post", "", True
    MyXML.SetN "Nick", "text", "", "昵 称[*]：", " 中英文或数字，不能超过20个字节（即10个汉字）", True
    MyXML.SetN "Passwd", "password", "", "密 码[*]：", " 最少6位", True
    MyXML.SetN "Mobile", "text", "", "手机号码：", " 手机号码是取回密码的凭证", True
    MyXML.SetN "", "submit", "确定", "", "", True
    MyXML.Printf "已经注册了？"
    MyXML.Println CreateA(getURL("login.asp", "Referer", strReferer), "点此登录", "")
    MyXML.Printf "忘记密码了？"
    MyXML.Println CreateA(getURL("forget.asp", "Referer", strReferer), "点此取回", "")
End Sub

Private Sub doPost()
    Dim strNick, strPass, strMobile
    If MyIO.Parse(KBYTE) <> 0 Then
        strError = "超过最大数据请求长度：" & KBYTE
    Else
        strNick = Trim(MyIO.Form("Nick"))
        strPass = Trim(MyIO.Form("Passwd"))
        strMobile = Trim(MyIO.Form("Mobile"))
        If strNick = "" Then
            strError = "请输入您的昵称"
        ElseIf strPass = "" Then
            strError = "请输入您的密码"
        ElseIf strMobile <> "" And Not ValidMobile(strMobile) Then
            strError = "手机号码格式错误"
        ElseIf InString(MyKernel.Config("ForbidName"), strNick, False) = True Then
            strError = "该昵称已被占用了"
        ElseIf LenC(strNick) > 20 Then
            strError = "昵称的长度不能超过20个字节（即10个汉字）"
        ElseIf Len(strPass) < 6 Then
            strError = "密码位数必须不能小于6"
        ElseIf ValidName(strNick) = False Then
            strError = "不要在昵称中使用中英文以及数字以外的字符"
        Else
            Dim rs, strSQL
            Dim lngUserId, lngTime
            strSQL = getLimitSQL(1, "*", T_USER, "NICK='$(Nick)'", "", "")
            strSQL = Replace(strSQL, "$(Nick)", SafeString(strNick))
            If WM_DataType = adMySQL Then
                Set rs = Server.CreateObject("ADODB.RecordSet")
                rs.CursorLocation = adUseClient
                rs.Open strSQL, MyKernel.DB.ActiveConnection, adOpenKeyset, adLockOptimistic, adCmdText
            Else
                Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            End If
            If Not rs.EOF Then
                strError = "该昵称已被占用了"
            Else
                lngUserId = getUserId() + 1
                lngTime = getTime(Now())
                blnError = False
                strError = "恭喜您成为[" & Mykernel.Config("SiteName") & "]会员" & vbCrLf & _
                    "您的昵称：" & strNick & vbCrLf & _
                    "您的密码：" & strPass & vbCrLf & _
                    "现在您可以尽情使用本站提供的服务了！"
                rs.AddNew
                rs("Nick") = strNick
                rs("Passwd") = MD5(strPass)
                rs("Mobile") = strMobile
                rs("UserId") = lngUserId
                rs("Status") = wmUserRegister
                rs("RegisterTime") = lngTime
                rs("RegisterIP") = MyKernel.Env("GATEWAY_ADDR")
                rs("FirstUsedTime") = lngTime
                rs("FirstUsedIP") = MyKernel.Env("GATEWAY_ADDR")
                rs("VisitCount") = 1
                rs("PageCount") = 1
                rs("FirstUserAgent") = Request.ServerVariables("HTTP_USER_AGENT")
                rs("LastLogin") = 0
                rs("MarkerTotal") = 0
                rs("LastBook") = 0
                rs("BookTotal") = 0
                rs("LastRemark") = 0
                rs("RemarkTotal") = 0
                rs("MsgSend") = 0
                rs("MsgRecv") = 0
                rs("MsgNew") = 0
                rs.Update
                rs.Filter = "SEQID=" & rs("SeqId")
                setUserId lngUserId
                MyKernel.Query("MEMID") = MyKernel.Memory.MemoryId
                Call AsyncMemory(rs)
                If AddOnline(rs("UserId"), strNick, lngTime) Then
                    Call setStat(stRegToday & "|" & stRegAll & "|" & stVisitToday, 1)
                End If
            End If
            rs.Close
            Set rs = Nothing
        End If
    End If
    MyXML.Println strError
    If blnError Then
        Call doGet
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPRegister
End Function
End Class
%>