📄 forum_move.asp

📁 1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册相片上传[方便上传
💻 ASP
字号:
<%
'===================================================================
'= ASP FILENAME	: /forum/forum_move.asp
'= CREATED TIME : 2006-6-25
'= LAST MODIFIED: 2006-6-25
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 移动帖子
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./forum_func.asp" -->
<!-- #include file = "./forum_inc.asp" -->
<!-- #include file = "./class_html_form.asp" -->
<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "forum/forum_move.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "移动帖子"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "FormTopicsMoveCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 在模板中引用的标签变量
Dim TAG_strVerifyCode	'== 表单校验
Dim TAG_objDicUnit		'== 单列记录

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()
%>

<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加载页面模块
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_forum_cate_list.html.asp" --> 
<%
End Function

'===================================================================
'= Sub         : FormTopicsMoveCtl()
'= Time		   : Created At 2006-6-25
'= Input       : None
'= Description : move topics to other forum
'===================================================================
Sub FormTopicsMoveCtl()

	Dim clsForm			'== Class of form
	Dim strHtmlCode
	Dim ForumId,TopicsId,strTitle

	'== subject move
	If Trim(Request.QueryString("ACT_MODE")) = "ACT_SUJECT_MODE" Then
		Call FormTopicsMoveSubject()
		Exit Sub
	End If

	ForumId = Trim(Request.QueryString("ForumId"))
	If Not IsNumeric(ForumId) Then
		Call ResultExecute(E_USER_PUB,"论坛ForumId错误","ES_ERR")
	End If

	TopicsId = Trim(Request.QueryString("TopicsId")) 
	If Not IsNumeric(TopicsId) Then
		Call ResultExecute(E_USER_PUB,"论坛TopicsID错误","ES_ERR")
	End If

	strTitle = Trim(Request.QueryString("pstTitle"))
	If Len(strTitle) <= 0 Then
		Call ResultExecute(E_USER_PUB,"帖子标题错误","ES_ERR")
	End If

	If GBL_strUserAuthen <> 1 And Not GetMaster(ForumId) Then
		Call ResultExecute(E_USER_PUB,"你没有操作权限","ES_ERR")
		Exit Sub
	End If

	Call ShowAddReplyForumMenu("移动帖子")

	'== get forum name
	Dim arrTmp,strForum
	arrTmp = Trim(GetConfig(Application(GBL_strCookieURL & "FORUM_CATE"),"Forum" & ForumId))
	If arrTmp <> ""  Then
		arrTmp = Split(arrTmp,"|")
		If Not IsArray(arrTmp) Then
			strForum = ""
		Else
			strForum = arrTmp(0)
		End If
	Else
		strForum = ""
	End If

	Set clsForm = New classFormOld
	clsForm.Action = "./forum_move_save.asp?action=FormSaveTopicsMove"

	clsForm.Id = "frmMoveTopics"
	clsForm.Name = "frmMoveTopics"
	clsForm.OnSubmit = "return CheckFormTopicsMove(this)"
	clsForm.ColumnScale = "30%"
	clsForm.MakeForm()
	clsForm.MakeTable "0","5","1","center","100%","TBone"

	clsForm.AddTr ""
	clsForm.AddTitle "<b>转 移 帖 子</b>","TBHead"

	GBL_cssFormTr = ""
	GBL_cssFormTdOne = "TBBG1"
	GBL_cssFormTdTwo = "TBBG9"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "帖子标题",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine  "<font color=red>" & strTitle & "</font>"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "当前版面",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine  "[" & strForum & "]"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "选择版面",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddSelect "selForumId",""
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT FORUM_ID,FORUM_NAME FROM CLASS_FORUM ORDER BY FORUM_ORDER DESC"
	GBL_objPubDB.SQLRSExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"get forum","ES_ERR")
	Dim i
	For i = 1 To GBL_objPubDB.intRSNum
		clsForm.AddOption GBL_objPubDB.objPubRS("FORUM_ID"),GBL_objPubDB.objPubRS("FORUM_NAME"),ForumId
		GBL_objPubDB.objPubRS.MoveNext
	Next

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "选择",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine "请选择您要转移的版面，一旦转移将不能还原"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "帖子提交",GBL_cssFormTdOne,GBL_cssFormTdTwo
	strHtmlCode = "<input type=hidden name='hidForumId' id='hidForumId' value=" & ForumId & ">"
	strHtmlCode = strHtmlCode & "<input type=hidden name='hidTopicsId' id='hidTopicsId' value=" & TopicsId & ">"
	clsForm.AddLine "Alt+S或Ctrl+Enter快速提交" & strHtmlCode

	clsForm.AddTr ""
	clsForm.AddSubTd "TBBG9 style='text-align:center;'"
	clsForm.AddSub "subTopicsMove","提 交","submit class='fmbtn' "
	clsForm.AddSub "rstTopicsMove","重 写","reset class='fmbtn' "

	clsForm.OutPutForm()
	Set clsForm = Nothing

