os_cpu_a.asm

此代码是ucos-II在凌阳61单片机上的移植

.DEFINE	P_IOA_Data   		0x7000         // Write Data into data register and read from IOA pad
.DEFINE P_IOA_Buffer        0x7001         // Write Data into buffer register and read from buffer register
.DEFINE P_IOA_Dir           0x7002         // Direction vector for IOA
.DEFINE P_IOA_Attrib        0x7003         // Attribute vector for IOA
.DEFINE P_IOA_Latch         0x7004         // Latch PortA data for key change wake-up

.DEFINE P_IOB_Data         	0x7005         // Write Data into the data register and read from IOB pad
.DEFINE P_IOB_Buffer        0x7006         // Write Data into buffer register and read from buffer register
.DEFINE P_IOB_Dir           0x7007         // Direction vector for IOB
.DEFINE P_IOB_Attrib        0x7008         // Attribute vector for IOB

.DEFINE P_FeedBack          0x7009         // Clock form external R,C
.DEFINE P_TimerA_Data       0x700A         // Data port for TimerA 
.DEFINE P_TimerA_Ctrl       0x700B         // Control Port for TimerA
.DEFINE P_TimerB_Data       0x700C         // Data port for TimerB
.DEFINE P_TimerB_Ctrl       0x700D         // Control Port for TimerB
.DEFINE P_TimeBase_Setup    0x700E         // TimerBase Freq. Set
.DEFINE P_TimeBase_Clear	0x700F 		   // Reset Timerbase counter
.DEFINE P_INT_Ctrl          0x7010         // Control port for interrupt source
.DEFINE P_INT_Ctrl_New      0x702D
.DEFINE P_INT_Clear         0x7011         // Clear interrupt source
.DEFINE P_Watchdog_Clear    0x7012         // Watchdog Reset
.DEFINE P_SystemClock       0x7013         // Change system clock frequency(include go to standby mode)

//... PA6442 New version MC52A (For EC-03)....
.DEFINE P_ADC 	        	0x7014         	// Data Port for AD
.DEFINE P_ADC_Ctrl          0x7015         	// Control Port for AD control
.DEFINE P_ADC_Status        0x7015         	// AD Port Status
.DEFINE P_DAC2              0x7016         	// Data Port for DAC2
.DEFINE P_PWM               0x7016         	// Data Port for PWM
.DEFINE P_DAC1	        	0x7017         	// Data Port for DAC1
.DEFINE P_DAC_Ctrl			0x702A 			// Control Port for two DAC and audio output mode
//............................................

.DEFINE P_IR_Ctrl			0x7018 			// Control Port for IR
.DEFINE P_LVD_Ctrl          0x7019         	// Control Port for LVD
.DEFINE P_SIO_Data			0x701A 			// Data port for serial IO
.DEFINE P_SIO_Addr_Low		0x701B 			// Address Port low
.DEFINE P_SIO_Addr_Mid		0x701C 			// Address Port middle
.DEFINE P_SIO_Addr_High	 	0x701D 			// Address Port high
.DEFINE P_SIO_Ctrl			0x701E 			// Control Port
.DEFINE P_SIO_Start			0x701F 			// Start port for serial interface
.DEFINE P_SIO_Stop			0x7020 			// Stop port for serial interface

.DEFINE P_UART_Command1		 0x7021 		// Command1 Port for UART
.DEFINE P_UART_Command2		 0x7022 		// Command2 Port for UART
.DEFINE P_UART_Data			 0x7023  		// Data Port for UART
.DEFINE	P_UART_BaudScalarLow 0x7024 		// Set Baud Rate scalar low
.DEFINE	P_UART_BaudScalarHigh 0x7025 		// Set Baud Rate scalar high


//... Definitions for P_INT_Ctrl ..............
.DEFINE C_IRQ6_TMB2             0x0001         	// Timer B IRQ6
.DEFINE C_IRQ6_TMB1             0x0002         	// Timer A IRQ6
.DEFINE C_IRQ5_2Hz              0x0004         	// 2Hz IRQ5
.DEFINE C_IRQ5_4Hz              0x0008         	// 4Hz IRQ5
.DEFINE C_IRQ4_1KHz             0x0010         	// 1024Hz IRQ4
.DEFINE C_IRQ4_2KHz             0x0020         	// 2048Hz IRQ4
.DEFINE C_IRQ4_4KHz             0x0040         	// 4096Hz IRQ4
.DEFINE C_IRQ3_KEY              0x0080         	// Key Change IRQ3
.DEFINE C_IRQ3_EXT1             0x0100         	// Ext1 IRQ3
.DEFINE C_IRQ3_EXT2             0x0200         	// Ext2 IRQ3
.DEFINE C_IRQ2_TMB              0x0400         	// Timer B IRQ2
.DEFINE C_FIQ_TMB               0x0800         	// Timer B FIQ
.DEFINE C_IRQ1_TMA              0x1000         	// Timer A IRQ1
.DEFINE C_FIQ_TMA               0x2000         	// Timer A FIQ
.DEFINE C_IRQ0_PWM              0x4000         	// PWM IRQ0
.DEFINE C_FIQ_PWM               0x8000         	// PWM FIQ


//.include  hardware.inc
.EXTERNAL _OSTaskSwHook;
.EXTERNAL _OSIntEnter
.EXTERNAL _OSTimeTick
.EXTERNAL _OSIntExit
.EXTERNAL _OSTCBCur
.EXTERNAL _OSTCBHighRdy
.EXTERNAL _OSRunning
.EXTERNAL _OSPrioHighRdy
.EXTERNAL _OSPrioCur
.EXTERNAL _OSIntNesting
.EXTERNAL _InterruptC

