callout_timer_atlasii.s

Centrality Atlas II development software

#  
# Copyright 2007, 2008, QNX Software Systems. 
#  
# Licensed under the Apache License, Version 2.0 (the "License"). You 
# may not reproduce, modify or distribute this software except in 
# compliance with the License. You may obtain a copy of the License 
# at: http://www.apache.org/licenses/LICENSE-2.0 
#  
# Unless required by applicable law or agreed to in writing, software 
# distributed under the License is distributed on an "AS IS" basis, 
# WITHOUT WARRANTIES OF ANY KIND, either express or implied.
# 
# This file may contain contributions from others, either as 
# contributors under the License or as licensors under other terms.  
# Please review this entire file for other proprietary rights or license 
# notices, as well as the QNX Development Suite License Guide at 
# http://licensing.qnx.com/license-guide/ for other information.
# #
/*
 * Centrality Atlas-II timer support
 */

#include "callout.ah"
#include "atlasii.h"
/*
 * --------------------------------------------------------------------------
 * Routine to patch callout code
 *
 * On entry:
 *	r0 - physical address of syspage
 *	r1 - virtual  address of syspage
 *	r2 - offset from start of syspage to start of the callout routine
 *	r3 - offset from start of syspage to read/write data used by callout
 * --------------------------------------------------------------------------
 */
patch_timer:
	stmdb	sp!,{r4,lr}
	add		r4, r0, r2					// address of callout routine

	/*
	 * Map registers
	 */
	mov		r0, #0x40	// size of registers
	ldr		r1, Lpaddr
	bl		callout_io_map

	/*
	 * Patch the callout routine
	 */
	CALLOUT_PATCH	r4, r0, r1, r2, ip

	ldmia	sp!,{r4,pc}

Lpaddr:	.word	_OST_MODULE_BASE

/*
 * --------------------------------------------------------------------------
 * Set clock resolution, and enable interrupt triggering as a side effect.
 * The interrupt remains masked until it is enabled via intr_unmask_omap
 *
 * On entry:
 *	r0 - pointer to syspage_entry
 *	r1 - pointer to qtime_entry
 * --------------------------------------------------------------------------
 */
CALLOUT_START(timer_load_atlasii, 0, patch_timer)
	/*
	 * Get the address of the timer registers (patched)
	 */
	mov		ip,     #0x000000ff
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000

	/*
	 * Get the load value 
	 */
	ldr		r0, [r1, #QT_TIMER_LOAD]

        /*
         * Clear the interrupt status register
         */
        mov              r2, #1
        str                r2, [ip, #0x20]

	/*
	 * clear the counter low value and load the match value 
	 */
	mov		r2, #0
	str		r0, [ip, #0x08]   //TIMER_MATCH_0
	str		r2, [ip, #0x0]    //counter low register reset to 0

       /*
         * Enable timer interrupt
         */
        ldr                r2, [ip, #0x24]
        orr                r2, r2, #1
        str                r2, [ip, #0x24]

	mov		pc, lr
CALLOUT_END(timer_load_atlasii)


/*
 * --------------------------------------------------------------------------
 * Read the current timer value, relative to the last clock tick
 *
 * On entry:
 *	r0 - pointer to syspage_entry
 *	r1 - pointer to qtime_entry
 * FIXME: Does not deal with roll-over
 * --------------------------------------------------------------------------
 */
CALLOUT_START(timer_value_atlasii, 0, patch_timer)
	/*
	 * Get the address of the timer registers (patched)
	 */
	mov		ip,     #0x000000ff
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000

	/*
	 * Latch the current timer value and return the value subtract the timer load value
	 */
	mov		r2, #1    //latch
	str		r2, [ip, #0x30]
	ldr		r0, [ip, #0x34]   //return timer_latch_low value
	ldr		r2, [ip, #0x08]   //TIMER_MATCH_0
	ldr     r1, [r1, #QT_TIMER_LOAD]
	sub		r1, r2, r1
    sub     r0, r0, r1

	mov		pc, lr
CALLOUT_END(timer_value_atlasii)


/*
 * --------------------------------------------------------------------------
 * Clear timer interrupt.
 *
 * On entry:
 *	r0 - pointer to syspage_entry
 *	r1 - pointer to qtime_entry
 * --------------------------------------------------------------------------
 */
CALLOUT_START(timer_reload_atlasii, 0, patch_timer)
	/*
	 * Get the address of the timer registers (patched)
	 */
	mov		ip,     #0x000000ff
	orr		ip, ip, #0x0000ff00
	orr		ip, ip, #0x00ff0000
	orr		ip, ip, #0xff000000

	/*
	 * Latch the current counter value and return the value
	 */
	mov		r2, #1    //latch
	str		r2, [ip, #0x30]
	ldr		r0, [ip, #0x34]   //return timer_latch_low value


        /*
         * Clear the interrupt status register
         */
        mov                r2, #1
        str                r2, [ip, #0x20]

	 /* Get the load value */
	ldr		r2, [r1, #QT_TIMER_LOAD]

	/*
	 * add the load value to the counter low reg
	 */
	add		r2, r2,r0
	str		r2, [ip, #0x08]   //TIMER_MATCH_0
	
	mov		pc, lr
CALLOUT_END(timer_reload_atlasii)