main.pas

这是一个DELPHI7应用案例开发篇有配套程序种子光盘

unit Main;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DBXpress, FMTBcd, StdCtrls, Provider, DB, SqlExpr, DBClient,
  ShellAPI, Menus, AppEvnts;

const
  WM_MYICON = WM_USER+1000;

type
  TfrmMain = class(TForm)
    pmTrayIcon: TPopupMenu;
    miAbout: TMenuItem;
    miExit: TMenuItem;
    ApplicationEvents1: TApplicationEvents;
    Label1: TLabel;
    lbConnects: TLabel;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure ApplicationEvents1Minimize(Sender: TObject);
    procedure miAboutClick(Sender: TObject);
    procedure miExitClick(Sender: TObject);
  private
    procedure AddTrayIcon;
    procedure IconMessage(var Mes:TMessage);message WM_MYICON;
  public
    Connects : Integer;
  end;

var
  frmMain: TfrmMain;

implementation

uses AppServer_TLB;

{$R *.dfm}

{ TfrmMain }

procedure TfrmMain.AddTrayIcon;
var
    IconData : TNotifyIconData;
    buf : array [0..255] of Char;
begin
  with IconData do
  begin
    cbSize := SizeOf(IconData);
    Wnd := Self.Handle;
    uID := 0;
    uFlags := nif_Icon or nif_Message or nif_Tip;
    uCallBackMessage := WM_MYICON;
    hIcon := LoadIcon(hInstance,'MYICON');
    if hIcon=0 then
    begin
        FormatMessage(FORMAT_MESSAGE_FROM_SYSTEM,nil,GetLastError,0,buf,256,nil);
        MessageDlg(buf, mtWarning, [mbOK], 0);
    end;
    StrCopy(szTip,PChar('书籍管理系统应用服务器'));
  end;
  Shell_NotifyIcon(NIM_ADD, @IconData);
end;

procedure TfrmMain.FormCreate(Sender: TObject);
begin
    AddTrayIcon;
    Connects := 0;
end;

procedure TfrmMain.IconMessage(var Mes: TMessage);
var
    Pos : TPoint;
begin
    if Mes.LParam = WM_RBUTTONDOWN then
    begin
        GetCursorPos(Pos);
        pmTrayIcon.Popup(Pos.X, Pos.Y);
    end
    else if Mes.LParam = WM_LBUTTONDOWN then
    begin
    end
    else if Mes.LParam = WM_LBUTTONDBLCLK then
    begin
        Self.Show;
    end;
end;

procedure TfrmMain.FormDestroy(Sender: TObject);
var
    IconData : TNotifyIconData;
begin
  with IconData do
  begin
    cbSize := SizeOf(IconData);
    Wnd := Self.Handle;
    uID := 0;
  end;
  Shell_NotifyIcon(NIM_DELETE, @IconData);
end;

procedure TfrmMain.ApplicationEvents1Minimize(Sender: TObject);
begin
    Hide;
end;

procedure TfrmMain.miAboutClick(Sender: TObject);
begin
    MessageDlg('书籍管理系统1.0'+#13+#10+'应用服务器', mtWarning, [mbOK], 0);
end;

procedure TfrmMain.miExitClick(Sender: TObject);
begin
    Application.Terminate;
end;

end.