.CODE 
.PUBLIC _OSStartHighRdy
_OSStartHighRdy:
		CALL  _OSTaskSwHook
		
		R1=0x0001            //将系统运行标志置1，表示系统开始运行，可以进行任务调度
		[_OSRunning]=R1
		
		R1=[_OSTCBCur]       //取得当前可以运行的任务的TCB块首地址
		SP=[R1]              //在TCB块的首地址（第一项）中存放的是该任务的堆栈地址
		POP R1 FROM [SP]
		[_InterruptC]=R1      //弹出该任务的中断开关次数标志
		POP R1,R5 FROM [SP]
		RETI


.PUBLIC _OSCtxSw
_OSCtxSw:
		PUSH R1,R5 TO [SP]            //调用子程序时会自动将PC,SR压入栈中，不需要再保存 
		R1=[_InterruptC]
		PUSH R1 TO [SP]               //压入该任务的中断开关次数标志 
		
		//保存即将挂起任务的堆栈地址
		R2=[_OSTCBCur]                //取得当前任务（即将挂起的任务）的TCB首地址      
		[R2]=SP                       //在TCB的第一项(首地址)中保存堆栈地址
		CALL _OSTaskSwHook
		
		//OSUCBCur=OSTCBHighRdy
		R1=_OSTCBCur                  //取得 OSTCBCur的地址
		R2=[_OSTCBHighRdy]            //取得 OSTCBHighRdy所指向的TCB的首地址
		[R1]=R2                       //将优先级最高的就绪态任务的TCB的首地址赋予 OSTCBCur
		
		//OSPrioCur=OSPrioHighRdy
		R1=[_OSPrioHighRdy]            
		[_OSPrioCur]=R1
		
		//切换至新的任务堆栈
		R1=[_OSTCBHighRdy]            //取得将要运行的任务的TCB块的首地址（其中放置了该任务的堆栈地址）
		SP=[R1]
		POP R1 FROM [SP]
		[_InterruptC]=R1              //弹出将要运行的任务的中断开关次数
		CMP R1,0                      //查看是否需要开中断

		JNE KAI                       //如果任务原先是关中断下被挂起，则直接返回
		INT IRQ                       //否则开中断返回
KAI:	POP R1,R5 FROM [SP]           
		RETI

		
.PUBLIC _OSIntCtxSw
_OSIntCtxSw:                          //将发生任务切换，将要挂起的任务的所有的寄存器包括堆栈地址已经保存
		CALL _OSTaskSwHook

		//OSUCBCur=OSTCBHighRdy
		R1=_OSTCBCur                   
		R2=[_OSTCBHighRdy]
		[R1]=R2
		
		//OSPrioCur=OSPrioHighRdy
		R1=[_OSPrioHighRdy]            
		[_OSPrioCur]=R1
		
		//切换至新的任务堆栈
		R1=[_OSTCBHighRdy]             
		SP=[R1]
		
		POP R1 FROM [SP]             //弹出将要运行任务的中断开关次数标志
		[_InterruptC]=R1
		CMP R1,0                      //查看是否需要关中断
		JE KAI1                       //如果任务原先是关中断下被挂起
		IRQ OFF                       //则关中断返回
KAI1:	POP R1,R5 FROM [SP]
		RETI


.PUBLIC _InitSystem
_InitSystem:
		INT OFF
		PUSH R1,R5 to [SP]
		R1 = 0xFFFF 				//设定IOB口为同相输出口；
		[P_IOB_Attrib] = R1 
		[P_IOB_Dir] = R1 
		[P_IOB_Data] = R1 
		
		//R1=0xFFFF
		[P_TimeBase_Setup]=R1       //设置64Hz TMB1
		
		R1 = 0x0002			        //开中断IRQ6_TMB1,64Hz
		[P_INT_Ctrl] = R1 
		[P_INT_Ctrl_New] = R1
		
		INT	IRQ                     //开中断并返回
		POP R1,R5 from [SP] 		
		RETF

.public _display
_display:
		PUSH R1,R5 to [SP]
		R1=SP+8
		R1=[R1]
		[P_IOB_Data]=R1
		POP R1,R5 from [SP]
		RETF		
			
.TEXT
.PUBLIC _IRQ6
_IRQ6:
		PUSH R1,R5 TO [SP]
		R1=0x0002
		[P_INT_Clear]=R1     //清中断标志
		
		CALL _Clear_Dog      //清看门狗
    	
		R1=[_OSIntNesting]   //中断嵌套标志加1
		R1+=1
		[_OSIntNesting]=R1
		
		CMP R1,1            
		JNE TCB              //如果没有发生嵌套中断
		R1=[_InterruptC]     //保存中断开关次数标志
		PUSH R1 TO [SP]
		R2=[_OSTCBCur]       //则保存当前堆栈地址
		[R2]=SP
		
TCB:	CALL _OSTimeTick
		CALL _OSIntExit
		
		R1=[_OSIntNesting]
		CMP R1,0
		JNE TCB1            //不等于0则表示为中断嵌套返回
		POP R1 FROM [SP]    //如果能执行到此，则说明不需要进行任务切换，也就无需进行开关中断处理
		[_InterruptC]=R1    //但需要弹出中断计数器以调整堆栈指针到正确位置
TCB1:	POP  R1,R5 FROM [SP]
		RETI


.PUBLIC _Clear_Dog
_Clear_Dog:
 		R1 = 0x0001;
    	[P_Watchdog_Clear] = R1    //清看门狗
    	RETF