forget.asp

WAP手机网页XXXXX WAP手机网页XXXXX

<%
Class ImplMocomWAPmoWAPForget
Private blnError
Private strError
Private strReferer

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
    blnError = True
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    strReferer = Request.QueryString("Referer")
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("SiteName") & "取回密码"
    MyXML.Align = "left"
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    If strReferer <> "" Then
        MyXML.Println CreateA(strReferer, "快速返回", getImagePrefix("back.gif"))
    End If
    Call BackHomeX(0)
    Call setLog("forget", 0)
    MyXML.Transform Response
End Sub

Private Sub doGet()
    MyXML.SetF getURL("forget.asp", "Referer", strReferer), "post", "", True
    MyXML.SetN "Nick", "text", "", "您的昵称：", "", True
    MyXML.SetN "Mobile", "text", "", "手机号码：", "", True, 11, 0, "NNNNNNNNNNN"
    MyXML.SetN "Passwd", "password", "", "重设密码：", "", True
    MyXML.SetN "", "submit", "确定", "", "", True
    MyXML.Printf "还没有注册？"
    MyXML.Println CreateA(getURL("register.asp", "Referer", strReferer), "点此注册", "")
    MyXML.Printf "已经注册了？"
    MyXML.Println CreateA(getURL("login.asp", "Referer", strReferer), "点此登录", "")
End Sub

Private Sub doPost()
    Dim strNick, strPass, strMobile
    Dim rs, strSQL
    Dim lngTime
    If MyIO.Parse(KBYTE) <> 0 Then
        strError = "超过最大数据请求长度；" & KBYTE
    Else
        strNick = Trim(MyIO.Form("Nick"))
        strPass = Trim(MyIO.Form("Passwd"))
        strMobile = Trim(MyIO.Form("Mobile"))
        If strNick = "" Then
            strError = "请输入您的昵称"
        ElseIf strPass = "" Then
            strError = "请输入您的新密码"
        Else
            strSQL = getLimitSQL(1, "*", T_USER, "NICK='$(Nick)'", "", "")
            strSQL = Replace(strSQL, "$(Nick)", SafeString(strNick))
            Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            If rs.EOF Then
                strError = "昵称或手机号码错误"
            ElseIf atos(rs("Mobile")) <> strMobile Then
                strError = "昵称或手机号码错误"
            Else
                blnError = False
                strError = "密码取回成功" & vbCrLf & _
                "您的新密码：" & strPass & vbCrLf & _
                "现在您可以尽情使用本站提供的服务了！"
                lngTime = getTime(Now())
                rs("Passwd") = MD5(strPass)
                rs("LastUsedIP") = MyKernel.Env("REMOTE_ADDR")
                rs("LastUsedTime") = lngTime
                rs("LastUserAgent") = Request.ServerVariables("HTTP_USER_AGENT")
                rs.Update
                MyKernel.Query("MEMID") = MyKernel.Memory.MemoryId
                Call AsyncMemory(rs)
                If AddOnline(rs("UserId"), strNick, lngTime) Then
                    Call setStat(stOnlineUser & "|" & stVisitToday, 1)
                End If
            End If
            rs.Close
            Set rs = Nothing
        End If
    End If
    MyXML.Println strError
    If blnError Then
        Call doGet
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPForget
End Function
End Class
%>