End Sub

'===================================================================
'= Sub         : FormTopicsMoveSubject()
'= Time		   : Created At Jun,15,2004
'= Input       : None
'= Description : move topics to other subject
'===================================================================
Sub FormTopicsMoveSubject()

	Dim clsForm			'== Class of form
	Dim strHtmlCode
	Dim ForumId,TopicsId,strTitle

	
	ForumId = Trim(Request.QueryString("ForumId"))
	If Not IsNumeric(ForumId) Then
		Call ResultExecute(E_USER_PUB,"论坛ForumId错误","ES_ERR")
	End If

	TopicsId = Trim(Request.QueryString("TopicsId")) 
	If Not IsNumeric(TopicsId) Then
		Call ResultExecute(E_USER_PUB,"论坛TopicsID错误","ES_ERR")
	End If

	strTitle = Trim(Request.QueryString("pstTitle"))
	If Len(strTitle) <= 0 Then
		Call ResultExecute(E_USER_PUB,"帖子标题错误","ES_ERR")
	End If

	If GBL_strUserAuthen <> 1 And Not GetMaster(ForumId) Then
		Call ResultExecute(E_USER_PUB,"你没有操作权限","ES_ERR")
		Exit Sub
	End If

	'== get forum name
	arrTmp = Trim(GetConfig(Application(GBL_strCookieURL & "FORUM_CATE"),"Forum" & ForumId))
	If arrTmp <> ""  Then
		arrTmp = Split(arrTmp,"|")
		If Not IsArray(arrTmp) Then
			strForum = ""
		Else
			strForum = arrTmp(0)
		End If
	Else
		strForum = ""
	End If

	Set clsForm = New classForm
	clsForm.Action = "./forum_move_save.asp?action=FormSaveTopicsMove&ACT_MODE=ACT_SUJECT_MODE"

	clsForm.Id = "frmMoveTopics"
	clsForm.Name = "frmMoveTopics"
	clsForm.OnSubmit = "return CheckFormTopicsMove(this)"
	clsForm.ColumnScale = "30%"
	clsForm.MakeForm()
	clsForm.MakeTable "0","5","1","center","100%","TBone"

	clsForm.AddTr ""
	clsForm.AddTitle "<b>为帖子设定专题</b>","TBHead"

	GBL_cssFormTr = ""
	GBL_cssFormTdOne = "TBBG1"
	GBL_cssFormTdTwo = "TBBG9"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "帖子标题",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine  "<font color=red>" & strTitle & "</font>"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "当前版面",GBL_cssFormTdOne,GBL_cssFormTdTwo
	clsForm.AddLine  "[" & strForum & "]"

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "选择专题",GBL_cssFormTdOne,GBL_cssFormTdTwo
	'== subject
	If Not IsEmpty(DEF_FormSubject(ForumId)) Then
		If IsArray(DEF_FormSubject(ForumId)) Then
			clsForm.AddSelect "selForumSubject",""
			arrNowSub = DEF_FormSubject(ForumId)
			For n = Lbound(arrNowSub) To Ubound(arrNowSub)
				Response.Write arrNowSub(n)
				clsForm.AddOption n+1,arrNowSub(n),""
			Next
			clsForm.AddOption 0,"不设定专题",""
		Else
			clsForm.AddLine "没有专题可以指定"
		End If
	Else
		clsForm.AddLine "没有专题可以指定"
	End If

	clsForm.AddTr GBL_cssFormTr
	clsForm.AddTd "帖子提交",GBL_cssFormTdOne,GBL_cssFormTdTwo
	strHtmlCode = "<input type=hidden name='hidForumId' id='hidForumId' value=" & ForumId & ">"
	strHtmlCode = strHtmlCode & "<input type=hidden name='hidTopicsId' id='hidTopicsId' value=" & TopicsId & ">"
	clsForm.AddLine "Alt+S或Ctrl+Enter快速提交" & strHtmlCode

	clsForm.AddTr ""
	clsForm.AddSubTd "TBBG9 style='text-align:center;'"
	clsForm.AddSub "subTopicsMove","提 交","submit class='fmbtn' "
	clsForm.AddSub "rstTopicsMove","重 写","reset class='fmbtn' "

	clsForm.OutPutForm()
	Set clsForm = Nothing

End Sub

Function ShowForumMenu()

	GetRSId = Trim(Request.QueryString("ForumId"))
	If Not IsNumeric(GetRSId) Then 
		Call ResultExecute(E_USER_PUB,"该帖子ID错误","ES_ERR")
	End If
%>
	<table width=<%=DEF_WEB_ScreenWidth%>  cellspacing=1 cellpadding=5 class="forum_nav_table">
		<tr >
			<td width=100% colspan=2 style="text-align:left" >
			<%
				Response.Write ForumMenu(1,"转移帖子")
			%>
			</td>
		</tr>
	</table>
<%
End Function
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -