message_form_inc.asp

简单的asp论坛源码系统,很适用于初学者!界面简洁,功能齐全

		'Create lists of years for birthdays
		For intLoop = CInt(Year(Now())) to CInt(Year(Now()))+1
			Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
			If intEventYearEnd = intLoop Then Response.Write(" selected")
			Response.Write(">" & intLoop & "</option>")
		Next

%>
    </select>
    <span class="smText">(<% = strTxtNotRequiredForSingleDateEvents %>)</span>
   </td>
  </tr><%

	End If
	
	'*************** Event End *******************
End If


	




'If this is a new poll then display space to enter the poll
If strMode = "poll" OR strMode = "editPoll" Then

	%><!--#include file="poll_form_inc.asp" --><%

End If


'The message textarea
%>
  <tr>
   <td valign="top" align="right" width="15%"><br /><br /><br /><% = strTxtMessage %>:<%


'*************** Emoticons *******************

'If emoticons are enabled show them next to the post window
If blnEmoticons Then

%>
   <table border="0" cellspacing="0" cellpadding="4" align="center">
    <tr><td class="smText" colspan="3" align="center"><br /><br /><% = strTxtEmoticons %></td></tr><%

	'Intilise the index position (we are starting at 1 instead of position 0 in the array for simpler calculations)
	intIndexPosition = 1

	'Calcultae the number of outer loops to do
	intNumberOfOuterLoops = 5

	'If there is a remainder add 1 to the number of loops
	If UBound(saryEmoticons) MOD 2 > 0 Then intNumberOfOuterLoops = intNumberOfOuterLoops + 1

	'Loop throgh th list of emoticons
	For intLoop = 1 to intNumberOfOuterLoops


	        Response.Write("<tr>")

		'Loop throgh th list of emoticons
		For intInnerLoop = 1 to 3

			'If there is nothing to display show an empty box
			If intIndexPosition > UBound(saryEmoticons) Then
				Response.Write(vbCrLf & "    <td>&nbsp;</td>")

			'Else show the emoticon
			Else
				If RTEenabled() <> "false" AND blnRTEEditor AND blnWYSIWYGEditor Then
					Response.Write(vbCrLf & "    <td><img src=""" & saryEmoticons(intIndexPosition,3) & """ border=""0"" title=""" & saryEmoticons(intIndexPosition,1) & """ OnClick=""AddEmoticon(this)"" id=""" & saryEmoticons(intIndexPosition,3) & """ style=""cursor: pointer;""></td>")
				Else
					Response.Write(vbCrLf & "    <td><img src=""" & saryEmoticons(intIndexPosition,3) & """ border=""0"" title=""" & saryEmoticons(intIndexPosition,1) & """ OnClick=""AddEmoticon('" & saryEmoticons(intIndexPosition,2) & "')"" id=""" & saryEmoticons(intIndexPosition,3) & """ style=""cursor: pointer;""></td>")
	              		End If
	              	End If

	              'Minus one form the index position
	              intIndexPosition = intIndexPosition + 1
		Next

		Response.Write("</tr>")

	Next

	If RTEenabled() <> "false" AND blnRTEEditor AND blnWYSIWYGEditor Then
		Response.Write(vbCrLf & "    <tr><td colspan=""3"" align=""center""><a href=""javascript:winOpener('RTE_popup_emoticons.asp" & strQsSID1 & "','emot',0,0,450,340)"" class=""smLink"" tabindex=""100"">" & strTxtMore & "</a></td></tr>")
	Else
		Response.Write(vbCrLf & "    <tr><td colspan=""3"" align=""center""><a href=""javascript:winOpener('non_RTE_popup_emoticons.asp" & strQsSID1 & "','emot',0,0,450,340)"" class=""smLink"" tabindex=""100"">" & strTxtMore & "</a></td></tr>")
	End If
%>
   </table>
  </td><%
End If

'******************************************

%>
   <td width="70%" valign="top"><%


'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
Response.Write(vbCrLf & vbCrLf & "<!--//" & _
vbCrLf & "/* *******************************************************" & _
vbCrLf & "Software: Web Wiz Rich Text Editor(TM) " & _
vbCrLf & "Info: http://www.richtexteditor.org" & _
vbCrLf & "Copyright: (C)2001-2008 Web Wiz(TM). All rights reserved" & _
vbCrLf & "******************************************************* */" & _
vbCrLf & "//-->")
'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******



'Name of the HTML form the textarea is within
Const strFormName = "frmMessageForm"

'ID tag name of HTML textarea being replaced
Const strTextAreaName = "message"


'Load default CSS and Javascript
Response.Write(vbCrLf & "    <script language=""JavaScript"" src=""RTE_javascript_common.asp"" type=""text/javascript""></script>")


'If this is an RTE enabled web browser load in the RTE content
If RTEenabled() <> "false" AND blnRTEEditor AND blnWYSIWYGEditor Then
	
	
	'If this is a quick reply to full reply then load up the session variable to pass across to the full RTE area
	If strMode = "QuickToFull" AND strMessage <> "" Then Session("Message") = strMessage


	'If this is Gecko based browser link to JS code for Gecko
	If (RTEenabled = "Gecko" OR RTEenabled = "opera") AND blnEmoticons Then Response.Write(vbCrLf & "    <script language=""JavaScript"" src=""RTE_javascript_gecko.asp"" type=""text/javascript""></script>")


	'Load in Javascript for RTE browsers (creating an IFrame for the RTE area)
%>
    <script language="JavaScript" src="RTE_javascript.asp?textArea=<% = Server.URLEncode(strTextAreaName) & strQsSID2 %>" type="text/javascript"></script>
    <script language="javascript" type="text/javascript">
       WebWizRTEtoolbar('<% = strFormName %>');
       document.write ('<iframe id="WebWizRTE" src="RTE_textarea.asp?mode=<% = strMode %>&POID=<% = lngMessageID %>&ID=<% = CInt(RND * 2000) & strQsSID2 %>" width="600" height="250" style="border: #A5ACB2 1px solid" onLoad="initialiseWebWizRTE();" tabindex="20"></iframe>');
    </script>
    <noscript><strong><br /><br /><% = strTxtJavaScriptEnabled %></strong></noscript>
    <input type="hidden" name="message" id="message" value="" />
    <input type="hidden" name="browser" id="browser" value="RTE" /><%

'If this is not an RTE enabled web browser load in the NON-RTE content
Else
%>
    <script language="JavaScript" src="non_RTE_javascript.asp?textArea=<% = Server.URLEncode(strTextAreaName) & strQsSID2 %>" type="text/javascript"></script>
    <script language="JavaScript" type="text/javascript">WebWizRTEtoolbar('<% = strFormName %>');</script>
    <textarea name="message" id="message" rows="15" wrap="virtual" tabindex="20" style="width:596px;" /><%

	If strMode="edit" OR strMode = "quote" OR strMode = "QuickToFull" or strMode="editTopic" or strMode="PM" Then Response.Write(vbCrLf & strMessage)

%></textarea><%

End If

'********************************************************************

%>
   </td>
  </tr>
  <tr>
   <td align="right">&nbsp;</td>
   <td align="left" valign="bottom">&nbsp;<input type="checkbox" name="forumCodes" value="True" checked tabindex="21" /><% = strTxtEnable %> <a href="javascript:winOpener('BBcodes.asp<% = strQsSID1 %>','codes',1,1,610,500)"><% = strTxtForumCodes %></a> <% = strTxtToFormatPosts %></td>
  </tr><%





'If not PM then display another row
If NOT strMode = "PM" Then

	'If signature of e-mail notify then display row to show
	If (blnLoggedInUserEmail = True AND blnEmail = True) OR blnLoggedInUserSignature = True Then

%>
  <tr>
   <td align="right">&nbsp;</td>
   <td align="left" valign="bottom"><%

		'If the user has a signature offer them the chance to show it
		If blnLoggedInUserSignature Then

			Response.Write(vbCrLf & "    &nbsp;<input type=""checkbox"" name=""signature"" id=""signature"" value=""True""")
			If blnAttachSignature = True Then Response.Write(" checked")
			Response.Write(" tabindex=""22"" />" & strTxtShowSignature & "&nbsp;")

		End If

		'Display e-mail notify of replies option
		If blnEmail AND blnLoggedInUserEmail Then

			Response.Write(vbCrLf & "    &nbsp;<input type=""checkbox"" name=""email"" id=""email"" value=""True""")
			If blnReplyNotify Then Response.Write(" checked")
			Response.Write(" tabindex=""23"" />" & strTxtEmailNotify & "&nbsp;")

		End If

%>
   </td>
  </tr><%


	End If

'If this is a private e-mail and e-mail is on and the user gave an e-mail address let them choose to be notified when pm msg is read
ElseIf strMode = "PM" AND blnEmail AND blnLoggedInUserEmail Then

%>
   <tr>
   <td align="right" width="92">&nbsp;</td>
   <td valign="bottom">&nbsp;<input type="checkbox" name="email" id="email" value="True" tabindex="24"><span><% = strTxtEmailNotifyWhenPMIsRead %></span></td>
  </tr><%

End If



'Display CAPTCHA images for Guest posting
If blnGuestPostingCAPTCHA AND lngLoggedInUserID = 2 Then 
	
	%>
 <tr>
  <td align="right" valign="top"><% = strTxtUniqueSecurityCode %>:</td>
  <td><!--#include file="CAPTCHA_form_inc.asp" --><span class="smText"><% = strTxtEnterCAPTCHAcode %></span></td>
 </tr><%
     
End If

%>
 <tr>
  <td><%

If NOT strMode = "PM" Then
	
	'If strMode = "QuickToFull" Then strMode = "reply"

%>
    <input type="hidden" name="mode" id="mode" value="<% = strMode %>" />
    <input type="hidden" name="FID" id="FID" value="<% = intForumID %>" />
    <input type="hidden" name="TID" id="TID" value="<% = lngTopicID %>" />
    <input type="hidden" name="PID" id="PID" value="<% = lngMessageID %>" />
    <input type="hidden" name="PN" id="PN" value="<% = intRecordPositionPageNum %>" /><%
         'If reply get the thread position number in the topic
         If strMode = "reply" Then
         	Response.Write(vbCrLf & "    <input type=""hidden"" name=""ThreadPos"" id=""ThreadPos"" value=""" & (intTotalRecords + 1) & """ />")
	End If
End If
%>
    <input type="hidden" name="pre" id="pre" value="" />
  </td>
  <td width="70%" align="left">
   <input type="submit" id="Submit" name="Submit" <%

'Select the correct button name for the page
If strMode="edit" OR strMode = "editTopic" OR strMode = "editPoll" Then

	Response.Write("value=""" & strTxtUpdatePost & """ ")

ElseIf strMode = "new" OR strMode = "poll" Then

	Response.Write("value=""" & strTxtPostNewTopic2 & """ ")

ElseIf strMode = "PM" Then

	Response.Write("value=""" & strTxtSendPM & """ ")
Else

	Response.Write("value=""" & strTxtPostReply & """ ")
End If


'If RTE enabled then use javascript to submit the RTE data
If RTEenabled() <> "false" AND blnRTEEditor AND blnWYSIWYGEditor Then
	Response.Write("onclick=""document.getElementById('message').value=document.getElementById('WebWizRTE').contentWindow.document.body.innerHTML;""")
End If

%> tabindex="26" />
   <input type="button" name="Preview" id="Preview" value="<% = strTxtPreviewPost %>" onclick="<%
   
'If RTE enabled get the preview content from the iframe
If RTEenabled() <> "false" AND blnRTEEditor AND blnWYSIWYGEditor Then
	Response.Write("document.getElementById('pre').value=document.getElementById('WebWizRTE').contentWindow.document.body.innerHTML;")
Else
	Response.Write("document.getElementById('pre').value=document.getElementById('message').value;")
End If

%> OpenPreviewWindow(document.frmMessageForm);" tabindex="27" />
   <input type="reset" name="Reset" id="Reset" value="<% = strTxtClearForm %>" tabindex="28" />
  </td>
 </tr>
</table>
</form>