article.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomWAPmoWAPBbsArticle
Private lngForumId, lngArtId
Private intPageNo, intPageId

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("BBSTitle")
    MyXML.Align = "left"
    lngForumId = atol(Request.QueryString("ForumId"))
    lngArtId = atol(Request.QueryString("ArticleId"))
    intPageNo = atoi(Request.QueryString("PageNo"))
    intPageId = atoi(Request.QueryString("PageId"))
    If MyKernel.Config("IsBBS") <> "1" Then
        MyXML.Println "该功能已被站长关闭"
    ElseIf lngForumId < 1 Then
        MyRedirect "bbs/index.asp"
    ElseIf lngArtId < 1 Then
        MyRedirect "bbs/forum.asp?ForumId=" & lngForumId
    ElseIf Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    MyXML.Println CreateA("bbs/index.asp", "返回" & MyKernel.Config("BBSTitle"), getImagePrefix("back.gif"))
    Call BackHomeX(BBS_SEQID)
    Call setLog("bbs", 0)
    MyXML.Transform Response
End Sub

Private Sub doGet()
    Dim rs, strSQL
    Dim objArt
    strSQL = getLimitSQL(1, "*", T_ARTICLE, "FORUMID=$(ForumId) AND SEQID=$(SeqId)", "", "")
    strSQL = Replace(strSQL, "$(ForumId)", lngForumId)
    strSQL = Replace(strSQL, "$(SeqId)", lngArtId)
    Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
    Set objArt = MyKernel.Table(T_ARTICLE)
    If rs.EOF Then
        MyXML.Println "找不到您要访问的帖子"
    Else
        objArt.Source = rs
        rs("Hit") = rs("Hit") + 1
        rs.Update
    End If
    rs.Close
    Set rs = Nothing
    If objArt("SeqId") = lngArtId Then
        MyXML.Println "[" & objArt("ForumName") & "]"
        MyXML.Printf CreateA("bbs/post.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo, "我要发帖", "")
        MyXML.Printf " "
        MyXML.Println CreateA("bbs/post.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo & "&ArticleId=" & lngArtId & "&PageId=" & intPageId, "我要回帖", "")
        MyXML.Println "标题：" & objArt("Title")
        If intPageId < 2 Then
            MyXML.Println "内容：" & FormatWord(MyKernel.Config("ForbidWord"), objArt("Content"))
            If Not ValidCoop() And MyKernel.Config("IsMsgbox") = "1" Then
                MyXML.Printf "作者："
                MyXML.Println CreateA(getMsgboxSendURL(objArt("UserId")), objArt("UserName"), "")
            Else
                MyXML.Println "作者：" & objArt("UserName")
            End If
            MyXML.Println "时间：" & FormatTime(getDate(objArt("Intime")), "YYYY-MM-DD HH24:MI:SS")
        End If
        Call doGetArticle
        MyXML.Println String(16, "-")
        MyXML.Println CreateA("bbs/forum.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo, "返回" & objArt("ForumName"), getImagePrefix("back.gif"))
    End If
    Set objArt = Nothing
End Sub

Private Sub doPost()
End Sub

Private Sub doGetArticle()
    Dim clsPage
    Dim rs
    Dim i
    Set clsPage = MyKernel.Page()
    clsPage.PageNum = Request.QueryString("PageId")
    clsPage.PageSize = 10
    clsPage.DataType = WM_DataType
    clsPage.Increment = "Intime"
    clsPage.Table = T_ARTICLE
    clsPage.Where = "FORUMID=" & lngForumId & " AND FOLLOW=" & lngArtId
    clsPage.Sort = "INTIME ASC"
    clsPage.SortType = False
    Set rs = clsPage.Execute()
    If clsPage.TotalRow > 0 Then
        i = 0
        Dim objArt
        Set objArt = MyKernel.Table(T_ARTICLE)
        Do While rs.EOF = False And i < clsPage.PageSize
            objArt.Source = rs
            MyXML.Println String(16, "-")
            MyXML.Println "跟帖：" & FormatWord(MyKernel.Config("ForbidWord"), objArt("Content"))
            If Not ValidCoop() And MyKernel.Config("IsMsgbox") = "1" Then
                MyXML.Printf "作者："
                MyXML.Println CreateA(getMsgboxSendURL(objArt("UserId")), objArt("UserName"), "")
            Else
                MyXML.Println "作者：" & objArt("UserName")
            End If
            MyXML.Println "时间：" & FormatTime(getDate(objArt("Intime")), "YYYY-MM-DD HH24:MI:SS")
            rs.MoveNext
            i = i + 1
        Loop
        Set objArt = Nothing
        MyXML.Println ""
        Dim arr1, arr2
        arr1 = Array("ForumId", "PageNo", "ArticleId", "PageId")
        arr2 = Array(lngForumId, intPageNo, lngArtId, 0)
        If clsPage.PageNum < clsPage.TotalPage Then
            arr2(3) = (clsPage.PageNum + 1)
            MyXML.Printf CreateA(getURL("bbs/article.asp", arr1, arr2), "下一页", "")
            MyXML.Printf "|"
            arr2(3) = clsPage.TotalPage
            MyXML.Println CreateA(getURL("bbs/article.asp", arr1, arr2), "最末页", "")
        End If
        If clsPage.PageNum > 1 Then
            arr2(3) = (clsPage.PageNum - 1)
            MyXML.Printf CreateA(getURL("bbs/article.asp", arr1, arr2), "上一页", "")
            MyXML.Printf "|"
            arr2(3) = 1
            MyXML.Println CreateA(getURL("bbs/article.asp", arr1, arr2), "第一页", "")
        End If
        If clsPage.TotalPage > 2 Then
            MyXML.SetF getPathName("bbs/article.asp"), "get", "", True
            Call setQuery
            MyXML.SetN "ForumId", "hidden", lngForumId, "", "", False
            MyXML.SetN "PageNo", "hidden", intPageNo, "", "", False
            MyXML.SetN "ArticleId", "hidden", lngArtId, "", "", False
            MyXML.SetN "PageId", "text", "", clsPage.PageNum & "/" & clsPage.TotalPage & "页>>跳到", "页", False, 5, 5, "*N"
            MyXML.SetN "", "submit", "GO", "", "", True
        End If
    End If
    If Not rs Is Nothing Then rs.Close
    Set rs = Nothing
    Set clsPage = Nothing
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPBbsArticle
End Function
End Class
%>