stockbit_f.sci

numerical modulator with matlab

//STOCKBIT_f Scicos Binary accumulator function block
//Classical interface function ver1.0 - scilab-2.7
//12 novembre 2003 - IRCOM GROUP - Author : A.Layec
function [x,y,typ]=STOCKBIT_f(job,arg1,arg2)
x=[];y=[];typ=[]
select job
case 'plot' then
  standard_draw(arg1)
case 'getinputs' then
  [x,y,typ]=standard_inputs(arg1)
case 'getoutputs' then
  [x,y,typ]=standard_outputs(arg1)
case 'getorigin' then
  [x,y]=standard_origin(arg1)
case 'set' then
   x=arg1;
   graphics=arg1.graphics;model=arg1.model;
   exprs=graphics.exprs;

   while %t do

      [ok,nbit,nbpaquet,initc,initv,exprs]=getvalue('Scicos Binary accumulator function block',...
      ['Number of bit';'Number of packet';'Initial counter value';'Initial discret value'],...
      list('vec',-1,'vec',-1,'vec',-1,'vec',-1),exprs);

      if ~ok then break,end;

      if size(nbit)==size(nbpaquet) then
       Nu=size(nbit,'*');
       if ok then
          graphics.exprs=exprs
          nbit=int(nbit);nbpaquet=int(nbpaquet)
          ipar=[nbit(:);nbpaquet(:)]
          model.ipar=ipar(:)
          model.dstate=[initc(:);initv(:)]
          model.in=Nu;model.out=Nu
          x.graphics=graphics; x.model=model;
          break;
       end
      else
       message('Vector Number of bit and Vector Number of packet must have the same size');
      end
   end

case 'define' then
  Nu=1
  nbit=3
  nbpaquet=4
  initc=0
  initv=0

  model=scicos_model()
  model.sim=list('stockbit',2)
  model.in=Nu
  model.out=Nu
  model.evtin=1
  model.evtout=[]
  model.dstate=[initc;initv]
  model.rpar=[]
  model.ipar=[nbit;nbpaquet]
  model.blocktype='d'
  model.firing=[]
  model.dep_ut=[%f %f]

  gr_i=['txt=[''Stockbit''];';
    'xstringb(orig(1),orig(2),txt,sz(1),sz(2),''fill'');']
  exprs=[string(nbit);string(nbpaquet);string(initc);string(initv)]
  x=standard_define([2 2],model,exprs,gr_i)
end
endfunction