callout_debug_atlasii.s

Centrality Atlas II development software

/*
 * $QNXLicenseC: 
 * Copyright 2007,2008, QNX Software Systems.  
 *  
 * Licensed under the Apache License, Version 2.0 (the "License"). You  
 * may not reproduce, modify or distribute this software except in  
 * compliance with the License. You may obtain a copy of the License  
 * at: http://www.apache.org/licenses/LICENSE-2.0  
 *  
 * Unless required by applicable law or agreed to in writing, software  
 * distributed under the License is distributed on an "AS IS" basis,  
 * WITHOUT WARRANTIES OF ANY KIND, either express or implied. 
 * 
 * This file may contain contributions from others, either as  
 * contributors under the License or as licensors under other terms.   
 * Please review this entire file for other proprietary rights or license  
 * notices, as well as the QNX Development Suite License Guide at  
 * http://licensing.qnx.com/license-guide/ for other information. 
 * $ 
 */



/*
 * Centrality Atals-II UART0 polled serial I/O
 */

#include "callout.ah"
#include "atlasii.h"

/*
 * -----------------------------------------------------------------------
 * Routine to patch callout code
 *
 * On entry:
 *	r0     - physical address of syspage
 *	r1     - virtual  address of syspage
 *	r2     - offset from start of syspage to start of the callout routine
 *	r3     - offset from start of syspage to read/write data used by callout
 *  [sp]   - data registered with callout via callout_register_data()
 *  [sp+4] - address of callout definition (CALLOUT_START)
 * -----------------------------------------------------------------------
 */
patch_debug:
	stmdb	sp!,{r4,lr}
	add		r4, r0, r2					// address of callout routine

	/*
	 * Map reset control registers
	 */
	mov		r0, #0x140	// size of registers
	ldr		r1, Lpaddr
	bl		callout_io_map

	/*
	 * Patch the callout routine
	 */
	CALLOUT_PATCH	r4, r0, r1, r2, ip
	ldmia	sp!,{r4,pc}

Lpaddr:	.word	_SER0_MODULE_BASE

/*
 * -----------------------------------------------------------------------
 * void	display_char_atlasii(struct sypage_entry *, char)
 * -----------------------------------------------------------------------
 */
CALLOUT_START(display_char_atlasii, 0, patch_debug)
	mov		ip,     #0x000000ff		// register base
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000


	/*
	 * Wait for not TX_FIFO_FULL
	 */
0:	ldr	r3, [ip, #0x0114]  //UART_TXFIFO_STATUS register
	tst		r3, #0x40  //TX_FIFO_FULL
	bne		0b
	/*
	 * Output character
	 */
	str	r1, [ip, #0x0118] //UART_TXFIFO_DATA

	mov		pc, lr
CALLOUT_END(display_char_atlasii)


/*
 * -----------------------------------------------------------------------
 * char	poll_key_atlasii(struct sypage_entry *)
 * -----------------------------------------------------------------------
 */
CALLOUT_START(poll_key_atlasii, 0, patch_debug)
	mov		ip,     #0x000000ff		// register base 
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000


	/*
	 * If RXRDY, read character, otherwise return -1
	 */
0:	ldrb	r3, [ip, #0x0134]    //UART_RXFIFO_STATUS
	tst		r3, #0x80     //RX_FIFO_EMPTY
	ldreq	r0, [ip]
	mvnne	r0, #1

	mov		pc, lr
CALLOUT_END(poll_key_atlasii)


/*
 * -----------------------------------------------------------------------
 * int break_detect(struct syspage_entry *)
 *
 * Return 1 if break detected, 0 otherwise
 * -----------------------------------------------------------------------
 */
CALLOUT_START(break_detect_atlasii, 0, patch_debug)
	mov		ip,     #0x000000ff		// register base
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000


	/*
	 * Check for break indicator
	 */
	ldr	r0, [ip, #0x0058]  //UART_INT_STATUS
	tst	r0, #0x0800             //Break detect
	bne		1f
	mov		r0, #0
	mov		pc, lr
1:
	/*
	 * Eat the null character
	 */
	ldrb	r0, [ip]
	mov		r0, #1
	mov		pc, lr
CALLOUT_END(break_detect_atlasii)