forum_inc.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /forum/forum_inc.asp
'= CREATED TIME : Mar,15,2004
'= LAST MODIFIED: Mar,15,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : forum public functions and not by style
'= Change Log:
'===================================================================
%>

<%
'===================================================================
'= Function    : GetMaster(intForumId)
'= Time		   : Created At Jun,11,2004
'= Input       : 
'= Table	   : Qurey CLASS_FORUM,CLASS_USER
'= Description : get user master of forum
'===================================================================
Dim GBL_cssFormTdOne : GBL_cssFormTdOne = "TBBG1"
Dim GBL_cssFormTdTwo : GBL_cssFormTdTwo = "TBBG9"
Dim GBL_strImgPath : GBL_strImgPath = "images/"

Function GetMaster(intForumId)

	Dim strTmp,i

	strTmp =  Trim(GetConfig(Application(GBL_strCookieURL & "FORUM_MASTER"),"Forum" & intForumId))

	If strTmp <> "" Then
		strTmp = Split(strTmp,"|")
		For i = Lbound(strTmp) To Ubound(strTmp)
			If Trim(strTmp(i)) = GBL_strUserAccount Then
				GetMaster = True
				Exit Function
			End If
		Next
	End If

	GetMaster = False

End Function
'===================================================================
'= Function    : ForumMenu(intFlag,strClew)
'= Time		   : Created At Mar,15,2004
'= Input       : intFlag	: now page mode
'= Table	   : Qurey CLASS_FORUM,
'= Description : Show form now menu
'===================================================================
Function ForumMenu(intFlag,strClew)

	Dim strPutMenu
	Dim strHtmlCode
	Dim arrTmp,strTmp,ForumId

	strPutMenu = ""
	strHtmlCode = ""
	strTmp = ""

	ForumId = Trim(Request("ForumId"))
	If Len(ForumId) = 0 Or Not IsNumeric(ForumId) Then
		ForumId = 0
	End If

	arrTmp = Trim(GetConfig(Application(GBL_strCookieURL & "FORUM_CATE"),"Forum" & ForumId))
	If arrTmp <> ""  Then
		arrTmp = Split(arrTmp,"|")
		If Not IsArray(arrTmp) Then
			ForumMenu = ""
			Exit Function
		End If
	Else
		ForumMenu = ""
		Exit Function
	End If

	strPutMenu = "&nbsp;<img src='" & GBL_strHomeURL & "images/jt.gif' border=0 align=absmiddle>&nbsp;<a href='" & GBL_strHomeURL & "index.asp'>首页</a> &gt;&gt;<a href='" & GBL_strHomeURL & "forum/forum_cate.asp' > 校友论坛</a> &gt;&gt; "
	strPutMenu = strPutMenu & "<a href='" & GBL_strHomeURL & "forum/forum_list.asp?ForumId=" & ForumId & "'>" & arrTmp(0) & "</a>"

	If Trim(strClew) <> "" Then
		strPutMenu = strPutMenu & " &gt;&gt; " & strClew
	End If
	
	Select Case intFlag
		Case 1	: 
			strPutMenu = strPutMenu & "<br>" & strHtmlCode
		Case 2	:
			strPutMenu = strPutMenu & ""
		Case 3	:
			strPutMenu= strPutMenu & " &gt;&gt; 修改帖子"
	End Select 

	ForumMenu = strPutMenu

End Function

'===================================================================
'= Sub         : CheckMasterForum(GetRSId)
'= Time		   : Created At Jan,29,2004
'= Table	   : Qurey CLASS_FORUM,
'= Description : check this forum admin only
'===================================================================
Function CheckMasterForum(GetRSId)

	If Trim(Request("VIEW_MODE")) = "ADMIN_ONLY"  And Session(GBL_strCookieURL & "SEN_strIsMaster") = "0"  Then
		GetRSId = -1
	End If
	If GetRSId = -1 Then
		Call ResultExecute(E_USER_PUB,"您没有浏览该管理员和版主版面的权限","ES_ERR")
		Exit Function
	Else
		Dim strForumAccess : strForumAccess = Trim(Application(GBL_strCookieURL & "FORUM_ACCESS"))
		Dim arrForumAccess : arrForumAccess = Split(strForumAccess,"|")
		Dim k
		For k = Lbound(arrForumAccess) To Ubound(arrForumAccess)
			intNowForumAccess = Cint(arrForumAccess(k))
			If Cint(GetRSId) = intNowForumAccess  And Session(GBL_strCookieURL & "SEN_strIsMaster") = "0" Then
				Call ResultExecute(E_USER_PUB,"您没有浏览该管理员和版主版面的权限","ES_ERR")
				Exit Function
			End If
		Next
	End If

End Function
%>