phone_fun.asp

网络办公系统源码

<%
'//广州首易接口
Function send_mobile(vsendno,vmsg)
   Dim CorpID,LoginName,Passwd
   Dim mrs,msql
   Psql="select * from sysphoneconfig Where ID=3"
   Call OpenRs(Mrs,Psql,1)

  if not Mrs.eof then
    CorpID=Mrs("UserID")
	LoginName=Mrs("UserName")
	Passwd=Mrs("UserPass")
  end if
  Mrs.close
  set Mrs=nothing
msg=Server.URLEncode(vmsg)
send_no=vsendno
Dim objHttpRequest	'XML文档对象
'根据参数，生成调用URL,因为是测试例子，不对变量为空的情况做处理
URL = "http://web.mobset.com/SDK/Sms_Send.asp?CorpID="&CorpID&"&LoginName="&LoginName&"&Passwd="&Passwd&"&send_no="&send_no&"&Timer="&now()&"&msg="&msg
'调用MSXML，发送请求
'set objHttpRequest = CreateObject("MSXML2.XMLHTTP.4.0" )
set objHttpRequest = CreateObject("Microsoft.XMLHTTP" )
if objHttpRequest is Nothing Then
   send_mobile=False
  exit function
end if

objHttpRequest.open "GET",URL,False
objHttpRequest.send()
if objHttpRequest.status <> 200  then
 '返回错误
 send_mobile=False
  exit function
end if

'取返回信息，并且分析
retMsg = objHttpRequest.responseText
Ret   = left(retMsg,InStr(retMsg,",")-1)
iRet  = Cint(Ret)
if iRet>0  then  '判断是否发送成功
    SendID = right(retMsg,len(retMsg)-InStr(retMsg,","))
    send_mobile=true
else
    send_mobile=False
end if
'释放资源
Set objHttpRequest = Nothing 		
end function

'//调用深圳市巨澜信息技术有限公司 
Function Send_Phone(vsendno,vmsg) '最多可输入手机60/小灵通58个中文字符或手机120/小灵通116个纯英文字符
   Dim CorpID,LoginName,Passwd
   Dim mrs,msql
   Psql="select * from sysphoneconfig Where ID=2"
   Call OpenRs(Mrs,Psql,1)
    if not Mrs.eof then
    CorpID=Mrs("UserID")
	LoginName=Mrs("UserName")
	Passwd=Mrs("UserPass")
     end if
     Call CloseRs(Mrs)
msg=vmsg
send_no=replace(vsendno,", ",",")
send_no=replace(send_no," ",",")

Dim objHttpRequest
'"http://WWW.SURGE.COM.CN:7001/smsHttp?username=user&password=pass&from=13823383105&to=130xxxxxxxxx&content=hell,world&presendTime=2003-02-03 12:12:03"
URL = "http://WWW.SURGE.COM.CN:7001/smsHttp?username="&CorpID&":"&LoginName&"&password="&Passwd&"&from=13888888888&to="&send_no&"&content="&msg&"&presendTime="&FormatDate(Now(),1)&""

set objHttpRequest = CreateObject("Microsoft.XMLHTTP" )
if objHttpRequest is Nothing Then
   Send_Phone=False
  exit function
end if

objHttpRequest.open "GET",URL,False
objHttpRequest.send()
if objHttpRequest.status <> 200  then
  Send_Phone=False
  exit function
end if

retMsg = objHttpRequest.responseText
if instr(retMsg,"OK")<>0 then
    SendID = right(retMsg,len(retMsg)-3)
    Send_Phone=true
else
    Send_Phone=False
end if

Set objHttpRequest = Nothing 		
end function

'----------------------------------------------------------------
'//发送邮件
'//
function sendmail(sendto,subject,body)

   Dim MailFrom,MailServer,MailUserName,MailPassword,leadermail
   Dim Mrs,msql
   msql="select * from oa_mailconfig Where companyid="&session("companyid")
   set Mrs=conn.execute(msql)
    if not Mrs.eof then
    	MailFrom=trim(Mrs("MailFrom"))
		MailServer=trim(Mrs("MailServer"))
		MailUserName=trim(Mrs("MailUserName"))
		MailPassword=trim(Mrs("MailPassword"))
		leadermail=trim(Mrs("leadermail"))
     end if
    Mrs.close
	set Mrs=nothing

'括号里面分别是：发送邮件服务器，邮件接收人，发送人，登录邮箱的用户名，登录邮箱的密码，邮件主题，邮件内容 
Set jmail = Server.CreateObject("JMAIL.Message") '建立发送邮件的对象  
jmail.silent = true '屏蔽例外错误，返回FALSE跟TRUE两值j  
jmail.logging = true '启用邮件日志  
jmail.Charset = "GB2312" '邮件的文字编码为国标  
jmail.ContentType = "text/html" '邮件的格式为HTML格式  
jmail.AddRecipient sendto '邮件收件人的地址  
jmail.From = MailFrom '发件人的E-MAIL地址  
jmail.MailServerUserName = MailUserName '登录邮件服务器所需的用户名  
jmail.MailServerPassword = MailPassword '登录邮件服务器所需的密码  
jmail.Subject = subject '邮件的标题  
jmail.Body = body '邮件的内容  
jmail.Priority = 1 '邮件的紧急程序，1 为最快，5 为最慢， 3 为默认值  
sendok=jmail.Send(MailServer) '执行邮件发送（通过邮件服务器地址
jmail.close 
  
if sendok=false then 
	response.Write("<script language=""javascript"">alert(""发送邮件失败！\n请确认你输入的邮件地址是正确的！"");history.back();</script>")
else
	response.Write("<script language=""javascript"">alert(""发送邮件成功！"");history.back();</script>")
end if 
end function 
%>