post.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomWAPmoWAPBbsPost
Private objForum
Private objArt
Private lngForumId
Private lngArtId
Private intPageNo
Private blnError
Private strError

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
    blnError = True
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("BBSTitle")
    MyXML.Align = "left"
    Set objForum = MyKernel.Table(T_FORUM)
    Set objArt = MyKernel.Table(T_ARTICLE)
    lngForumId = atol(Request.QueryString("ForumId"))
    intPageNo = atoi(Request.QueryString("PageNo"))
    lngArtId = atol(Request.QueryString("ArticleId"))
    If MyKernel.Config("IsBBS") <> "1" Then
        MyXML.Println "该功能已被站长关闭"
    ElseIf IsGuest() Then
        Call RegisterHint("只有注册用户才能发帖")
    ElseIf objForum.Execute("*", "SeqId=" & lngForumId) = False Then
        MyRedirect "bbs/index.asp"
    Else
        If lngArtId > 0 Then objArt.Execute "*", "SeqId=" & lngArtId
        MyXML.Println "[" & objForum("Title") & "]"
        If lngArtId <> objArt("SeqId") Then
            MyXML.Println "找不到你要回帖的原贴"
        Else
            If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
                Call doPost
            Else
                Call doGet
            End If
            If objArt("SeqId") > 0 Then
                MyXML.Println CreateA("bbs/article.asp?ForumId=" & objForum("SeqId") & "&PageNo=" & intPageNo & "&ArticleId=" & objArt("SeqId"), "返回" & objArt("Title"), getImagePrefix("back.gif"))
            End If
        End If
        MyXML.Println CreateA("bbs/forum.asp?ForumId=" & objForum("SeqId") & "&PageNo=" & intPageNo, "返回" & objForum("Title"), getImagePrefix("back.gif"))
    End If
    Set objArt = Nothing
    Set objForum = Nothing
    MyXML.Println CreateA("bbs/index.asp", "返回" & MyKernel.Config("BBSTitle"), getImagePrefix("back.gif"))
    Call BackHomeX(BBS_SEQID)
    Call setLog("bbs", 0)
    MyXML.Transform Response
End Sub

Private Sub doGet()
    If objArt("SeqId") <> 0 Then
        MyXML.Println "回复帖子[" & objArt("Title") & "]"
        MyXML.SetF FormatURL("bbs/post.asp?ForumId=" & objForum("SeqId") & "&PageNo=" & intPageNo & "&ArticleId=" & objArt("SeqId")), "post", "", True
    Else
        MyXML.Println "发表新帖"
        MyXML.setF FormatURL("bbs/post.asp?ForumId=" & objForum("SeqId") & "&PageNo=" & intPageNo), "post", "", True
        MyXML.SetN "Title", "text", "", "帖子标题：", "", True
    End If
    MyXML.SetN "Content", "text", "", "帖子内容：", "", True
    MyXML.SetN "", "submit", "确定", "", "", True
End Sub

Private Sub doPost()
    If MyIO.Parse(KBYTE * 5) <> 0 Then
        strError = "超过最大数据请求长度：" & (KBYTE * 5)
    Else
        Dim strTitle, strContent
        strTitle = Trim(MyIO.Form("Title"))
        strContent = Trim(MyIO.Form("Content"))
        If objArt("SeqId") = 0 And strTitle = "" Then
            strError = "请输入帖子标题"
        ElseIf strContent = "" Then
            strError = "请输入帖子内容"
        ElseIf getTime(Now()) - atol(MyKernel.Memory("LastArt")) < atoi(MyKernel.Config("ArtInterval")) Then
            strError = "感谢您的参与，请不要频繁发帖或回帖"
        ElseIf atoi(MyKernel.Memory("ArtTotal")) > atoi(MyKernel.Config("ArtTotal")) Then
            blnError = True
            strError = "感谢你的参与，一天最多能发表" & MyKernel.Config("BookTotal") & "个留言"
        Else
            blnError = False
            strError = IIf(objArt("SeqId") = 0, "发帖", "回帖") & "成功"
            Dim strSQL
            strSQL = "INSERT INTO $(Table) (USERID,USERNAME,FORUMID,FORUMNAME,TITLE,CONTENT,REPLY,HIT,FOLLOW,INTIME,OUTIME) VALUES ($(UserId),'$(UserName)',$(ForumId),'$(ForumName)','$(Title)','$(Content)',0,0,$(Follow),$(Timeval),$(Timeval))"
            strSQL = Replace(strSQL, "$(Table)", T_ARTICLE)
            strSQL = Replace(strSQL, "$(UserId)", MyKernel.Memory("UserId"))
            strSQL = Replace(strSQL, "$(UserName)", SafeString(MyKernel.Memory("Nick")))
            strSQL = Replace(strSQL, "$(ForumId)", objForum("SeqId"))
            strSQl = Replace(strSQL, "$(ForumName)", SafeString(objForum("Title")))
            strSQL = Replace(strSQL, "$(Title)", SafeString(strTitle))
            strSQL = Replace(strSQL, "$(Content)", SafeString(strContent))
            strSQL = Replace(strSQL, "$(Follow)", objArt("SeqId"))
            strSQL = Replace(strSQL, "$(Timeval)", getTime(Now()))
            MyKernel.DB.Exec strSQL
            If objArt("SeqId") > 0 Then
                strSQL = "UPDATE $(Table) SET REPLY=REPLY+1,Outime=$(Timeval) WHERE SEQID=$(SeqId)"
                strSQL = Replace(strSQL, "$(Table)", T_ARTICLE)
                strSQL = Replace(strSQL, "$(Timeval)", getTime(Now()))
                strSQL = Replace(strSQL, "$(SeqId)", objArt("SeqId"))
                MyKernel.DB.Exec strSQL
            End If
            strSQL = "UPDATE $(Table) SET ARTTOTAL=$(ArtTotal),LASTART=$(Timeval) WHERE SEQID=$(SeqId)"
            strSQL = Replace(strSQL, "$(Table)", T_USER)
            If atol(MyKernel.Memory("LastRemark")) >= getTime(Date()) Then
                MyKernel.Memory("ArtTotal") = atoi(MyKernel.Memory("ArtTotal")) + 1
            Else
                MyKernel.Memory("ArtTotal") = 1
            End If
            strSQL = Replace(strSQL, "$(ArtTotal)", MyKernel.Memory("ArtTotal"))
            strSQL = Replace(StrSQL, "$(Timeval)", getTime(Now()))
            strSQL = Replace(strSQL, "$(SeqId)", MyKernel.Memory("SeqId"))
            MyKernel.DB.Exec strSQL
        End If
    End If
    MyXML.Println strError
    If blnError Then
        Call doGet
    End IF
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPBbsPost
End Function
End Class
%>