jmail.asp

企业管理系统,黑色风格

<%
function send_email(byval Add,byval Subject,byval Body)
   If IsObjInstalled("JMAIL.Message") Then
     dim jmail,smtpserver,username,Password
	 '-----------------------------------------------------------------------------发送邮箱配置
	 smtpserver=c_smtp_server  'smtp服务器
	 username=c_smtp_username '登录邮件服务器所需的会员名
	 Password=c_smtp_Password          '登录邮件服务器所需的密码
	 '-----------------------------------------------------------------------------以下内容一般不需要修改
     Set jmail = Server.CreateObject("JMAIL.Message")   '建立发送邮件的对象
     jmail.silent = true      '屏蔽例外错误，返回FALSE跟TRUE两值j
     jmail.logging = true      '启用邮件日志
     jmail.Charset = "GB2312"  '邮件的文字编码为国标
     jmail.ContentType = "text/html"    '邮件的格式为HTML格式
     jmail.AddRecipient add    '邮件收件人的地址
     jmail.From =username     '发件人的E-MAIL地址
     jmail.MailServerUserName = username    '登录邮件服务器所需的会员名
     jmail.MailServerPassword = Password    '登录邮件服务器所需的密码
     jmail.Subject = Subject     '邮件的标题 
     jmail.Body = Body           '邮件的内容
     jmail.Priority = 1          '邮件的紧急程序，1 为最快，5 为最慢， 3 为默认值
     jmail.Send(smtpserver)      '执行邮件发送（通过邮件服务器地址）
     jmail.Close   '关闭对象
  end if
end function
'==================================================
'判断服务器是否支持该组件
'==================================================
Function IsObjInstalled(byval strClassString)
	On Error Resume Next
	IsObjInstalled = False
	Err = 0
	Dim xTestObj
	Set xTestObj = Server.CreateObject(strClassString)
	If Err = 0 Then IsObjInstalled = True
	If Err = -2147352567 Then IsObjInstalled = True
	Set xTestObj = Nothing
	Err = 0
End Function
%>