forum_status.asp

1] 校友多种方式注册认证[直接注册,答问注册,认证注册] 2] 校友论坛 小巧而实用的论坛,支持UBB标签,快速回复,帖子搜索,灵活的将帖子置顶,设置精华 3] 校友相册 相片上传[方便上传

<%
'===================================================================
'= ASP FILENAME	: /forum/forum_status.asp
'= CREATED TIME : 2006-6-24
'= LAST MODIFIED: 2006-6-24
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 改变帖子状态
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./forum_inc.asp" -->
<!-- #include file = "./forum_func.asp" -->

<%
'========================================================
'==   Action参数设置
'========================================================
'== 页面名
Const CONST_PAGE_FILE	= "forum/forum_status.asp"

'== 页面标题/功能
Const CONST_PAGE_TITLE	= "改变帖子状态"

'== 功能函数名字空间
Const CONST_ACTION_FUNC	= "MdyTopicsStatusCtl"

'== 相对根目录路径 
GBL_strHomeURL			= "../"

'== 页面构造
Call ActionBuild()

'== 请求校验与过滤
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 页面析构
Call ActionOver()

%>

<%
'===================================================================
'= Sub         : MdyTopicsStatusCtl() 
'= Time	       : Created At 2006-6-25
'= Input       : None
'= Table       : UPDATE CLASS_TOPICS
'= Description : 改变帖子状态
'===================================================================
Sub MdyTopicsStatusCtl() 

	Dim strAddInfo								'== checked data's clew
	Dim intErrId,ForumId,GetRSId
	Dim intStatus

	intErrId = 0

	If Request.QueryString("ACT_MODE") = "ACT_FORBID" Then
		 Call MdyTopicsForbid()
		 Exit Sub
	ElseIf Request.QueryString("ACT_MODE") = "ACT_ALLTOP" Then
		 Call MdyTopicsAllTop()
		 Exit Sub
	End If

	ForumId = Trim(Request.QueryString("ForumId"))
	strAddInfo = "论坛栏目"
	intErrId = DataCheck("DT_ID",ForumId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	GetRSId = Trim(Request.QueryString("TopicsId"))
	strAddInfo = "所属论坛帖子"
	intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	intStatus = Trim(Request.QueryString("pstStatus"))
	strAddInfo = "帖子状态指定"
	intErrId = DataCheck("DT_ENUM",intStatus,strAddInfo,"0,9")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
	intStatus = Cint(intStatus)

	If GBL_strUserAuthen <> 1 And Not GetMaster(ForumId) Then
		Call ResultExecute(E_USER_PUB,"你没有操作权限","ES_ERR")
		Exit Sub
	End If

	'== mdy topics stauts
	GBL_objPubDB.Clear()
	If intStatus = 0 Then 
		GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_STATUS=" & intStatus & " WHERE TOPICS_ID=" & GetRSId & " AND TOPICS_STATUS=9 "
	Else
		GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_STATUS=" & intStatus & " WHERE TOPICS_ID=" & GetRSId & " AND TOPICS_STATUS=0 "
	End If
	GBL_objPubDB.SQLExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"mdy topics status","ES_ERR")

	Set GBL_objPubDB = Nothing
	Response.Redirect GBL_strHomeURL & "forum/forum_show.asp?action=ShowForumContent&TopicsId=" & GetRSId & "&ForumId=" & ForumId
	
End Sub

'===================================================================
'= Sub         : MdyTopicsForbid() 
'= Time	       : Created At Mar,15,2004
'= Input       : None
'= Table       : UPDATE CLASS_TOPICS
'= Description : modify topics status
'===================================================================
Sub MdyTopicsForbid() 

	Dim strAddInfo								'== checked data's clew
	Dim intErrId,ForumId,GetRSId
	Dim intForbid

	intErrId = 0

	ForumId = Trim(Request.QueryString("ForumId"))
	strAddInfo = "论坛栏目"
	intErrId = DataCheck("DT_ID",ForumId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	GetRSId = Trim(Request.QueryString("TopicsId"))
	strAddInfo = "所属论坛帖子"
	intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	intForbid = Trim(Request.QueryString("pstForbid"))
	strAddInfo = "帖子状态指定"
	intErrId = DataCheck("DT_ENUM",intForbid,strAddInfo,"0,1")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	If GBL_strUserAuthen <> 1 And Not GetMaster(ForumId) Then
		Call ResultExecute(E_USER_PUB,"你没有操作权限","ES_ERR")
		Exit Sub
	End If

	'== mdy topics stauts
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_REPLY_FORBID=" & intForbid & " WHERE TOPICS_ID=" & GetRSId
	GBL_objPubDB.SQLExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"mdy topics forbid","ES_ERR")

	Set GBL_objPubDB = Nothing
	Response.Redirect GBL_strHomeURL & "forum/forum_show.asp?action=ShowForumContent&TopicsId=" & GetRSId & "&ForumId=" & ForumId
	
End Sub

'===================================================================
'= Sub         : MdyTopicsAllTop() 
'= Time	       : Created At Aug,1,2004
'= Input       : None
'= Table       : UPDATE CLASS_TOPICS
'= Description : modify topics status
'===================================================================
Sub MdyTopicsAllTop() 

	Dim strAddInfo								'== checked data's clew
	Dim intErrId,ForumId,GetRSId
	Dim intForbid

	intErrId = 0

	'== now only for admin
	If GBL_strUserAuthen <> 1 Then
		Call ResultExecute(E_USER_PUB,"您需要有管理员权限!!","ES_ERR")
		Exit Sub
	End If

	ForumId = Trim(Request.QueryString("ForumId"))
	strAddInfo = "论坛栏目"
	intErrId = DataCheck("DT_ID",ForumId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	GetRSId = Trim(Request.QueryString("TopicsId"))
	strAddInfo = "所属论坛帖子"
	intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"ES_ERR")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	Dim intAllTop : intAllTop = Trim(Request.QueryString("pstAllTop"))
	strAddInfo = "帖子状态指定"
	intErrId = DataCheck("DT_ENUM",intAllTop,strAddInfo,"0,10")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
	intAllTop = Cint(intAllTop)

	'== mdy topics stauts
	GBL_objPubDB.Clear()
	If intAllTop = 0 Then
		GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_STATUS=" & intAllTop & " WHERE TOPICS_ID=" & GetRSId & " AND TOPICS_STATUS=10 "
	Else
		GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_STATUS=" & intAllTop & " WHERE TOPICS_ID=" & GetRSId 
	End If
	GBL_objPubDB.SQLExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"mdy topics all top","ES_ERR")

	Set GBL_objPubDB = Nothing
	Response.Redirect GBL_strHomeURL & "forum/forum_show.asp?action=ShowForumContent&TopicsId=" & GetRSId & "&ForumId=" & ForumId
	
End Sub
%>