email_notify_subscriptions.asp

简单的asp论坛源码系统,很适用于初学者!界面简洁,功能齐全

 
If blnEmail Then

%>
   <a href="email_notify_subscriptions.asp<% If strMode = "A" Then Response.Write("?PF=" & lngEmailUserID & "&M=A" & strQsSID2) Else Response.Write(strQsSID1) %>" title="<% = strTxtSubscriptions %>" class="tabButtonActive">&nbsp;<img src="<% = strImagePath %>subscriptions.<% = strForumImageType %>" border="0" alt="<% = strTxtSubscriptions %>" /> <% = strTxtSubscriptions %></a><%
End If


'Only disply other links if not in admin mode
If strMode <> "A" AND blnActiveMember AND blnPrivateMessages Then

%>
   <a href="pm_buddy_list.asp<% = strQsSID1 %>" title="<% = strTxtBuddyList %>" class="tabButton">&nbsp;<img src="<% = strImagePath %>buddy_list.<% = strForumImageType %>" border="0" alt="<% = strTxtBuddyList %>" /> <% = strTxtBuddyList %></a><%

End If


'If the user is user is using a banned IP redirect to an error page
If blnAttachments OR blnImageUpload Then

%>
   <a href="file_manager.asp<% If strMode = "A" Then Response.Write("?PF=" & lngEmailUserID & "&M=A" & strQsSID2) Else Response.Write(strQsSID1) %>" title="<% = strTxtFileManager %>" class="tabButton">&nbsp;<img src="<% = strImagePath %>file_manager.<% = strForumImageType %>" border="0" alt="<% = strTxtFileManager %>" /> <% = strTxtFileManager %></a><%

End If

%>
  </td>
 </tr>
</table>
<br />
<form name="frmForumDel" id="frmForumDel" method="post" action="email_notify_remove.asp<% If strMode = "A" Then Response.Write("?PF=" & lngEmailUserID & "&M=A" & strQsSID2) Else Response.Write(strQsSID1) %>" OnSubmit="return confirm('<% = strTxtAreYouWantToUnsubscribe & " " & strTxtForums %>')">
<table cellspacing="1" cellpadding="3" class="tableBorder" align="center">
 <tr class="tableLedger">
  <td width="97%" align="left"><% = strTxtForums & " " & strTxtThatYouHaveSubscribedTo %></td>
  <td width="3%" align="center"><input type="checkbox" name="chkAll" onclick="checkAllForum();"></td>
 </tr><%
	
    
'Check there are email subscriptions to show
If isArray(sarrySubscribedForums) = false Then

	'If there are no email notifies to display
	Response.Write(vbCrLf & " <tr class=""tableRow""><td colspan=""2"" align=""center""><br />" &  strTxtYouHaveNoSubToEmailNotify & "<input type=""hidden"" name=""chkDelete"" value=""-1""><br /><br /></tr></td>")

'Else there the are email subs so show em
Else 	
	'Loop round to read in all the email notifys
	Do WHILE intCurrentRecord =< UBound(sarrySubscribedForums, 2)
	
		'SQL Query Array Look Up table
		'0 = Forum_name
		'1 = Forum_ID
		'2 = Watch_ID
	
		'Get the row number
		intForumColourNumber = intForumColourNumber + 1
	
	%>
 <tr class="<% If (intForumColourNumber MOD 2 = 0 ) Then Response.Write("evenTableRow") Else Response.Write("oddTableRow") %>"> 
  <td><a href="forum_topics.asp?FID=<% = sarrySubscribedForums(1,intCurrentRecord) %><% = strQsSID2 %>"><% = sarrySubscribedForums(0,intCurrentRecord) %></a></td>
  <td align="center"><input type="checkbox" name="chkDelete" value="<% = sarrySubscribedForums(2,intCurrentRecord) %>"></td>
 </tr><%
		
		'Move to the next record
		intCurrentRecord = intCurrentRecord + 1
	Loop
End If

'reset
intCurrentRecord = 0
%>
</table>
<table class="basicTable" cellspacing="0" cellpadding="2" align="center">
 <tr align="right"><td><input type="submit" name="Submit" value="<% = strTxtUnsusbribe %>"></td></tr>
</table>
</form>
<form name="frmTopicDel" id="frmTopicDel" method="post" action="email_notify_remove.asp<% If strMode = "A" Then Response.Write("?PF=" & lngEmailUserID & "&M=A") %><% = strQsSID2 %>" OnSubmit="return confirm('<% = strTxtAreYouWantToUnsubscribe & " " & strTxtTopics %>')">
<table cellspacing="1" cellpadding="3" class="tableBorder" align="center">
 <tr class="tableLedger">
  <td width="67%" align="left"><% = strTxtTopics & " " & strTxtThatYouHaveSubscribedTo %></td>
  <td width="30%"><% = strTxtLastPost %></td>
  <td width="3%" align="center"><input type="checkbox" name="chkAll" onclick="checkAllTopic();"></td>
 </tr><%
	
    
