📄 article.asp

📁 WAP手机网页XXXXX WAP手机网页XXXXX
💻 ASP
字号:
<%
Class ImplMocomWAPmoManagerArticle
Private intErrId
Private strReason
Private objPage
Private rs, strSQL

Public Sub main()
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Select Case LCase(Request.QueryString("Handle"))
    Case "option"
        Call doGetOption
    Case "list"
        MyIO.CodePage = 65001
        Call doGetList
    Case "detail"
        Call doGetDetail
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doPost()
    Select Case LCase(Request.QueryString("Handle"))
    Case "move"
        Call doPostMove
    Case "remove"
        Call doPostRemove
    Case Else
        MyIO.Echo "未知操作"
    End Select
End Sub

Private Sub doGetMain()
    MyIO.Echo "<html>"
    MyIO.Echo "<head>"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""no-cache"" />"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""max-age=0"" />"
    MyIO.Echo "<meta http-equiv=""content-type"" content=""text/html; charset=gb2312"" />"
    MyIO.Echo "<title>" & MyKernel.Env("WM_VNAME") & " - 帖子管理</title>"
    MyIO.Echo "<link rel=""stylesheet"" href=""images/xw.css"" />"
    MyIO.Echo "<script language=""javascript"" src=""jspp/jspp.js""></script>"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "jspp.Caption = """ & MyKernel.Env("WM_NAME") & """;"
    MyIO.Echo "</script>"
    MyIO.Echo "<script language=""javascript"" src=""images/wm_article.js""></script>"
    MyIO.Echo "</head>"
    MyIO.Echo "<body style=""padding:5;margin:0;overflow:auto;border:0"">"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"" style=""border:1px solid #000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td align=""right"" bgcolor=""#A2ADC4"" style=""border-bottom:1px solid #000000;padding-right:1px;padding-top:1px"" height=""24""><img src=""images/xw_cls0.gif"" border=""0"" align=""absMiddle"" onMouseOver=""this.src='images/xw_cls1.gif'"" onMouseOut=""this.src='images/xw_cls0.gif'"" onMouseDown=""this.src='images/xw_cls2.gif'"" onMouseUp=""this.src='images/xw_cls1.gif'"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td height=""24"" style=""background-image:url(images/xw_back4.gif)"">&nbsp;</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""98%"" border=""0"" cellpadding=""0"" cellspacing=""0"" align=""center"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td id=""_OPTION"" class=""f12""></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "<iframe id=""console"" name=""console"" frameborder=""0"" scrolling=""no"" width=""0"" height=""0"" style=""display:none""></iframe>"
    MyIO.Echo "</body>"
    MyIO.Echo "</html>"
End Sub

Private Sub doGetOption()
    Response.Charset = "utf-8"
    Select Case Request.QueryString("Option")
    Case "0"
        MyIO.Echo "<form id=""frmMain"" onsubmit=""return(false)"">"
        MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td colspan=""2"" class=""winT0"">"
        MyIO.Echo " <b>所有帖子</b>"
        MyIO.Echo " <a href=""javascript:void(0)"" class=""a1"" onclick=""jspp.Article.doPage(jspp.Article.page)"">刷新帖子列表</a>"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td colspan=""2"" id=""_list_""></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
        MyIO.Echo "</form>"
    Case Else
        MyIO.Echo "未知选项"
    End Select
End Sub

Private Sub doGetList()
    Response.Charset = "utf-8"
    Dim i
    Dim strKey
    Dim strWhere
    strKey = Trim(MyIO.QueryString("Keyword"))
    Set objPage = MyKernel.Page()
    objPage.PageNum = MyIO.QueryString("Page")
    objPage.PageSize = 20
    objPage.DataType = WM_DataType
    objPage.Increment = "SeqId"
    objPage.Column = "*"
    objPage.Table = T_ARTICLE
    strWhere = "Follow=0"
    If strKey <> "" Then
        strWhere = strWhere & Replace(" AND (Title LIKE '%$(Keyword)%' Or UserName LIKE '%$(Keyword)%' Or Content LIKE '%$(Keyword)%')", "$(Keyword)", SafeString(strKey))
    End If
    objPage.Where = strWhere
    objPage.Sort = "SeqId DESC"
    objPage.SortType = True
    Set rs = objPage.Execute()
    MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse;word-break:break-all;word-wrap:break-word;"" bordercolor=""#000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>选择</b></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>所属论坛<b/></td>"
    MyIO.Echo "<td width=""30%"" class=""winT0""><b>标题<b/></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>发帖人<b/></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>回复数<b/></td>"
    MyIO.Echo "<td width=""12%"" class=""winT0""><b>发帖时间<b/></td>"
    MyIO.Echo "<td width=""12%"" class=""winT0""><b>最后回复<b/></td>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>管理</b></td>"
    MyIO.Echo "</tr>"
    If objPage.TotalRow > 0 Then
        i = 0
        Dim objArt
        Set objArt = MyKernel.Table(T_ARTICLE)
        Do While rs.EOF = False And i < objPage.PageSize
            objArt.Source = rs
            MyIO.Echo "<tr class=""winT1"">"
            MyIO.Echo "<td align=""center""><input type=""checkbox"" id=""SeqId"" name=""SeqId"" value=""" & objArt("SeqId") & """ /></td>"
            MyIO.Echo "<td>" & Server.HTMLEncode(objArt("ForumName")) & "</td>"
            MyIO.Echo "<td>" & Server.HTMLEncode(objArt("Title")) & "</td>"
            MyIO.Echo "<td>" & Server.HTMLEncode(objArt("UserName")) & "</td>"
            MyIO.Echo "<td>" & objArt("Reply") & "</td>"
            MyIO.Echo "<td align=""right"">" & FormatTime(getDate(objArt("Intime")), "YY-MM-DD HH24:MI") & "</td>"
            MyIO.Echo "<td align=""right"">" & FormatTime(getDate(objArt("Outime")), "YY-MM-DD HH24:MI") & "</td>"
            MyIO.Echo "<td align=""center"">"
            MyIO.Echo "<select class=""sel"" onchange=""jspp.Article.control(this, " & objArt("SeqId") & ")"">"
            MyIO.Echo "<option value=""0"">管理</option>"
            'MyIO.Echo "<option value=""1"">详情</option>"
            MyIO.Echo "<option value=""2"">移动</option>"
            MyIO.Echo "<option value=""3"">删除</option>"
            MyIO.Echo "</select>"
            MyIO.Echo "</td>"
            MyIO.Echo "</tr>"
            rs.MoveNext
            i = i + 1
        Loop
        Set objArt = Nothing
        Call ShowControl
        Call ShowPage
    Else
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td colspan=""8"">尚无任何帖子</td>"
        MyIO.Echo "</tr>"
        Call ShowControl
    End If
    MyIO.Echo "</table>"
    If Not rs Is Nothing Then rs.Close
    Set rs = Nothing
    Set objPage = Nothing
End Sub

Private Sub ShowControl()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td align=""center""><input type=""checkbox"" onclick=""chkAll(this)"" /></td>"
    MyIO.Echo "<td colspan=""7"">"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""移动"" onclick=""jspp.Article.moveAll(this.form)"" />"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""删除"" onclick=""jspp.Article.removeAll(this.form)"" />"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""搜索"" onclick=""jspp.Article.query(this.form)"" />"
    MyIO.Echo " <input name=""Keyword"" type=""text"" class=""txt"" value=""" & Server.HTMLEncode(MyIO.QueryString("Keyword")) & """ />"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub ShowPage()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td colspan=""8"" align=""right"">"
    MyIO.Echo "共 " & objPage.TotalRow & " 条信息 "
    MyIO.Echo objPage.PageSize & " 条/页 "
    MyIO.Echo objPage.PageNum & "/" & objPage.TotalPage & " 页"
    If objPage.PageNum > 1 Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Article.doPage(1)"" class=""a1"" />首  页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Article.doPage(" & (objPage.PageNum - 1) & ")"" class=""a1"" />上一页</a>"
    Else
        MyIO.Echo " <a class=""a1"">首  页</a>"
        MyIO.Echo " <a class=""a1"">上一页</a>"
    End If
    If objPage.PageNum < objPage.TotalPage Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Article.doPage(" & (objPage.PageNum + 1) & ")"" class=""a1"" />下一页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Article.doPage(" & objPage.TotalPage & ")"" class=""a1"" />尾  页</a>"
    Else
        MyIO.Echo " <a class=""a1"">下一页</a>"
        MyIO.Echo " <a class=""a1"">尾  页</a>"
    End If
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub doGetDetail()
    Response.Charset = "utf-8"
    Dim objArt
    Set objArt = MyKernel.Table(T_ARTICLE)
    If objArt.Execute("*", "SeqId=" & atol(Request.QueryString("SeqId"))) = False Then
        MyIO.Echo "<table width=""200"" border=""1"" cellpadding=""2"" cellspacing=""0"" bordercolor=""#000000"" style=""border-collapse:collapse"">"
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td>找不到您要查看的帖子</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
    Else
        MyIO.Echo "<table width=""300"" border=""1"" cellpadding=""2"" cellspacing=""0"" bordercolor=""#000000"" style=""border-collapse:collapse"">"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td width=""100"">产品名称</td>"
        MyIO.Echo "<td width=""200"">" & Server.HTMLEncode(objArt("Title")) & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>用户姓名</td>"
        MyIO.Echo "<td>" & objArt("Name") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>电话号码</td>"
        MyIO.Echo "<td>" & objArt("Phone") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>手机号码</td>"
        MyIO.Echo "<td>" & objArt("Mobile") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>通信地址</td>"
        MyIO.Echo "<td>" & objArt("Address") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>邮政编码</td>"
        MyIO.Echo "<td>" & objArt("ZipCode") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>帖子时间</td>"
        MyIO.Echo "<td>" & FormatTime(getDate(objArt("Intime")), "YYYY-MM-DD HH24:MI:SS") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td>最后回复</td>"
        MyIO.Echo "<td>" & FormatTime(getDate(objArt("Outime")), "YYYY-MM-DD HH24:MI:SS") & "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
    End If
    Set objArt = Nothing
End Sub

Private Sub doPostMove()
    Response.Charset = "utf-8"
    Dim strId
    Dim objForum
    Set objForum = MyKernel.Table(T_FORUM)
    strId = Trim(Request.Form("SeqId"))
    If Not IsNumbers(strId) Then
        MyIO.Echo "请选择您要移动的帖子"
    ElseIf objForum.Execute("*", "SeqId=" & atol(Request.Form("Follow"))) = False Then
        MyIO.Echo "找不到您要移动的目的论坛"
    Else
        strSQL = "UPDATE $(Table) SET FORUMID=$(ForumId),FORUMNAME='$(ForumName)' WHERE SEQID IN ($(SeqId))"
        strSQL = Replace(strSQL, "$(Table)", T_ARTICLE)
        strSQL = Replace(strSQL, "$(ForumId)", objForum("SeqId"))
        strSQL = Replace(strSQL, "$(ForumName)", SafeString(objForum("Title")))
        strSQL = Replace(strSQL, "$(SeqId)", strId)
        MyKernel.DB.Exec strSQL
        MyIO.Echo "OK"
    End If
    Set objForum = Nothing
End Sub

Private Sub doPostRemove()
    Response.Charset = "utf-8"
    If MyPower("DeleteArticle") = 0 Then
        MyIO.Echo "您没有删除帖子的权限"
    Else
        Dim strId
        strId = Trim(Request.Form("SeqId"))
        If Not IsNumbers(strId) Then
            MyIO.Echo "请选择您要删除的帖子"
        Else
            strSQL = "DELETE FROM $(Table) WHERE SEQID IN ($(SeqId)) OR FOLLOW IN ($(SeqId))"
            strSQL = Replace(strSQL, "$(Table)", T_ARTICLE)
            strSQL = Replace(strSQL, "$(SeqId)", strId)
            MyKernel.DB.Exec strSQL
            MyIO.Echo "OK"
        End If
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoManagerArticle
End Function
End Class
%>
💿 文件大小 2070 K
👤 上传用户 dongchenxi2
📂 所属分类手机WAP编程
🏷️ 相关标签

#XXXXX #WAP #手机 #页
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -