pm_inbox.asp

简单的asp论坛源码系统,很适用于初学者!界面简洁,功能齐全

vbCrLf & "Software: Web Wiz Forums(TM) ver. " & strVersion & "" & _
vbCrLf & "Info: http://www.webwizforums.com" & _
vbCrLf & "Copyright: (C)2001-2008 Web Wiz(TM). All rights reserved" & _
vbCrLf & "******************************************************* */" & _
vbCrLf & "//-->" & vbCrLf & vbCrLf)
'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******


'If there are more than 1 pm's write the function
If intNumOfPMs > 1 Then

	Response.Write("<script  language=""JavaScript"" type=""text/javascript"">")

	Response.Write(vbCrLf & "//Funtion to check or uncheck all the delete boxes")
	Response.Write(vbCrLf & "function checkAll(){")
		
	Response.Write(vbCrLf & vbCrLf & "	for (i=0; i < document.frmDelete.chkDelete.length; i++){")
	Response.Write(vbCrLf & "		document.frmDelete.chkDelete[i].checked = document.frmDelete.chkAll.checked;")
	Response.Write(vbCrLf & "	}")
	Response.Write(vbCrLf & "}")
	Response.Write(vbCrLf & "</script>")
End If

'Page to link to for mutiple page (with querystrings if required)
strLinkPage = "pm_inbox.asp?"
%>
<link href="<% = strCSSfile %>default_style.css" rel="stylesheet" type="text/css" />
<!-- #include file="includes/header.asp" -->
<!-- #include file="includes/status_bar_header_inc.asp" -->
<table class="basicTable" cellspacing="0" cellpadding="3" align="center">
 <tr>
  <td align="left"><h1><% = strTxtPrivateMessenger & ": " & strTxtInbox  %></h1></td>
</tr>
</table>
<br />
<table class="basicTable" cellspacing="0" cellpadding="0" align="center"> 
 <tr> 
  <td class="tabTable">
   <a href="pm_welcome.asp<% = strQsSID1 %>" title="<% = strTxtPrivateMessenger %>" class="tabButton">&nbsp;<img src="<% = strImagePath %>messenger.<% = strForumImageType %>" border="0" alt="<% = strTxtPrivateMessenger %>" /> <% = strTxtMessenger %></a>
   <a href="pm_inbox.asp<% = strQsSID1 %>" title="<% = strTxtPrivateMessenger & " " & strTxtInbox %>" class="tabButtonActive">&nbsp;<img src="<% = strImagePath %>inbox_messages.<% = strForumImageType %>" border="0" alt="<% = strTxtPrivateMessenger & " " & strTxtInbox %>" /> <% = strTxtInbox %></a>
   <a href="pm_outbox.asp<% = strQsSID1 %>" title="<% = strTxtPrivateMessenger & " " & strTxtOutbox %>" class="tabButton">&nbsp;<img src="<% = strImagePath %>sent_messages.<% = strForumImageType %>" border="0" alt="<% = strTxtPrivateMessenger & " " & strTxtOutbox %>" /> <% = strTxtOutbox %></a>
   <a href="pm_new_message_form.asp<% = strQsSID1 %>" title="<% = strTxtNewPrivateMessage %>" class="tabButton">&nbsp;<img src="<% = strImagePath %>new_message.<% = strForumImageType %>" border="0" alt="<% = strTxtNewPrivateMessage %>" /> <% = strTxtNewMessage %></a>
  </td>
 </tr>
</table>
<table class="basicTable" cellspacing="0" cellpadding="3" align="center">
 <tr>
  <td align="right">&nbsp;<!-- #include file="includes/page_link_inc.asp" --></td>
 </tr>
</table>
<form name="frmDelete" id="frmDelete" method="post" action="pm_delete_message.asp?Page=<% = intRecordPositionPageNum %><% = strQsSID2 %>" OnSubmit="return confirm('<% = strTxtDeletePrivateMessageAlert %>')">
<table cellspacing="1" cellpadding="3" class="tableBorder" align="center">
    <tr class="tableLedger">
     <td width="3%"" align="center"><% = strTxtRead %></td>
     <td width="39%"><% = strTxtMessageTitle %></td>
     <td width="22%"><% = strTxtMessageFrom %></td>
     <td width="31%"><% = strTxtDate %></td>
     <td width="5%" align="center"><%

'If there are more than 1 pm's write the check all box
If intNumOfPMs > 1 Then Response.Write("<input type=""checkbox"" name=""chkAll"" id=""chkAll"" onclick=""checkAll();"">") Else Response.Write("&nbsp;")

Response.Write("</td>")
Response.Write(vbCrLf & "    </tr>")
    
'Check there are PM messages to display
If intNumOfPMs = 0 Then

	'If there are no pm messages to display then display the appropriate error message
	Response.Write(vbCrLf & "    <tr class=""tableRow""><td colspan=""5"" align=""center""><br />" & strTxtNoPrivateMessages & " " & strTxtInbox & "<input type=""hidden"" name=""chkDelete"" id=""chkDelete"" value=""-1""><br /><br /></td></tr>")

'Else there the are topic's so write the HTML to display the topic names and a discription
Else 
	
	'Do....While Loop to loop through the recorset to display the forum members
	Do While intCurrentRecord < intEndPosition

		'If there are no member's records left to display then exit loop
		If intCurrentRecord >= intNumOfPMs Then Exit Do
			
			
			'SQL Query Array Look Up table
			'0 = PM_ID
			'1 = From_ID
			'2 = PM_Tittle
			'3 = PM_Message_Date
			'4 = Read_Post
			'5 = Username
			
			
	%>
    <tr class="<% If (intCurrentRecord MOD 2 = 0 ) Then Response.Write("evenTableRow") Else Response.Write("oddTableRow") %>"> 
     <td align="center"><% 
      
     		If CBool(sarryPmMessage(4,intCurrentRecord)) = False Then
     			Response.Write("<img src=""" & strImagePath & "unread_mail." & strForumImageType & """ alt=""" & strTxtUnreadMessage & """ title=""" & strTxtUnreadMessage & """ />")
     		Else
     			Response.Write("<img src=""" & strImagePath & "read_mail." & strForumImageType & """ alt=""" & strTxtReadMessage & """ title=""" & strTxtReadMessage & """ />")
     		End If
     
     %></td>
     <td><% Response.Write("<a href=""pm_message.asp?ID=" & sarryPmMessage(0,intCurrentRecord) & strQsSID2 & """>" & formatInput(sarryPmMessage(2,intCurrentRecord)) & "</a>") %></td>
     <td><a href="member_profile.asp?PF=<% = sarryPmMessage(1,intCurrentRecord) & strQsSID2 %>" rel="nofollow"><% = sarryPmMessage(5,intCurrentRecord) %></a></td>
     <td nowrap><% Response.Write(DateFormat(sarryPmMessage(3,intCurrentRecord)) & " " & strTxtAt & " " & TimeFormat(sarryPmMessage(3,intCurrentRecord))) %></td>
     <td align="center"><input type="checkbox" name="chkDelete" id="chkDelete" value="<% = sarryPmMessage(0,intCurrentRecord) %>"></td>
    </tr><%
		
		'Move to the next record
		intCurrentRecord = intCurrentRecord + 1
					
	'Loop back round
	Loop
End If
%>
</table>
<table class="basicTable" cellspacing="0" cellpadding="3" align="center">
   <tr>
      <td width="94%"><img src="<% = strImagePath %>unread_mail.<% =  strForumImageType %>" alt="<% = strTxtUnreadMessage %>" title="<% = strTxtUnreadMessage %>" /> <% = strTxtUnreadMessage %>&nbsp;&nbsp;<img src="<% = strImagePath %>read_mail.<% = strForumImageType %>" alt="<% = strTxtReadMessage %>" title="<% = strTxtReadMessage %>" /> <% = strTxtReadMessage %></td>
      <td width="6%" align="right"><% 

'Display delete buttons      
If intNumOfPMs > 0 Then  
      	
      	Response.Write("<input type=""submit"" name=""delAll"" id=""delAll"" value=""" & strTxtDelete & " " & strTxtAll & """ />")
      	Response.Write("&nbsp;<input type=""submit"" name=""delSel"" id=""delSel"" value=""" & strTxtDelete & " " & strTxtSelected & """ />") 
      	
Else 
      	Response.Write("&nbsp;") 
      	
End If

%></td>
    </tr>
 </table>
 <table class="basicTable" cellspacing="0" cellpadding="3" align="center">
   <tr>
      <td colspan="2"><% Response.Write(strLoggedInUsername & ", " & strTxtYouHave & " " & intNumOfPMs & " " & strTxtPrivateMessagesYouCanReceiveAnother & " " & (intNumPrivateMessages-intNumOfPMs) & " " & strTxtOutOf & " " & intNumPrivateMessages) %></td>
     </tr>
     <tr> 
      <td>
       <table class="tableBorder" cellspacing="0" cellpadding="3" style="width:300px;">
           <tr class="tableRow"><td colspan="3" align="center" class="smText"><% = strTxtYourInboxIs & " " & FormatPercent((intNumOfPMs / intNumPrivateMessages), 0) & " " & strTxtFull %></td></tr>
           <tr class="tableRow"><td colspan="3"><img src="<% = strImagePath %>bar_graph_image.gif" width="<% = FormatPercent((intNumOfPMs / intNumPrivateMessages), 0) %>" height="13"  title="<% = strTxtYourInboxIs & " " & FormatPercent((intNumOfPMs / intNumPrivateMessages), 0) & " " & strTxtFull %>" /></td></tr>
           <tr class="tableRow">
            <td width="30%" class="smText">0%</td>
            <td width="41%" align="center" class="smText">50%</td>
            <td width="29%" align="right" class="smText">100%</td>
           </tr>
        </table> 
       </td>
       <td align="right" nowrap><!-- #include file="includes/page_link_inc.asp" --></td>
     </tr>
</table>
<br />
<table class="basicTable" cellspacing="0" cellpadding="3" align="center">
   <tr>
   <td><!-- #include file="includes/forum_jump_inc.asp" --></td>
  </tr>
 </table>
<div align="center"><br />
 <%
'Clear server objects
Call closeDatabase()

'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
If blnLCode = True Then
	
	If blnTextLinks = True Then 
		Response.Write("<span class=""text"" style=""font-size:10px"">Bulletin Board Software by <a href=""http://www.webwizforums.com"" target=""_blank"" style=""font-size:10px"">Web Wiz Forums&reg;</a> version " & strVersion & "</span>")
	Else
  		Response.Write("<a href=""http://www.webwizforums.com"" target=""_blank""><img src=""webwizforums_image.asp"" border=""0"" title=""Bulletin Board Software by Web Wiz Forums&reg; version " & strVersion& """ alt=""Bulletin Board Software by Web Wiz Forums&reg; version " & strVersion& """ /></a>")
	End If
	
	Response.Write("<br /><span class=""text"" style=""font-size:10px"">Copyright &copy;2001-2008 <a href=""http://www.webwizguide.com"" target=""_blank"" style=""font-size:10px"">Web Wiz</a></span>")
End If 
'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******


'Display the process time
If blnShowProcessTime Then Response.Write "<span class=""smText""><br /><br />" & strTxtThisPageWasGeneratedIn & " " & FormatNumber(Timer() - dblStartTime, 3) & " " & strTxtSeconds & "</span>"

'Display a msg if a PM has been deleted
If Request.QueryString("MSG") = "DEL" Then
		Response.Write("<script  language=""JavaScript"">")
		Response.Write("alert('" & strTxtMeassageDeleted & ".');")
		Response.Write("</script>")
End If
%>
</div>
 <!-- #include file="includes/footer.asp" -->