modiq_f.sci

numerical modulator with matlab

//MODIQ_f Scicos I/Q Modulator block
//Classical interface function ver1.0 - scilab-2.7
//8 novembre 2003 - IRCOM GROUP - Author : A.Layec
function [x,y,typ]=MODIQ_f(job,arg1,arg2)
x=[];y=[];typ=[]
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
   x=arg1;
   graphics=arg1.graphics;model=arg1.model;
   exprs=graphics.exprs;

   while %t do

      [ok,wo,exprs]=getvalue('Set I/Q Modulator block',...
      ['Vector of carrier frequencies'],...
      list('vec',-1),exprs);

      if ~ok then break,end;
        nu=size(wo,'*')
        [model,graphics,ok]=check_io(model,graphics,[nu;nu],[nu;nu],1,[])
        if ok then
           graphics.exprs=exprs;
           model.rpar=wo,
           x.graphics=graphics; x.model=model;
           break;
        end
   end

case 'define' then
  wo=1
  nu=1

  model=scicos_model()
  model.sim=list('modiq',2)
  model.in=[nu;nu]
  model.out=[nu;nu]
  model.evtin=1
  model.evtout=[]
  model.dstate=[]
  model.rpar=wo
  model.ipar=[]
  model.blocktype='d'
  model.firing=[]
  model.dep_ut=[%f %f]

  gr_i=['txt=[''I              Re'';''   Mod I/Q'';''Q            Img''];';
    'xstringb(orig(1),orig(2),txt,sz(1),sz(2),''fill'');']
  exprs=[sci2exp(wo)];
  x=standard_define([3 2],model,exprs,gr_i)
end
endfunction