📄 forum.asp

📁 WAP手机网页XXXXX WAP手机网页XXXXX
💻 ASP
字号:
<%
Class ImplMocomWAPmoManagerForum
Private intErrId
Private strReason
Private rs, strSQL

Public Sub main()
    If Request.ServerVariables("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Select Case LCase(Request.QueryString("Handle"))
    Case "option"
        Call doGetOption
    Case "list"
        Call doGetList
    Case "add"
        Call doGetAdd
    Case "modify"
        Call doGetModify
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doPost()
    Select Case LCase(Request.QueryString("Handle"))
    Case "add"
        MyIO.CodePage = 65001
        Call doPostAdd
    Case "modify"
        MyIO.CodePage = 65001
        Call doPostModify
    Case "move"
        Call doPostMove
    Case "remove"
        Call doPostRemove
    Case "sort"
        Call doPostSort
    Case Else
    End Select
End Sub

Private Sub doGetMain()
    MyIO.Echo "<html>"
    MyIO.Echo "<head>"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""no-cache"" />"
    MyIO.Echo "<meta http-equiv=""cache-control"" content=""max-age=0"" />"
    MyIO.Echo "<meta http-equiv=""content-type"" content=""text/html; charset=gb2312"" />"
    MyIO.Echo "<title>" & MyKernel.Env("WM_VNAME") & " - 论坛管理</title>"
    MyIO.Echo "<link rel=""stylesheet"" href=""images/xw.css"" />"
    MyIO.Echo "<script language=""javascript"" src=""jspp/jspp.js""></script>"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "jspp.Caption = """ & MyKernel.Env("ProName") & """;"
    MyIO.Echo "jspp.SiteName = """ & MyKernel.Config("SiteName") & """;"
    MyIO.Echo "</script>"
    MyIO.Echo "<script language=""javascript"" src=""images/wm_forum.js""></script>"
    MyIO.Echo "</head>"
    MyIO.Echo "<body style=""padding:5;margin:0;overflow:auto;border:0"">"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"" style=""border:1px solid #000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td align=""right"" bgcolor=""#A2ADC4"" style=""border-bottom:1px solid #000000;padding-right:1px;padding-top:1px"" height=""24""><img src=""images/xw_cls0.gif"" border=""0"" align=""absMiddle"" onMouseOver=""this.src='images/xw_cls1.gif'"" onMouseOut=""this.src='images/xw_cls0.gif'"" onMouseDown=""this.src='images/xw_cls2.gif'"" onMouseUp=""this.src='images/xw_cls1.gif'"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td height=""24"" style=""background-image:url(images/xw_back4.gif)"">&nbsp;</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""98%"" border=""0"" cellpadding=""0"" cellspacing=""0"" align=""center"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td id=""_OPTION"" class=""f12""></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "<iframe id=""console"" name=""console"" frameborder=""0"" scrolling=""no"" width=""0"" height=""0"" style=""display:none""></iframe>"
    MyIO.Echo "</body>"
    MyIO.Echo "</html>"
End Sub

Private Sub doGetOption()
    Response.Charset = "utf-8"
    Select Case Request.QueryString("Option")
    Case "0"
        MyIO.Echo "<form id=""frmMain_0"" onsubmit=""return(false)"">"
        MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td width=""42%"" class=""winT0""><b>论坛名称</b></td>"
        MyIO.Echo "<td width=""42%"" class=""winT0""><b>论坛说明</b></td>"
        MyIO.Echo "<td width=""6%"" class=""winT0""><b>分页</b></td>"
        MyIO.Echo "<td width=""10%"" class=""winT0""><b>管理</b></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td colspan=""5"">"
        MyIO.Echo "<div id=""_tree_"">"
        MyIO.Echo "<div id=""tree_item_0"" expand=""no"" mark="""" last=""1"" style=""font-size:12px""></div>"
        MyIO.Echo "</div>"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td colspan=""5"">"
        MyIO.Echo " <label style=""padding:4px 2px 0px 2px""><b>管理</b></label>"
        MyIO.Echo " <input type=""button"" value=""新建"" class=""btn"" onclick=""tree.add()"" />"
        MyIO.Echo " <input type=""button"" value=""移动"" class=""btn"" onclick=""tree.moveAll()"" />"
        MyIO.Echo " <input type=""button"" value=""删除"" class=""btn"" onclick=""tree.removeAll()"" />"
        MyIO.Echo " <input type=""button"" value=""板块排序"" class=""btn"" onclick=""tree.sort()"" />"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
        MyIO.Echo "</form>"
    Case Else
        MyIO.Echo "未知选项"
    End Select
End Sub

Private Sub doGetList()
    Response.Charset = "utf-8"
    Dim objForum
    Dim strTemp
    strSQL = "SELECT * FROM " & T_FORUM & " ORDER BY SERIAL"
    Set rs = MyKernel.DB.Execute(strSQL)
    Set objForum = MyKernel.Table(T_FORUM)
    MyIO.Echo "$forum = new Array();"
    Do While rs.EOF = False
        objForum.Source = rs
        strTemp = "$forum.push({SeqId:$(SeqId),Title:""$(Title)"",Content:""$(Content)"",Page:$(Page),Follow:$(Follow),Intime:$(Intime)});"
        strTemp = Replace(strTemp, "$(SeqId)", objForum("SeqId"))
        strTemp = Replace(strTemp, "$(Title)", JSEncode(objForum("Title")))
        strTemp = Replace(strTemp, "$(Content)", JSEncode(objForum("Content")))
        strTemp = Replace(strTemp, "$(Page)", objForum("Page"))
        strTemp = Replace(strTemp, "$(Follow)", objForum("Follow"))
        strTemp = Replace(strTemp, "$(Intime)", objForum("Intime"))
        MyIO.Echo strTemp
        rs.MoveNext
    Loop
    Set objForum = Nothing
    rs.Close
    Set rs = Nothing
End Sub

Private Sub doGetAdd()
    Response.Charset = "utf-8"
    MyIO.Echo "<form id=""frmTemplet"" onsubmit=""return(false)"">"
    MyIO.Echo "<table width=""400"" border=""1"" cellpadding=""2"" cellspacing=""0"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td colspan=""2"" class=""winT0""><b>新建论坛</b></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td width=""80"">所属论坛</td>"
    MyIO.Echo "<td width=""320"">"
    MyIO.Echo "<select name=""Follow"" class=""sel"">"
    MyIO.Echo "<option value=""0"">新建为板块</option>"
    MyIO.Echo "</select>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td width=""80"">论坛名称</td>"
    MyIO.Echo "<td width=""320""><input type=""text"" name=""Title"" class=""txt"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td>论坛说明</td>"
    MyIO.Echo "<td><textarea name=""Content"" class=""area"" style=""width:300px;height:100px""></textarea></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td>帖子分页</td>"
    MyIO.Echo "<td><input type=""text"" name=""Page"" class=""txt"" value=""10"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td colspan=""2"" align=""center"">"
    MyIO.Echo " <input name=""Accept"" type=""button"" value=""确  定"" class=""btn"" />"
    MyIO.Echo " <input name=""Cancel"" type=""button"" value=""取  消"" class=""btn"" />"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</form>"
End Sub

Private Sub doGetModify()
    Response.Charset = "utf-8"
    Dim objForum
    Set objForum = MyKernel.Table(T_FORUM)
    If objForum.Execute("*", "SEQID=" & atol(Request.QueryString("SeqId"))) = False Then
        ExportHintX "找不到您要编辑的论坛"
    Else
        MyIO.Echo "<form id=""frmTemplet"" onsubmit=""return(false)"">"
        MyIO.Echo "<table width=""400"" border=""1"" cellpadding=""2"" cellspacing=""0"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td colspan=""2"" class=""winT0""><b>编辑论坛</b></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td width=""80"">论坛名称</td>"
        MyIO.Echo "<td width=""320""><input type=""text"" name=""Title"" class=""txt"" value=""" & Server.HTMLEncode(objForum("Title")) & """ /></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td>论坛说明</td>"
        MyIO.Echo "<td><textarea name=""Content"" class=""area"" style=""width:300px;height:100px"">" & Server.HTMLEncode(objForum("Content")) & "</textarea></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td>帖子分页</td>"
        MyIO.Echo "<td><input type=""text"" name=""Page"" class=""txt"" value=""" & objForum("Page") & """ /></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td colspan=""2"" align=""center"">"
        MyIO.Echo " <input name=""Accept"" type=""button"" value=""确  定"" class=""btn"" />"
        MyIO.Echo " <input name=""Cancel"" type=""button"" value=""取  消"" class=""btn"" />"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
        MyIO.Echo "</form>"
    End If
    Set objForum = Nothing
End Sub

Private Sub doPostAdd()
    Response.Charset = "utf-8"
    Dim strTitle, strContent, intPage, lngFollow
    If MyPower("AddForum") = 0 Then
        MyIO.Echo "您没有添加板块/论坛的权限"
    Else
        strTitle = Trim(MyIO.Form("Title"))
        strContent = Trim(MyIO.Form("Content"))
        intPage = atoi(MyIO.Form("Page"))
        lngFollow = atol(MyIO.Form("Follow"))
        If strTitle = "" Then
            MyIO.Echo "请输入论坛标题"
        Else
            strSQL = getLimitSQL(1, "*", T_FORUM, "0=1", "", "")
            Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            rs.AddNew
            rs("Title") = strTitle
            rs("Content") = strContent
            rs("Page") = IIf(intPage < 0, 10, intPage)
            rs("Follow") = lngFollow
            rs("Intime") = getTime(Now())
            rs.Update
            rs.Close
            Set rs = Nothing
            MyIO.Echo "OK"
        End If
    End If
End Sub

Private Sub doPostModify()
    Response.Charset = "utf-8"
    Dim lngId
    Dim strTitle, strContent, intPage
    lngId = atol(Request.QueryString("SeqId"))
    If MyPower("ModifyForum") = 0 Then
        MyIO.Echo "您没有编辑板块/论坛的权限"
    ElseIf lngId <= 0 Then
        MyIO.Echo "请选择您要编辑的论坛"
    Else
        strTitle = Trim(MyIO.Form("Title"))
        strContent = Trim(MyIO.Form("Content"))
        intPage = atoi(MyIO.Form("Page"))
        If strTitle = "" Then
            MyIO.Echo "请输入论坛标题"
        Else
            strSQL = getLimitSQL(1, "*", T_FORUM, "SEQID=$(SeqId)", "", "")
            strSQL = Replace(strSQL, "$(SeqId)", lngId)
            Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            If rs.EOF Then
                MyIO.Echo "找不到您要编辑的论坛"
            Else
                rs("Title") = strTitle
                rs("Content") = strContent
                rs("Page") = IIf(intPage < 0, 10, intPage)
                rs.Update
                MyIO.Echo "OK"
            End If
            rs.Close
            Set rs = Nothing
        End If
    End If
End Sub

Private Sub doPostMove()
    Response.Charset = "utf-8"
    If MyPower("ModifyForum") = 0 Then
        MyIO.Echo "您没有编辑板块/论坛的权限"
    Else
        Dim lngId
        Dim strId
        strId = Trim(Request.Form("Source"))
        lngId = atol(Request.Form("Target"))
        If Not IsNumbers(strId) Then
            MyIO.Echo "请选择您要移动的论坛"
        Else
            strSQL = "UPDATE $(Table) SET FOLLOW=$(Follow) WHERE SEQID IN ($(SeqId))"
            strSQL = Replace(strSQL, "$(Table)", T_FORUM)
            strSQL = Replace(strSQL, "$(Follow)", lngId)
            strSQL = Replace(strSQL, "$(SeqId)", strId)
            MyKernel.DB.Exec strSQL
            MyIO.Echo "OK"
        End If
    End If
End Sub

Private Sub doPostRemove()
    Response.Charset = "utf-8"
    If MyPower("DeleteForum") = 0 Then
        MyIO.Echo "您没有删除板块/论坛的权限"
    Else
        Dim strId
        strId = Trim(Request.Form("SeqId"))
        If Not IsNumbers(strId) Then
            MyIO.Echo "请选择您要删除的论坛"
        Else
            strSQL = "DELETE FROM $(TableA) WHERE FORUMID IN ($(SeqId)) OR FORUMID IN (SELECT SEQID FROM $(TableB) WHERE FORUMID IN ($(SeqId)))"
            strSQL = Replace(strSQL, "$(TableA)", T_ARTICLE)
            strSQL = Replace(strSQL, "$(TableB)", T_FORUM)
            strSQL = Replace(strSQL, "$(SeqId)", strId)
            MyKernel.DB.Exec strSQL
            strSQL = "DELETE FROM $(Table) WHERE SEQID IN ($(SeqId)) OR FOLLOW IN ($(SeqId))"
            strSQL = Replace(strSQL, "$(Table)", T_FORUM)
            strSQL = Replace(strSQL, "$(SeqId)", strId)
            MyKernel.DB.Exec strSQL
            MyIO.Echo "OK"
        End If
    End If
End Sub

Private Sub doPostSort()
    Response.Charset = "utf-8"
    If MyPower("ModifyForum") = 0 Then
        MyIO.Echo "您没有编辑板块/论坛的权限"
    Else
        Dim lngId
        Dim arr
        Dim i
        lngId = atol(Request.Form("SeqId"))
        arr = Split(Request.Form("List"), ",")
        strSQL = "UPDATE $(Table) SET Serial=$(Serial) WHERE SeqId=$(SeqId) AND Follow=$(Follow)"
        strSQL = Replace(strSQL, "$(Table)", T_FORUM)
        strSQL = Replace(strSQL, "$(Follow)", lngId)
        For i = 0 To UBound(arr)
            MyKernel.DB.Exec Replace(Replace(strSQL, "$(Serial)", i), "$(SeqId)", atol(arr(i)))
        Next
        MyIO.Echo "OK"
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoManagerForum
End Function
End Class
%>
💿 文件大小 2070 K
👤 上传用户 dongchenxi2
📂 所属分类手机WAP编程
🏷️ 相关标签

#XXXXX #WAP #手机 #页
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -