pop_up_topic_admin.asp

简单的asp论坛源码系统,很适用于初学者!界面简洁,功能齐全

 <form name="frmTopicAdmin" id="frmTopicAdmin" method="post" action="pop_up_topic_admin.asp<% = strQsSID1 %>" onSubmit="return CheckForm();">
  <tr class="tableRow" colspan="2">
    <td colspan="2">*<% = strTxtRequiredFields %></td>
  </tr>
  <tr class="tableRow">
   <td align="right" width="20%"><% = strTxtSubjectFolder %>*:</td>
   <td width="80%"><input type="text" name="subject" size="30" maxlength="50" value="<% = strSubject %>" /></td>
  </tr><%

'Display message icon drop down
If blnTopicIcon Then

	'Get the topic icon array
	%><!--#include file="includes/topic_icon_inc.asp" -->
  <tr class="tableRow">
   <td align="right" width="20%"><% = strTxtMessageIcon %>:</td>
   <td align="left" width="80%">
    <select name="icon" id="icon" onchange="(T_icon.src = icon.options[icon.selectedIndex].value)" >
     <option value="<% = strImagePath %>blank_smiley.gif"<% If strTopicIcon = "" Then Response.Write(" selected") %>><% = strTxtNoneSelected %></option><%

	'Loop through to display topic icons
	For intLoop = 1 TO Ubound(saryTopicIcon)

		Response.Write(vbCrLf & "     <option value=""" & saryTopicIcon(intLoop,2) & """")
		If strTopicIcon = saryTopicIcon(intLoop,2) Then Response.Write(" selected")
		Response.Write(">" & saryTopicIcon(intLoop,1) & "</option>")
	Next

	'If no topic Icon then get the default one
	If strTopicIcon = "" Then strTopicIcon = strImagePath & "blank_smiley.gif"
%>
    </select>
    &nbsp;&nbsp;<img src="<% = strTopicIcon %>" border="0" id="T_icon" alt"<% = strTxtMessageIcon %>" />
   </td>
  </tr><%

End If

%>
  <tr class="tableRow">
   <td align="right"><% = strTxtPinnedTopic %>:</td>
    <td>
    <select name="priority">
     <option value="0"<% If intTopicPriority = 0 Then Response.Write(" selected") %>><% = strTxtNormal %></option>
     <option value="1"<% If intTopicPriority = 1 Then Response.Write(" selected") %>><% = strTxtPinnedTopic %></option>
     <option value="2"<% If intTopicPriority = 2 Then Response.Write(" selected") %>><% = strTopThisForum %></option><%

'If this is the forum admin let them post a priority post to all forums
If blnAdmin Then 
         		%>
     <option value="3"<% If intTopicPriority = 3 Then Response.Write(" selected") %>><% = strTxtTopAllForums %></option><%

End If
        	%>
    </select></td>
   </tr><%




'Display Calendar event date input (if this is an event)
If blnCalendar AND (isDate(dtmEventDate) OR isDate(dtmEventDateEnd)) Then
%>
  <tr class="tableRow">
   <td align="right" valign="top"><% = strTxtCalendarEvent %>:</td>
   <td align="left">
    <% = strTxtStartDate %>:
    <br />
    &nbsp;&nbsp;&nbsp;&nbsp;<% = strTxtDay %>
    <select name="eventDay" id="eventDay">
     <option value="0"<% If intEventDay = 0 Then Response.Write(" selected") %>>----</option><%

	'Create lists day's for birthdays
	For intLoop = 1 to 31
		Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
		If intEventDay = intLoop Then Response.Write(" selected")
		Response.Write(">" & intLoop & "</option>")
	Next

%>
    </select>
    <% = strTxtCMonth %>
    <select name="eventMonth" id="eventMonth">
     <option value="0"<% If intEventMonth = 0 Then Response.Write(" selected") %>>---</option><%

	'Create lists of days of the month for birthdays
	For intLoop = 1 to 12
		Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
		If intEventMonth = intLoop Then Response.Write(" selected")
		Response.Write(">" & intLoop & "</option>")
	Next

%>
    </select>
    <% = strTxtCYear %>
    <select name="eventYear" id="eventYear">
     <option value="0"<% If intEventYear = 0 Then Response.Write(" selected") %>>-----</option><%

	'If this is an old event and the date is from a previous year, display that year
	If intEventYear <> 0 AND intEventYear < CInt(Year(Now())) Then Response.Write(VbCrLf & "     <option value=""" & intEventYear & """ selected>" & intEventYear & "</option>")

	'Create lists of years for birthdays
	For intLoop = CInt(Year(Now())) to CInt(Year(Now()))+1
		Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
		If intEventYear = intLoop Then Response.Write(" selected")
		Response.Write(">" & intLoop & "</option>")
	Next

%>
    </select>
    <br />
    <% = strTxtEndDate %>: 
    <br />
    &nbsp;&nbsp;&nbsp;&nbsp;<% = strTxtDay %>
    <select name="eventDayEnd" id="eventDayEnd">
     <option value="0"<% If intEventDayEnd = 0 Then Response.Write(" selected") %>>----</option><%

		'Create lists day's for birthdays
		For intLoop = 1 to 31
			Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
			If intEventDayEnd = intLoop Then Response.Write(" selected")
			Response.Write(">" & intLoop & "</option>")
		Next

%>
    </select>
    <% = strTxtCMonth %>
    <select name="eventMonthEnd" id="eventMonthEnd">
     <option value="0"<% If intEventMonthEnd = 0 Then Response.Write(" selected") %>>---</option><%

		'Create lists of days of the month for birthdays
		For intLoop = 1 to 12
			Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
			If intEventMonthEnd = intLoop Then Response.Write(" selected")
			Response.Write(">" & intLoop & "</option>")
		Next

%>
    </select>
    <% = strTxtCYear %>
    <select name="eventYearEnd" id="eventYearEnd">
     <option value="0"<% If intEventYear = 0 Then Response.Write(" selected") %>>-----</option><%

		'If this is an old event and the date is from a previous year, display that year
		If intEventYearEnd <> 0 AND intEventYearEnd < CInt(Year(Now())) Then Response.Write(VbCrLf & "     <option value=""" & intEventYearEnd & """ selected>" & intEventYearEnd & "</option>")

		'Create lists of years for birthdays
		For intLoop = CInt(Year(Now())) to CInt(Year(Now()))+1
			Response.Write(vbCrLf & "     <option value=""" & intLoop & """")
			If intEventYearEnd = intLoop Then Response.Write(" selected")
			Response.Write(">" & intLoop & "</option>")
		Next

%>
    </select>
   </td>
  </tr><%

End If




	
	
%>
   <tr class="tableRow">
    <td align="right"><% = strTxtLockedTopic %>:</td>
    <td><input type="checkbox" name="locked" value="true" <% If blnLockedStatus = True Then Response.Write(" checked") %> /></td>
   </tr>
   <tr class="tableRow">
    <td align="right" valign="top"><% = strTxtMoveTopic %>:</td>
    <td><select name="forum" id="forum"><%


'Show forum select
If isArray(sarryForumSelect) Then
	
	'Loop round to show all the categories and forums
	Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
		'Loop through the array looking for forums that are to be shown
		'if a forum is found to be displayed then show the category and the forum, if not the category is not displayed as there are no forums the user can access
		Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
			'Read in details
			blnHideForum = CBool(sarryForumSelect(5,intCurrentRecord))
			blnRead = CBool(sarryForumSelect(6,intCurrentRecord))
					
			'If this forum is to be shown then leave the loop and display the cat and the forums
			If blnHideForum = False OR blnRead = True Then Exit Do
			
			'Move to next record
			intCurrentRecord = intCurrentRecord + 1
		Loop
				
		'If we have run out of records jump out of loop
		If intCurrentRecord > Ubound(sarryForumSelect,2) Then Exit Do
	 
		
		
		'Read in the deatils for the category
		intCatID = CInt(sarryForumSelect(0,intCurrentRecord))
		strCatName = sarryForumSelect(1,intCurrentRecord)		
		
		
		'Display a link in the link list to the forum
		Response.Write vbCrLf & "     <optgroup label=""&nbsp;&nbsp;" & strCatName & """>"
		
		
		
		'Loop round to display all the forums for this category
		Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
			'Read in the forum details from the recordset
			intForumID = CInt(sarryForumSelect(2,intCurrentRecord))
			intSubForumID = CInt(sarryForumSelect(3,intCurrentRecord))
			strForumName = sarryForumSelect(4,intCurrentRecord)
			blnHideForum = CBool(sarryForumSelect(5,intCurrentRecord))
			blnRead = CBool(sarryForumSelect(6,intCurrentRecord))
			
			
			'If this forum is to be hidden but the user is allowed access to it set the hidden boolen back to false
			If blnHideForum = True AND blnRead = True Then blnHideForum = False

			'If the forum is not a hidden forum to this user, display it
			If blnHideForum = False AND intSubForumID = 0 Then
				'Display a link in the link list to the forum
				Response.Write (vbCrLf & "      <option value=""" & intForumID & """")
				If intoldForumID = intForumID Then Response.Write(" selected")
				Response.Write(">&nbsp;" & strForumName & "</option>")	
			End If
			
			
			
			'See if this forum has any sub forums
			'Initilise variables
			intTempRecord = 0
					
			'Loop round to read in any sub forums in the stored array recordset
			Do While intTempRecord <= Ubound(sarryForumSelect,2)
			
				'Becuase the member may have an individual permission entry in the permissions table for this forum, 
				'it maybe listed twice in the array, so we need to make sure we don't display the same forum twice
				If intSubForumID = CInt(sarryForumSelect(2,intTempRecord)) Then intTempRecord = intTempRecord + 1
				
				'If there are no records left exit loop
				If intTempRecord > Ubound(sarryForumSelect,2) Then Exit Do
				
				'If this is a subforum of the main forum then get the details
				If CInt(sarryForumSelect(3,intTempRecord)) = intForumID Then
				
					'Read in the forum details from the recordset
					intSubForumID = CInt(sarryForumSelect(2,intTempRecord))
					strForumName = sarryForumSelect(4,intTempRecord)
					blnHideForum = CBool(sarryForumSelect(5,intTempRecord))
					blnRead = CBool(sarryForumSelect(6,intTempRecord))
					
					
					'If this forum is to be hidden but the user is allowed access to it set the hidden boolen back to false
					If blnHideForum = True AND blnRead = True Then blnHideForum = False
		
					'If the forum is not a hidden forum to this user, display it
					If blnHideForum = False Then
						'Display a link in the link list to the forum
						Response.Write (vbCrLf & "      <option value=""" & intSubForumID & """")
						If intoldForumID = intSubForumID Then Response.Write(" selected")
						Response.Write (">&nbsp&nbsp;-&nbsp;" & strForumName & "</option>")	
					End If
				End If
				
				'Move to next record 
				intTempRecord = intTempRecord + 1
				
			Loop
			
			
					
			'Move to the next record in the array
			intCurrentRecord = intCurrentRecord + 1
			
			
			'If there are more records in the array to display then run some test to see what record to display next and where				
			If intCurrentRecord <= Ubound(sarryForumSelect,2) Then

				'Becuase the member may have an individual permission entry in the permissions table for this forum, 
				'it maybe listed twice in the array, so we need to make sure we don't display the same forum twice
				If intForumID = CInt(sarryForumSelect(2,intCurrentRecord)) Then intCurrentRecord = intCurrentRecord + 1
				
				'If there are no records left exit loop
				If intCurrentRecord > Ubound(sarryForumSelect,2) Then Exit Do
				
				'See if the next forum is in a new category, if so jump out of this loop to display the next category
				If intCatID <> CInt(sarryForumSelect(0,intCurrentRecord)) Then Exit Do
			End If
		Loop
		
		
		Response.Write(vbCrLf & "     </optgroup>")
	Loop
End If
%>
     </select><br />
     <input type="checkbox" name="moveIco" value="true" checked /><% = strTxtShowMovedIconInLastForum %></td>
   </tr><%

'If there is a poll then let the admin moderator edit or delete the poll
If lngPollID <> 0 Then

	%>
   <tr class="tableRow">
    <td align="right"><% = strTxtPoll %></td>
    <td><a href="delete_poll.asp?TID=<% = lngTopicID %>" onclick="return confirm('<% = strTxtAreYouSureYouWantToDeleteThisPoll %>');"><% = strTxtDeletePoll %></a></td>
   </tr><%
End If

%>
   <tr class="tableRow">
    <td align="right" valign="top"><% = strTxtHideTopic %>:</td>
    <td><input type="checkbox" name="hidePost" value="true" <% If blnHidden = True Then Response.Write(" checked") %> /> <span class="smText"><% = strTxtIfYouAreShowingTopic %></span></td>
   </tr>
   <tr align="center" class="tableRow">
    <td valign="top" colspan="2" />
     <input type="hidden" name="TID" id="TID" value="<% = lngTopicID %>" />
     <input type="hidden" name="postBack" id="postBack" value="true" />
    </td>
   </tr>
   <tr class="tableBottomRow">
    <td align="right" colspan="2">
     <input type="submit" name="Submit" id="Submit" value="     <% = strTxtOK %>     " <% If blnDemoMode Then Response.Write(" disabled=""disabled""") %> />&nbsp;<input type="button" name="cancel" value=" <% = strTxtClose %> " onclick="window.close()"></td>
   </tr>
  </form>
</table>
</body>
</html>