'Check there are email subscriptions to show
If isArray(sarrySubscribedTopics) = false Then

	'If there are no pm messages to display then display the appropriate error message
	Response.Write(vbCrLf & " <tr class=""tableRow""><td colspan=""3"" align=""center""><br />" & strTxtYouHaveNoSubToEmailNotify & "<input type=""hidden"" name=""chkDelete"" value=""-1""><br /><br /></tr></td>")

'Else there the are email subs so show em
Else 	
	'Loop round to read in all the email notifys
	Do WHILE intCurrentRecord =< UBound(sarrySubscribedTopics, 2)
	
		'SQL Query Array Look Up table
		'0 = Subject
		'1 = Last_Thread_ID
		'2 = Topic_ID
		'3 = Watch_ID
		'4 = Message_date
	
		'Get the date of the last entry
		dtmLastEntryDate = CDate(sarrySubscribedTopics(4,intCurrentRecord))
	
		'Get the row number
		intForumColourNumber = intForumColourNumber + 1
	%>
 <tr class="<% If (intForumColourNumber MOD 2 = 0 ) Then Response.Write("evenTableRow") Else Response.Write("oddTableRow") %>"> 
  <td><a href="forum_posts.asp?TID=<% = sarrySubscribedTopics(2,intCurrentRecord) %><% = strQsSID2 %>"><% = formatInput(sarrySubscribedTopics(0,intCurrentRecord)) %></a></td>
  <td nowrap><% Response.Write(DateFormat(dtmLastEntryDate) & "&nbsp;" & strTxtAt & "&nbsp;" & TimeFormat(dtmLastEntryDate)) %></td>
  <td align="center"><input type="checkbox" name="chkDelete" value="<% = sarrySubscribedTopics(3,intCurrentRecord) %>"></td>
 </tr><%
		
		'Move to the next record
		intCurrentRecord = intCurrentRecord + 1
	Loop
End If

'reset
intCurrentRecord = 0
%>
</table>
<table class="basicTable" cellspacing="0" cellpadding="2" align="center">
 <tr align="right"><td><input type="submit" name="Submit" value="<% = strTxtUnsusbribe %>"></td></tr>
</table>
</form><%

'If this is not in admin mode then see if the user wants email notification of a forum
If strMode <> "A" Then 
%>
<form method="post" name="frmAddForum" id="frmAddForum" action="email_notify.asp?M=SP" onSubmit="return CheckForm();">
<table cellspacing="1" cellpadding="3" class="tableBorder" align="center">
 <tr class="tableLedger">
  <td><% = strTxtSubscribeToForum %></td>
 </tr>
 <tr class="tableRow"> 
  <td> <% = strTxtSelectForumToSubscribeTo %> <%
            
