login.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomWAPmoWAPLogin
Private blnError
Private strError
Private strReferer

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    strReferer = Request.QueryString("Referer")
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("SiteName") & "会员登录"
    MyXML.Align = "left"
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    If strReferer <> "" Then
        MyXML.Println CreateA(strReferer, "快速返回", getImagePrefix("back.gif"))
    End If
    Call BackHomeX(0)
    Call setLog("login", 0)
    MyXML.Transform Response
End Sub

Private Sub doGet()
    MyXML.SetF getURL("login.asp", "Referer", strReferer), "post", "", True
    MyXML.SetN "Nick", "text", "", "昵称：", "", True
    MyXML.SetN "Passwd", "password", "", "密码：", "", True
    MyXML.SetN "", "submit", "确定", "", "", True
    MyXML.Printf "还没有注册？"
    MyXML.Println CreateA(getURL("register.asp", "Referer", strReferer), "点此注册", "")
    MyXML.Printf "忘记密码了？"
    MyXML.Println CreateA(getURL("forget.asp", "Referer", strReferer), "点此取回", "")
End Sub

Private Sub doPost()
    Dim strNick, strPass
    Dim rs, strSQL
    Dim lngTime
    If MyIO.Parse(KBYTE) <> 0 Then
        strError = "超过最大数据请求长度：" & KBYTE
    Else
        strNick = Trim(MyIO.Form("Nick"))
        strPass = Trim(MyIO.Form("Passwd"))
        If strNick = "" Then
            strError = "请输入您的昵称"
        ElseIf strPass = "" Then
            strError = "请输入您的密码"
        ElseIf MyKernel.Memory("Nick") = strNick And MyKernel.Memory("Passwd") = MD5(strPass) Then
            strError = "请勿重复登陆"
        Else
            strSQL = getLimitSQL(1, "*", T_USER, "NICK='$(Nick)'", "", "")
            strSQL = Replace(strSQL, "$(Nick)", SafeString(strNick))
            Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            If rs.EOF Then
                strError = "昵称或密码错误"
            ElseIf rs("Passwd") <> MD5(strPass) Then
                strError = "昵称或密码错误"
            Else
                blnError = False
                strError = "登录成功" & vbCrLf & _
                "现在您可以尽情使用本站提供的服务了！" & vbCrLf & _
                "友情提示：返回首页后，把首页加入手机书签，以后通过书签访问本站即可快速进入"
                lngTime = getTime(Now())
                rs("LastLogin") = lngTime
                rs("LastUsedIP") = MyKernel.Env("REMOTE_ADDR")
                rs("LastUsedTime") = lngTime
                rs("LastUserAgent") = Request.ServerVariables("HTTP_USER_AGENT")
                rs.Update
                MyKernel.Query("MEMID") = MyKernel.Memory.MemoryId
                Call AsyncMemory(rs)
                If AddOnline(rs("UserId"), strNick, lngTime) Then
                    Call setStat(stOnlineUser & "|" & stVisitToday, 1)
                End If
            End IF
            rs.Close
            Set rs = Nothing
        End If
    End If
    MyXML.Println strError
    If blnError Then
        Call doGet
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPLogin
End Function
End Class
%>