Response.Write(vbCrLf & "   <select name=""FID"">")
Response.Write(vbCrLf & "    <option value="""" selected>-- " & strTxtSelectForum & " --</option>")

'Show forum select
If isArray(sarryForumSelect) Then
	
	'Loop round to show all the categories and forums
	Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
		'Loop through the array looking for forums that are to be shown
		'if a forum is found to be displayed then show the category and the forum, if not the category is not displayed as there are no forums the user can access
		Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
			'Read in details
			blnHideForum = CBool(sarryForumSelect(5,intCurrentRecord))
			blnRead = CBool(sarryForumSelect(6,intCurrentRecord))
					
			'If this forum is to be shown then leave the loop and display the cat and the forums
			If blnHideForum = False OR blnRead = True Then Exit Do
			
			'Move to next record
			intCurrentRecord = intCurrentRecord + 1
		Loop
				
		'If we have run out of records jump out of loop
		If intCurrentRecord > Ubound(sarryForumSelect,2) Then Exit Do
	 
		
		
		'Read in the deatils for the category
		intCatID = CInt(sarryForumSelect(0,intCurrentRecord))
		strCatName = sarryForumSelect(1,intCurrentRecord)		
		
		
		'Display a link in the link list to the forum
		Response.Write vbCrLf & "    <optgroup label=""&nbsp;&nbsp;" & strCatName & """>"
		
		
		
		'Loop round to display all the forums for this category
		Do While intCurrentRecord <= Ubound(sarryForumSelect,2)
		
			'Read in the forum details from the recordset
			intForumID = CInt(sarryForumSelect(2,intCurrentRecord))
			intSubForumID = CInt(sarryForumSelect(3,intCurrentRecord))
			strForumName = sarryForumSelect(4,intCurrentRecord)
			blnHideForum = CBool(sarryForumSelect(5,intCurrentRecord))
			blnRead = CBool(sarryForumSelect(6,intCurrentRecord))
			
			
			'If this forum is to be hidden but the user is allowed access to it set the hidden boolen back to false
			If blnHideForum = True AND blnRead = True Then blnHideForum = False

			'If the forum is not a hidden forum to this user, display it
			If blnHideForum = False AND intSubForumID = 0 Then
				'Display a link in the link list to the forum
				Response.Write (vbCrLf & "     <option value=""" & intForumID & """>&nbsp;" & strForumName & "</option>")	
			End If
			
			
			
			'See if this forum has any sub forums
			'Initilise variables
			intTempRecord = 0
					
			'Loop round to read in any sub forums in the stored array recordset
			Do While intTempRecord <= Ubound(sarryForumSelect,2)
			
				'Becuase the member may have an individual permission entry in the permissions table for this forum, 
				'it maybe listed twice in the array, so we need to make sure we don't display the same forum twice
				If intSubForumID = CInt(sarryForumSelect(2,intTempRecord)) Then intTempRecord = intTempRecord + 1
				
				'If there are no records left exit loop
				If intTempRecord > Ubound(sarryForumSelect,2) Then Exit Do
				
				'If this is a subforum of the main forum then get the details
				If CInt(sarryForumSelect(3,intTempRecord)) = intForumID Then
				
					'Read in the forum details from the recordset
					intSubForumID = CInt(sarryForumSelect(2,intTempRecord))
					strForumName = sarryForumSelect(4,intTempRecord)
					blnHideForum = CBool(sarryForumSelect(5,intTempRecord))
					blnRead = CBool(sarryForumSelect(6,intTempRecord))
					
					
					'If this forum is to be hidden but the user is allowed access to it set the hidden boolen back to false
					If blnHideForum = True AND blnRead = True Then blnHideForum = False
		
					'If the forum is not a hidden forum to this user, display it
					If blnHideForum = False Then
						'Display a link in the link list to the forum
						Response.Write (vbCrLf & "     <option value=""" & intSubForumID & """>&nbsp&nbsp;-&nbsp;" & strForumName & "</option>")	
					End If
				End If
				
				'Move to next record 
				intTempRecord = intTempRecord + 1
				
			Loop
			
			
					
			'Move to the next record in the array
			intCurrentRecord = intCurrentRecord + 1
			
			
			'If there are more records in the array to display then run some test to see what record to display next and where				
			If intCurrentRecord <= Ubound(sarryForumSelect,2) Then

				'Becuase the member may have an individual permission entry in the permissions table for this forum, 
				'it maybe listed twice in the array, so we need to make sure we don't display the same forum twice
				If intForumID = CInt(sarryForumSelect(2,intCurrentRecord)) Then intCurrentRecord = intCurrentRecord + 1
				
				'If there are no records left exit loop
				If intCurrentRecord > Ubound(sarryForumSelect,2) Then Exit Do
				
				'See if the next forum is in a new category, if so jump out of this loop to display the next category
				If intCatID <> CInt(sarryForumSelect(0,intCurrentRecord)) Then Exit Do
			End If
		Loop
		
		
		Response.Write(vbCrLf & "    </optgroup>")
	Loop
End If

Response.Write(vbCrLf & "    </select>")

%>
   <input type="submit" name="Submit" id="Submit" value="<% = strTxtSubscribe %>" />
  </td>
 </tr>
</table>
</form><%
End If
%>
<div align="center">
<br /><%

'***** START WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******
If blnLCode = True Then
	
	If blnTextLinks = True Then 
		Response.Write("<span class=""text"" style=""font-size:10px"">Bulletin Board Software by <a href=""http://www.webwizforums.com"" target=""_blank"" style=""font-size:10px"">Web Wiz Forums&reg;</a> version " & strVersion & "</span>")
	Else
  		Response.Write("<a href=""http://www.webwizforums.com"" target=""_blank""><img src=""webwizforums_image.asp"" border=""0"" title=""Bulletin Board Software by Web Wiz Forums&reg; version " & strVersion& """ alt=""Bulletin Board Software by Web Wiz Forums&reg; version " & strVersion& """ /></a>")
	End If
	
	Response.Write("<br /><span class=""text"" style=""font-size:10px"">Copyright &copy;2001-2008 <a href=""http://www.webwizguide.com"" target=""_blank"" style=""font-size:10px"">Web Wiz</a></span>")
End If 
'***** END WARNING - REMOVAL OR MODIFICATION OF THIS CODE WILL VIOLATE THE LICENSE AGREEMENT ******

'Display the process time
If blnShowProcessTime Then Response.Write "<span class=""smText""><br /><br />" & strTxtThisPageWasGeneratedIn & " " & FormatNumber(Timer() - dblStartTime, 3) & " " & strTxtSeconds & "</span>"


Response.Write("</div>")

%>
<!-- #include file="includes/footer.asp" -->